Passing object as parameter

Question

Hi All,
I have a procedure that takes IN an object as the parameter. I'm using SQL Developer , and also have SQL*plus.
The type is
create or replace
TYPE TY_RAILROAD_OPERATOR AS OBJECT
RRX_RAILROAD_OPERATOR_CD VARCHAR2(6 BYTE),
RRX_RAILROAD_OPERATOR_NM VARCHAR2(60 BYTE) ,
RRX_RAILROAD_OPERATOR_DSC VARCHAR2(2000 BYTE),
STATUS CHAR(1 BYTE),
LAST_UPDATE_DT DATE,
LAST_UPDATE_USER VARCHAR2(60))
procedure set_Railroad_Operator(p_TY_Railroad_Operator IN TY_Railroad_Operator, p_Railroad_Operator_Id OUT NUMBER) IS
v_Railroad_Operator_Id NUMBER;
BEGIN
I have to execute the procedure. How should I pass the parameters?
I would like to test the procedure, and I have no idea how to test it.
Any help is appreciated.
Thanks in advance
N

Answer 1

sample:
SQL> CREATE OR REPLACE TYPE ty_railroad_operator AS OBJECT(
  2     rrx_railroad_operator_cd    VARCHAR2(6 BYTE),
  3     rrx_railroad_operator_nm    VARCHAR2(60 BYTE),
  4     rrx_railroad_operator_dsc   VARCHAR2(2000 BYTE),
  5     status                      CHAR(1 BYTE),
  6     last_update_dt              DATE,
  7     last_update_user            VARCHAR2(60)
  8  );
  9  /
Type created.
SQL> CREATE OR REPLACE PROCEDURE set_railroad_operator(
  2     p_ty_railroad_operator   IN       ty_railroad_operator,
  3     p_railroad_operator_id   OUT      NUMBER
  4  )
  5  IS
  6     v_railroad_operator_id   NUMBER := 10;
  7  BEGIN
  8     DBMS_OUTPUT.put_line(p_ty_railroad_operator.rrx_railroad_operator_cd);
  9     DBMS_OUTPUT.put_line(p_ty_railroad_operator.rrx_railroad_operator_nm);
10     DBMS_OUTPUT.put_line(p_ty_railroad_operator.rrx_railroad_operator_dsc);
11     DBMS_OUTPUT.put_line(p_ty_railroad_operator.status);
12     DBMS_OUTPUT.put_line(p_ty_railroad_operator.last_update_dt);
13     DBMS_OUTPUT.put_line(p_ty_railroad_operator.last_update_user);
14  END;
15  /
Procedure created.
SQL>
SQL> DECLARE
  2     v_ty_railroad_operator   ty_railroad_operator
  3        := ty_railroad_operator('OP_CD', 'OP CODE NAME', 'OP CODE DESC', 'S',
  4                                SYSDATE, 'OP CODE USER');
  5     a                        NUMBER(10);
  6  BEGIN
  7     set_railroad_operator(p_ty_railroad_operator => v_ty_railroad_operator,
  8                           p_railroad_operator_id => a);
  9  END;
10  /
OP_CD
OP CODE NAME
OP CODE DESC
S
15-JUN-10
OP CODE USER
PL/SQL procedure successfully completed.
SQL>