Problem regarding passing variable in sdo_ordinate_array

Question

I want to pass user selected points in sdo_ordinate array and return result in an array . I have created two varrays in oracle called ALLPOS and LSTPOS.ALLPOS is output array . I get the desired output when i hard cord the values of sd0_ordinate_array but i am not able to pass any variable parameter in sdo_ordinate_array . If i try to pass a string variable i get invalid number exception . If i pass a varray called LSTPOS i get following exception.
FUNCTION FOO(lstpos in LSTPOS) RETURN ALLPOS
AS
POS_DATA ALLPOS := ALLPOS();
CURSOR c_pos is
SELECT cust_id FROM T_S_CUSTOMERS
WHERE SDO_RELATE(geometry,
SDO_GEOMETRY(2003, 8307, NULL,
SDO_ELEM_INFO_ARRAY(1,1003,1),
SDO_ORDINATE_ARRAY(lstpos)),'mask=inside querytype=window') = 'TRUE';
BEGIN
FOR pos_rec IN c_pos LOOP
POS_DATA.extend;
POS_DATA(POS_DATA.count) := pos_rec.cust_id;
END LOOP;
RETURN POS_DATA;
END;
i get following compilation error
Error(9,24): PL/SQL: ORA-00932: inconsistent datatypes: expected NUMBER got BATUSER.LSTPOS
Thanks and Regards
Nidhi

Answer 1

Hi!
I would like you using following with MDSYS.SDO_ORDINATE_ARRAY
definition: [CREATE TYPE mdsys.sdo_elem_info_array AS VARRAY (1048576) of NUMBER]
CREATE OR REPLACE FUNCTION FOO(lstpos in MDSYS.SDO_ORDINATE_ARRAY)
  RETURN MDSYS.SDO_ORDINATE_ARRAY AS
  POS_DATA MDSYS.SDO_ORDINATE_ARRAY := MDSYS.SDO_ORDINATE_ARRAY();
  CURSOR c_pos is
    SELECT cust_id FROM T_S_CUSTOMERS
    WHERE SDO_RELATE(
      geometry,
      MDSYS.SDO_GEOMETRY(2003, 8307, NULL,
        MDSYS.SDO_ELEM_INFO_ARRAY(1,1003,1),
        lstpos
      ),'mask=inside querytype=window'
    ) = 'TRUE';
BEGIN
  FOR pos_rec IN c_pos LOOP
    POS_DATA.extend;
    POS_DATA(POS_DATA.count) := pos_rec.cust_id;
  END LOOP;
  RETURN POS_DATA;
END;
--call the function
declare
  -- Non-scalar parameters require additional processing
  result mdsys.sdo_ordinate_array;
  lstpos mdsys.sdo_ordinate_array := mdsys.sdo_ordinate_array(1,2,3,4);
begin
  -- Call the function
  result := foo(lstpos => lstpos);
end;regards, Andreas