Performance of native sql query detoriates

Question

Dear Experts,
The performance of my native SQL query is bad. On the database the query takes less than 5 seconds to process. From my abap program I get a session timeout dump after 10 minutes. What might be the possible reason.
Warm Regards,
Abdullah

Answer 1

I am not a DBA, but this is a wild guess.
I have a native SQL query. It was running fine all morning(transported it to production today). By afternoon the report was not giving any output.
I went to the MS SQL query analyzer and executed the query, it returned the results in less than 5 seconds. The same query when I was executing from SAP using native SQL took more than 10 minutes and gave a dump(time exceeded).
My database guy asked me to execute the following on the database. Dbcc dbreindex('tablename')
The report is running fine since then. I am still not satisfied if this is the reason the performance is back on track, but yeah the report is running fine again. There seems to be some problem with the indexes.
I am using standard classes provided by SAP to execute my query and after execution the resultset reference object is being closed, I am closing the connection.
the code is as below.
      PERFORM:
        connect               USING con_name con_ref,
        select_into_table     USING con_ref,
        disconnect            USING con_ref.
*  FORM connect
*  Connects to the database specified by the logical connection name
*  P_CON_NAME which is expected to be specified in table DBCON. In case
*  of success the form returns in P_CON_REF a reference to a connection
*  object of class CL_SQL_CONNECTION.
*  --> P_CON_NAME  logical connection name
*  <-- P_CON_REF   reference to a CL_SQL_CONNECTION object
FORM connect  USING    p_con_name TYPE dbcon-con_name
                       p_con_ref  TYPE REF TO cl_sql_connection
                       RAISING cx_sql_exception.
* if CON_NAME is not initial then try to open the connection, otherwise
* create a connection object representing the default connection.
  IF p_con_name IS INITIAL.
    CREATE OBJECT p_con_ref.
  ELSE.
    p_con_ref = cl_sql_connection=>get_connection( p_con_name ).
  ENDIF.
ENDFORM.                    " connect
*  FORM select_into_table
*  Selects some rows from the test table and fetches the result rows
*  into an internal table whose row structure corresponds to the
*  queries select list columns.
FORM select_into_table
  USING   p_con_ref TYPE REF TO cl_sql_connection
  RAISING cx_sql_exception.
  DATA:
    l_stmt         TYPE string,
    l_stmt_ref     TYPE REF TO cl_sql_statement,
    l_dref         TYPE REF TO data,
    l_res_ref      TYPE REF TO cl_sql_result_set,
*Data related query
    l_itab         TYPE TABLE OF t_pricing_report,
    l_row_cnt      TYPE i.
* create the query string
CONCATENATE
    'select A.SEQ,A.CONDTABLE,A.CONDNAME,A.VKORG,A.VTWEG,A.MATKL,A.MATNR,B.MTEXT,A.VKGRP,A.SGRPNAME,'
    'A.VKBUR,A.SOFFNAME,A.ZSALES,A.SCNTNAME,A.KUNNR,A.SCSTNAME,A.PRBATCH,A.INCO1,'
    'A.INCO2,A.DATAB,A.DATBI,A.KBETR,A.KONWA,A.KOSRT,B.MTART,B.GROES,B.VOLUM,B.EXTWG,B.WRKST,'
    'A.MXWRT,A.GKWRT,'
    'B.PATTERN,B.RIM,B.SERIES,B.SPDINDEX,B.LDINDX,B.MGROUP,B.APPLN,B.SDWALL,B.MGRPTXT'
    'FROM Z_PRICELIST A,Z_MATERIALVIEW B'
    'WHERE A.MANDT = ? AND'
          'B.MANDT = A.MANDT AND'
          'A.MATNR = B.MATNR AND'
          'A.KSCHL = ? AND'
          'A.CONDTABLE LIKE ? AND'
          'A.VKORG LIKE ? AND'
          'A.VTWEG LIKE ? AND'
          'A.MATKL >= ? AND A.MATKL <= ? AND'
          'A.MATNR >= ? AND A.MATNR <= ? AND'
          'A.INCO1 LIKE ? AND'
          'A.INCO2 LIKE ? AND'
          'A.ZSALES >= ? AND A.ZSALES <= ? AND'
          'A.KUNNR  >= ? AND A.KUNNR <= ? AND'
          'A.PRBATCH  >= ? AND A.PRBATCH <= ? AND'
          'A.VKBUR  >= ? AND A.VKBUR <= ? AND'
          'A.VKGRP  >= ? AND A.VKGRP <= ? AND'
          'B.WRKST  >= ? AND B.WRKST <= ? AND'
          'B.MTART  >= ? AND B.MTART <= ? AND'
          '? BETWEEN A.DATAB AND A.DATBI AND'
          'B.GROES LIKE ? AND'
          'B.LDINDX LIKE ? AND'
          'B.SPDINDEX LIKE ? AND'
          'B.RIM LIKE ? AND'
          'B.SERIES LIKE ? AND'
          'B.PATTERN LIKE ? AND'
          'B.MGROUP LIKE ?'
          'order by A.MATNR'
    INTO l_stmt SEPARATED BY space.                         "#EC NOTEXT
