Pointer of structure

Question

Can I get the pointer of a structure. e.g getting pointer of any integer etc maybe I need Marshal class.
Allow time to reverse.

Answer 1

With Marshal.StructureToPtr you can copy your structure to a memory block
(see the VB example in the documentation) and then access the data via pointer represented as an
IntPtr (for example, using Marshal.Copy). If you make some parts in C#, then you will be able to deal with pointers via
unsafe and fixed, which are not available in VB.
Thanks Viorel,
I found my answer that I cannot get the pointer of a structure declared in .net environment. In order to deal with unmanaged structure I made this code:
Imports System.Runtime.InteropServices
Namespace Unmanaged
Public Structure [Object](Of Struct As Structure)
Implements IDisposable, ICloneable, IObject
Private _Pointer As IntPtr
''' <summary>
''' Returns the pointer of structure
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property Pointer As IntPtr Implements IObject.Pointer
Get
Return _Pointer
End Get
End Property
''' <summary>
''' Returns the total size of object.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property Size As Integer Implements IObject.Size
Get
Return Marshal.SizeOf(GetType(Struct))
End Get
End Property
''' <summary>
''' Return the type of structure.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property Type As Type
Get
Return GetType(Struct)
End Get
End Property
''' <summary>
''' Accepts or returns the managed array of bytes.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public Property ManagedBytes As Byte()
Get
Dim bytes(Size - 1) As Byte
Marshal.Copy(_Pointer, bytes, 0, Size)
Return bytes
End Get
Set(value As Byte())
Marshal.Copy(value, 0, _Pointer, Size)
End Set
End Property
''' <summary>
''' Returns the managed value of structure.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public Property Value As Struct
Get
Return Marshal.PtrToStructure(_Pointer, GetType(Struct))
End Get
Set(value As Struct)
Marshal.StructureToPtr(value, _Pointer, True)
End Set
End Property
''' <summary>
''' Returns a copy of unmanaged object. Similar to Clone.
''' </summary>
''' <returns></returns>
''' <remarks></remarks>
Public Function Copy() As [Object](Of Struct)
Dim bytes(Size - 1) As Byte
Marshal.Copy(_Pointer, bytes, 0, Size)
Dim pointer = Marshal.AllocHGlobal(Size)
Marshal.Copy(bytes, 0, pointer, Size)
Erase bytes
Return New [Object](Of Struct)(Intptr:=pointer)
End Function
''' <summary>
''' Copy structure from current pointer to a specific pointer.
''' </summary>
''' <param name="Pointer"></param>
''' <remarks></remarks>
Public Sub CopyTo(Pointer As IntPtr)
Marshal.StructureToPtr(Value, Pointer, True)
End Sub
''' <summary>
''' Copy structure from current pointer to a pointer of specific unmanaged object.
''' </summary>
''' <param name="Obj"></param>
''' <remarks></remarks>
Public Sub CopyTo(Obj As [Object](Of Struct))
Obj.Value = Me.Value
End Sub
''' <summary>
''' Create new unmanaged object that has value of specific managed structure.
''' </summary>
''' <param name="Value"></param>
''' <remarks></remarks>
Sub New(Value As Struct)
_Pointer = Marshal.AllocHGlobal(Marshal.SizeOf(GetType(Struct)))
Marshal.StructureToPtr(Value, _Pointer, True)
End Sub
''' <summary>
''' Converts pointer of structure to unmanaged object.
''' </summary>
''' <param name="Intptr"></param>
''' <remarks></remarks>
Sub New(Intptr As IntPtr)
Me._Pointer = Intptr
End Sub
''' <summary>
''' Creates an unmanaged object at specific pointer having specific value.
''' </summary>
''' <param name="Pointer"></param>
''' <param name="Value"></param>
''' <remarks></remarks>
Sub New(Pointer As IntPtr, Value As Struct)
_Pointer = Pointer
Marshal.StructureToPtr(_Pointer, Pointer, True)
End Sub
Public Shared Narrowing Operator CType(Value As [Object](Of Struct)) As Struct
Return Value.Value
End Operator
Public Shared Narrowing Operator CType(Value As Struct) As [Object](Of Struct)
Return New [Object](Of Struct)(Value)
End Operator
Public Shared Narrowing Operator CType(Obj As [Object](Of Struct)) As IntPtr
Return Obj.Pointer
End Operator
Public Shared Narrowing Operator CType(Pointer As IntPtr) As [Object](Of Struct)
Return New [Object](Of Struct)(Intptr:=Pointer)
End Operator
''' <summary>
''' Create a copy of unmanaged object.
''' </summary>
''' <returns></returns>
''' <remarks></remarks>
Public Function Clone() As Object Implements ICloneable.Clone
Return New [Object](Of Struct)(Me.Value)
End Function
''' <summary>
''' Destroy unmanaged object.
''' </summary>
''' <remarks></remarks>
Public Sub Dispose() Implements IDisposable.Dispose
Marshal.FreeHGlobal(_Pointer)
_Pointer = Nothing
End Sub
End Structure
Public Structure Array(Of Struct As Structure)
Implements IDisposable, ICloneable, IObject, IEnumerable
Private _Pointer As IntPtr
Private Property _Count As Integer
Get
Return Marshal.ReadInt32(_Pointer)
End Get
Set(value As Integer)
Marshal.WriteInt32(_Pointer, value)
End Set
End Property
Public ReadOnly Property Count As Integer
Get
Return _Count
End Get
End Property
Public ReadOnly Property Pointer As IntPtr Implements IObject.Pointer
Get
Return _Pointer
End Get
End Property
Public ReadOnly Property Size As Integer Implements IObject.Size
Get
Return 4 + (Count * StructureSize)
End Get
End Property
Public Property Value As Struct()
Get
Dim array(Count - 1) As Struct
For i = 0 To Count - 1
array(i) = Me(i)
Next
Return array
End Get
Set(value As Struct())
For i = 0 To value.Count - 1
Me(i) = value(i)
Next
End Set
End Property
Public ReadOnly Property StructureType As Type
Get
Return GetType(Struct)
End Get
End Property
Public ReadOnly Property StructureSize As Integer
Get
Return Marshal.SizeOf(StructureType)
End Get
End Property
Public ReadOnly Property ArrayPointer As IntPtr
Get
Return _Pointer + 4
End Get
End Property
Public ReadOnly Property MemberPointer(ID As Integer) As IntPtr
Get
If ID >= Count Then Throw New System.IndexOutOfRangeException()
Return _Pointer + 4 + (Size * ID)
End Get
End Property
Public Property Member(ID As Integer) As [Object](Of Struct)
Get
Return New [Object](Of Struct)(Intptr:=MemberPointer(ID))
End Get
Set(value As [Object](Of Struct))
Dim obj = Member(ID)
obj.Value = value.Value
End Set
End Property
Default Public Property ManagedMember(ID As Integer) As Struct
Get
Dim pointer = MemberPointer(ID)
Return Marshal.PtrToStructure(pointer, GetType(Struct))
End Get
Set(value As Struct)
Dim pointer = MemberPointer(ID)
Marshal.StructureToPtr(value, pointer, True)
End Set
End Property
Public Function Copy() As Array(Of Struct)
Dim bytes(Size - 1) As Byte
Marshal.Copy(_Pointer, bytes, 0, Size)
Dim pointer = Marshal.AllocHGlobal(Size)
Marshal.Copy(bytes, 0, pointer, Size)
Erase bytes
Return New Array(Of Struct)(Pointer:=pointer)
End Function
Sub New(Pointer As IntPtr)
Me._Pointer = Pointer
End Sub
Sub New(Count As Integer)
_Pointer = Marshal.AllocHGlobal(4 + (Count * Marshal.SizeOf(GetType(Struct))))
Me._Count = Count
End Sub
Sub New(Array() As Struct)
Me.New(Array.Count)
Me.Value = Array
End Sub
Public Function Clone() As Object Implements ICloneable.Clone
Return New Array(Of Struct)(Me.Value)
End Function
Public Sub Dispose() Implements IDisposable.Dispose
Marshal.FreeHGlobal(_Pointer)
_Pointer = 0
End Sub
Public Function GetEnumerator() As IEnumerator Implements IEnumerable.GetEnumerator
Return New Enumerator(Me)
End Function
Private Structure Enumerator
Implements IEnumerator
Private _current As Integer
Private _array As Array(Of Struct)
Sub New(Array As Array(Of Struct))
Me._array = Array
_current = 0
End Sub
Public ReadOnly Property Current As Object Implements IEnumerator.Current
Get
Return _array(_current)
End Get
End Property
Public Function MoveNext() As Boolean Implements IEnumerator.MoveNext
_current = _current + 1
Return (_current < _array.Count)
End Function
Public Sub Reset() Implements IEnumerator.Reset
_current = 0
End Sub
End Structure
End Structure
Public Interface IObject
''' <summary>
''' Returns the pointer of structure
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
ReadOnly Property Pointer As IntPtr
''' <summary>
''' Returns the total size of object.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
ReadOnly Property Size As Integer
End Interface
End Namespace
I think I am doing right. Does my array matches the native array?
Allow time to reverse.
I would say NO!
La vida loca