PL SQL Array Output

Question

Hi,
I have below pl sql type structure.
create or replace
TYPE     xx_emp_obj AS OBJECT (
   empno             NUMBER,
   ename            VARCHAR2 (200),
   last_name         VARCHAR2 (200),
   job              VARCHAR2 (200),
   mgr_id           NUMBER,
   deptno           NUMBER,
CONSTRUCTOR FUNCTION xx_emp_obj
      RETURN SELF AS RESULT
create or replace
TYPE     xx_emp_tbl IS TABLE OF xx_emp_obj;Wrote below package to hold values.
create or replace PACKAGE xx_emp_ret_pkg as
PROCEDURE get_emp_prc(p_deptno IN NUMBER, x_emp_tbl  OUT  xx_emp_tbl);
END xx_emp_ret_pkg;
create or replace PACKAGE BODY xx_emp_ret_pkg as
PROCEDURE print(p_msg VARCHAR2) IS
BEGIN
dbms_output.put_line(p_msg);
END;
PROCEDURE get_emp_prc(p_deptno IN NUMBER, x_emp_tbl  OUT  xx_emp_tbl) IS
CURSOR cur_get_emp_det(pc_deptno NUMBER) IS
SELECT empno,ename,job,mgr,deptno FROM scott.emp where deptno = pc_deptno;
l_emps_tbl    xx_emp_tbl := xx_emp_tbl();
l_emp_obj     xx_emp_obj;
v_empno NUMBER;
i NUMBER;
BEGIN
i:=0;
FOR  r_get_emp_det IN cur_get_emp_det(10) LOOP
l_emp_obj.empno := r_get_emp_det.empno;
l_emp_obj.ename :=  r_get_emp_det.ename;
l_emps_tbl.EXTEND;
i := i+1;
l_emps_tbl(i) := l_emp_obj;
END LOOP;
x_emp_tbl := l_emps_tbl;
END get_emp_prc;
END xx_emp_ret_pkg;Please let me know after passing parameters to packaged procedure how to capture outbound table type parameter and print it to check values ?
Thanks ,
Kiran
Edited by: 911681 on Jan 5, 2013 12:38 AM

Answer 1

Welcome to the forum!
Whenever you post provide your 4 digit Oracle version (result of SELECT * FROM V$VERSION)
>
Please let me know after passing parameters to packaged procedure how to capture outbound table type parameter and print it to check values ?
>
The method I prefer is to use a PIPELINED function rather than expensive PGA memory and having to pass collections around. Then you can just query the function as if it were a table; no special handling or loop required at all.
I'm surprised that Solomon didn't mention this and refer you to his classic reply in this thread
Re: Pipe line function
If you define what you need in a package spec you can use PL/SQL types (e.g. %ROWTYPE) and Oracle will create the actual SQL types for you automagically!
create or replace
    package pkg1
      as
        type emp_table_type is table of emp%rowtype;
        function get_emp(p_deptno number)
          return emp_table_type pipelined;
end;
create or replace
    package body pkg1
      as
        function get_emp(p_deptno number)
          return emp_table_type pipelined is
          begin
              for v_rec in (select * from emp where deptno = p_deptno) loop
                pipe row(v_rec);
              end loop;
          end;
  end;
SQL> select * from table(pk1.get_emp(20))
EMPNO     ENAME     JOB     MGR     HIREDATE     SAL     COMM     DEPTNO
7369     smith     CLERK     7902     12/17/1980     800          20
7566     jones     MANAGER     7839     4/2/1981     2975          20
7788     scott     ANALYST     7566     4/19/1987     3000          20
7876     adams     CLERK     7788     5/23/1987     1100          20
7902     ford     ANALYST     7566     12/3/1981     3000          20If you don't have a table with the columns you need just define a CURSOR in the package spec and base your %ROWTYPE on that
create or replace
    package pkg2
      as
        CURSOR emp_cur is (SELECT empno, ename, job, mgr, deptno FROM emp);
        type pkg_emp_table_type is table of emp_cur%rowtype;
        function get_emp(p_deptno number)
          return pkg_emp_table_type
          pipelined;
  end;
create or replace
    package body pkg2
      as
        function get_emp(p_deptno number)
          return pkg_emp_table_type pipelined is
          begin
              for v_emp_rec in (SELECT empno, ename, job, mgr, deptno
                                FROM emp where deptno = p_deptno) loop
                pipe row(v_emp_rec);
              end loop;
          end;
  end;
  / In both of the above cases the TYPEs are automatically created by Oracle. In 10g they are visible if you query USER_TYPES. But , as Solomon said in his reply:
>
in 11g they are not visible in DBA_TYPES and require select from data dictionary tables sys.type$ and sys.attribute$.
>
If you want to manually create you own types and manually load data into them you can but that is the hard way.
-- type to match emp record
create or replace type emp_scalar_type as object
  (EMPNO NUMBER(4) ,
   ENAME VARCHAR2(10),
   JOB VARCHAR2(9),
   MGR NUMBER(4),
   HIREDATE DATE,
   SAL NUMBER(7, 2),
   COMM NUMBER(7, 2),
   DEPTNO NUMBER(2)
-- table of emp records
create or replace type emp_table_type as table of emp_scalar_type
-- pipelined function
create or replace function get_emp( p_deptno in number )
  return emp_table_type
  PIPELINED
  as
   TYPE EmpCurTyp IS REF CURSOR RETURN emp%ROWTYPE;
    emp_cv EmpCurTyp;
    l_rec  emp%rowtype;
  begin
    open emp_cv for select * from emp where deptno = p_deptno;
    loop
      fetch emp_cv into l_rec;
      exit when (emp_cv%notfound);
      pipe row( emp_scalar_type( l_rec.empno, LOWER(l_rec.ename),
          l_rec.job, l_rec.mgr, l_rec.hiredate, l_rec.sal, l_rec.comm, l_rec.deptno ) );
    end loop;
    return;
  end;
select * from table(get_emp(20))
EMPNO     ENAME     JOB     MGR     HIREDATE     SAL     COMM     DEPTNO
7369     smith     CLERK     7902     12/17/1980     800          20
7566     jones     MANAGER     7839     4/2/1981     2975          20
7788     scott     ANALYST     7566     4/19/1987     3000          20
7876     adams     CLERK     7788     5/23/1987     1100          20
7902     ford     ANALYST     7566     12/3/1981     3000          20