* create a statement object
  l_stmt_ref = p_con_ref->create_statement( ).
* bind input variables
  GET REFERENCE OF l_col1 INTO l_dref.
  l_stmt_ref->set_param( l_dref ).
*binding other references here
  GET REFERENCE OF l_col33 INTO l_dref.
  l_stmt_ref->set_param( l_dref ).
* set the input values and execute the query
  l_col1  = sy-mandt.
*..Assigning values here
  l_col33 = p_mgroup.
*  PERFORM trace_2 USING 'EXECUTE_QUERY' l_stmt l_col1 l_col2.
  l_res_ref = l_stmt_ref->execute_query( l_stmt ).
* set output table
  GET REFERENCE OF l_itab INTO l_dref.
  l_res_ref->set_param_table( l_dref ).
* get the complete result set
  l_row_cnt = l_res_ref->next_package( ).
* display the contents of the output table
*  PERFORM trace_next_package USING l_itab.
*  PERFORM trace_result USING l_row_cnt 'rows fetched'.
  pricing_report[] = l_itab[].
  free l_itab.
* don't forget to close the result set object in order to free
* resources on the database
  l_res_ref->close( ).
ENDFORM.                    "select_into_table
*  FORM disconnect
*  Disconnect from the given connection. In case of the default
*  connection this can be omitted.
FORM disconnect
  USING   p_con_ref TYPE REF TO cl_sql_connection
  RAISING cx_sql_exception.
  DATA: l_con_name TYPE dbcon-con_name.
  l_con_name = p_con_ref->get_con_name( ).
  CHECK l_con_name <> cl_sql_connection=>c_default_connection.
*  PERFORM trace_0 USING 'CLOSE CONNECTION' l_con_name.
  p_con_ref->close( ).
*  PERFORM trace_result USING l_con_name 'closed'.
ENDFORM.                    "disconnect
*  FORM handle_sql_exception
*  Write appropriate error messages when a SQL exception has occured
*  -->  P_SQLERR_REF  reference to a CX_SQL_EXCEPTION object
FORM handle_sql_exception
  USING p_sqlerr_ref TYPE REF TO cx_sql_exception.
  FORMAT COLOR COL_NEGATIVE.
  IF p_sqlerr_ref->db_error = 'X'.
    WRITE: / 'SQL error occured:', p_sqlerr_ref->sql_code,
           / p_sqlerr_ref->sql_message.                     "#EC NOTEXT
  ELSE.
    WRITE:
      / 'Error from DBI (details in dev-trace):',
        p_sqlerr_ref->internal_error.                       "#EC NOTEXT
  ENDIF.
ENDFORM.                    "handle_sql_exception