PASSING TABLES AS PARAMETERS IN FOR ALL INSERT

Question

Hi All,
I want to pass table as a parameter to perform update in dynamic sql....
sample code:
declare
cur_tab1 is select * from tabl1;
TYPE tables_bulk is TABLE OF table2.source_table%TYPE;
v_tables_bulk tables_bulk;
ls_exe varchar2(2000);
begin
for i in cur_tab1 loop
select source_table bulk collect into v_tables_bulk from table2 where table_id =i.col1
forall i in 1..v_tables_bulk.count
ls_exe :='update '|| v_tables_bulk(i) || set bulk_col1|| =i.col2'
end;
code description :
here source_table is a column in table 2..source table column contains many tables..I have to fecth that table and update it with conditions using cursor.Also for select condition , we will get more than one value (more tables)..so i used bulk collect instead of normal variable.......i get local collection error..please help me out..

Answer 1

user2639048 wrote:
I did that but still it showed invalid sql....What is version of your database ?
Some syntax works on newer versions, and is disallowed on older.
Here is an example that works on Oracle 11g2
-- create base table
CREATE TABLE TAB AS
SELECT TAB_ID,
       EMP_ID,
       'NAME ' || TAB_ID NAME,
       ROUND( DBMS_RANDOM.VALUE( 1, 1000 ), 2 ) SALARY
FROM (
  SELECT ROUND( DBMS_RANDOM.VALUE(1,20)) TAB_ID,
         LEVEL EMP_ID
  FROM DUAL
  CONNECT BY LEVEL <= 100
-- create child tables
DECLARE
  X PLS_INTEGER;
BEGIN
  SELECT MAX( TAB_ID ) INTO X
  FROM TAB;
  FOR I IN 1 .. X LOOP
     EXECUTE IMMEDIATE
        'CREATE TABLE TAB' || I ||
       q'{ AS SELECT * FROM TAB
           WHERE 1 = 0 }';
  END LOOP;
END;
CREATE OR REPLACE
PACKAGE UPDATE_TAB IS
   TYPE TAB_TAB_TYP IS TABLE OF TAB%ROWTYPE;
   PROCEDURE UPDATE_TAB( I_TAB IN TAB_TAB_TYP );
   PROCEDURE TEST_UPDATE_TAB;
END UPDATE_TAB;
CREATE OR REPLACE
PACKAGE BODY UPDATE_TAB AS
  PROCEDURE UPDATE_TAB( I_TAB IN TAB_TAB_TYP ) AS
  BEGIN
    FOR I IN I_TAB.FIRST .. I_TAB.LAST
    LOOP
        EXECUTE IMMEDIATE
            ' UPDATE TAB' || I_TAB(I).TAB_ID ||
            Q'{ SET TAB_ID = :TABID, NAME = :NAM, SALARY = :SAL
                WHERE EMP_ID = :EMPID }'
        USING I_TAB(I).TAB_ID, I_TAB(I).NAME,
                I_TAB(I).SALARY, I_TAB(I).EMP_ID;
        IF SQL%ROWCOUNT <= 0 THEN
            EXECUTE IMMEDIATE
              ' INSERT INTO TAB' || I_TAB(I).TAB_ID ||
              ' ( TAB_ID, EMP_ID, NAME, SALARY ) ' ||
              ' VALUES( :TABID,  :EMPID, :NAME , :SAL )'
            USING I_TAB(I).TAB_ID, I_TAB(I).EMP_ID,
                  I_TAB(I).NAME, I_TAB(I).SALARY;
        END IF;
    END LOOP;
  END UPDATE_TAB;
   PROCEDURE TEST_UPDATE_TAB IS
     L_TAB TAB_TAB_TYP;
   BEGIN
      SELECT * BULK COLLECT INTO L_TAB
      FROM TAB;
      UPDATE_TAB( L_TAB );
   END;
END UPDATE_TAB;
--- TEST
BEGIN
  UPDATE_TAB.TEST_UPDATE_TAB;
END;
SELECT * FROM TAB16;
TAB_ID                 EMP_ID                 NAME                                          SALARY                
16                     2                      NAME 16                                       455.86                
16                     6                      NAME 16                                       253.18                
16                     14                     NAME 16                                       478.92                
16                     32                     NAME 16                                       381.27                
16                     56                     NAME 16                                       737.77                
16                     58                     NAME 16                                       382.65                
16                     70                     NAME 16                                       203.03                
16                     100                    NAME 16                                       435.73                
8 rows selected
SELECT * FROM TAB2;
TAB_ID                 EMP_ID                 NAME                                          SALARY                
2                      1                      NAME 2                                        737.91                
2                      18                     NAME 2                                        35.61                 
2                      22                     NAME 2                                        57.76                 
2                      33                     NAME 2                                        851.72                
2                      73                     NAME 2                                        109.74
5 rows selected
UPDATE TAB SET SALARY = 100
WHERE TAB_ID = 2;
5 rows updated
BEGIN
  UPDATE_TAB.TEST_UPDATE_TAB;
END;
SELECT * FROM TAB2;
TAB_ID                 EMP_ID                 NAME                                          SALARY                
2                      1                      NAME 2                                        100                   
2                      18                     NAME 2                                        100                   
2                      22                     NAME 2                                        100                   
2                      33                     NAME 2                                        100                   
2                      73                     NAME 2                                        100    
5 rows selected