Problem with sequences after import

Question

We recently imported some table data from QA to DEV and now the DEV database has issues with sequences errors. How can I resolve the problem with sequences since we have constraint violation errors as a result of the table sequences being out of sync after the import of several schema tables.

Answer 1

We run a script like the following to get the sequences as close as possible after importing from PROD to DEV:
set serveroutput on;
DECLARE
     CURSOR CUR IS
          SELECT      otherdb_seq.sequence_owner AS owner,
                    otherdb_seq.sequence_name AS seq_nm,
                    TO_CHAR(otherdb_seq.last_number) AS start_nr
          FROM           dba_sequences currdb_seq,
                    dba_sequences@prod otherdb_seq
     WHERE      currdb_seq.sequence_owner IN ('~schemaname~') AND
                    currdb_seq.sequence_owner = otherdb_seq.sequence_owner AND
               currdb_seq.SEQUENCE_NAME = otherdb_seq.sequence_name
          ORDER BY      1, 2;
     sql_string VARCHAR2(500);
BEGIN
     FOR REC IN CUR
     LOOP
     sql_string := 'DROP SEQUENCE '||REC.owner||'.'||REC.seq_nm;
          DBMS_OUTPUT.PUT_LINE(sql_string||';');
          EXECUTE IMMEDIATE sql_string;
          sql_string := 'CREATE SEQUENCE '||REC.owner||'.'||REC.seq_nm;
          sql_string := sql_string ||' START WITH '||REC.start_nr;
          sql_string := sql_string ||' MAXVALUE 999999999999999999999999999';
          sql_string := sql_string ||' MINVALUE '||REC.start_nr;
          sql_string := sql_string ||' NOCYCLE NOCACHE ORDER';
          DBMS_OUTPUT.PUT_LINE(sql_string||';');
          EXECUTE IMMEDIATE sql_string;
          sql_string := 'DROP PUBLIC SYNONYM '||REC.seq_nm;
          DBMS_OUTPUT.PUT_LINE(sql_string||';');
          EXECUTE IMMEDIATE sql_string;
          sql_string := 'CREATE PUBLIC SYNONYM '||REC.seq_nm||' FOR '||REC.owner||'.'||REC.seq_nm;
          DBMS_OUTPUT.PUT_LINE(sql_string||';');
          EXECUTE IMMEDIATE sql_string;
          sql_string := 'GRANT SELECT ON '||REC.owner||'.'||REC.seq_nm||' TO PUBLIC';
          DBMS_OUTPUT.PUT_LINE(sql_string||';');
          EXECUTE IMMEDIATE sql_string;
     END LOOP;
END;