Problem moving files using applescript/folder action setup.

Question

I'm wanting files to move to certain folders depending on what the first letter of the file name. Here is what I have so far. If the file starts with TF715SH it should move to Serenity:Color Images for Monthly:T
property dialog_timeout : 30 -- set the amount of time before dialogs auto-answer.
on adding folder items to this_folder after receiving added_items
    try
        tell application "Finder"
            repeat with this_item in added_items
                if this_item starts with "M" then
                    move this_item to "Serenity:Color Images for Monthly:M:" with replacing
                end if
                if this_item starts with "N" then
                    move this_item to "Serenity:Color Images for Monthly:N:" with replacing
                end if
                if this_item starts with "T" then
                    move this_item to "Serenity:Color Images for Monthly:T:" with replacing
                end if
            end repeat
        end tell
    end try
end adding folder items to

Answer 1

Hi,
Because the class of this_item is a alias wich contains the full path of the file :
You need to get the file name, also you must use the term "folder" before the string "Serenity:Color Images for Monthly:M:", otherwise the Finder will return an error.
if (name of this_item) starts with "M" then
      move this_item to folder "Serenity:Color Images for Monthly:M:" with replacing
end if
Here's another way to do this :
on adding folder items to this_folder after receiving added_items
      tell application "Finder"
            set colorImgFolder to folder "Serenity:Color Images for Monthly:"
            repeat with this_item in added_items
                  set c to first character of (get name of this_item)
                  considering case -- case sensitive
                        if c is in "MNT" then move this_item to folder c of colorImgFolder with replacing
                  end considering
            end repeat
      end tell
end adding folder items to