Procedue Table relationship

Question

Procedure-Table relations ship
I am having a oroduction dtabase of around 400 procedures, which uses 250 tables.I want such a script which can produce formate in the form of name of procedure,
table used , mode of table use in I(insertion),U(updation),S(select),D(delete).
like proc A
table t1 i
table t2 d
etc.
Thnaks in advnace,

Answer 1

I imagine there is probably some tool out there that will do the job, but here are a couple of ways to do it, in sql and pl/sql. In the following examples, I have allowed for the possiblities of different case, extra spaces, table prefaced with owner, and commands split between lines. I used a function to remove the extra spaces. If you just need the information and the format is not important, then I would use the SQL. If you need the specific format, then you may want the PL/SQL. I used dbms_output in the PL/SQL example, but you would probably want to use UTL_FILE and output to a file, as the amount of data may exceed the limitations of dmbs_output.
scott@ORA92> -- sample procedures for testing and demonstration:
scott@ORA92> CREATE OR REPLACE PROCEDURE test_proc1
  2  AS
  3  BEGIN
  4    insert       into       scott.dept(deptno) VALUES (1);
  5    UPDATE
  6    dept  SET deptno = 2;
  7  END test_proc1;
  8  /
Procedure created.
scott@ORA92> CREATE OR REPLACE PROCEDURE test_proc2
  2  AS
  3  BEGIN
  4    UPDATE emp SET empno = 2;
  5    DELETE FROM dept;
  6  END test_proc2;
  7  /
Procedure created.
scott@ORA92> CREATE OR REPLACE PROCEDURE test_proc3
  2  AS
  3  BEGIN
  4    DELETE emp;
  5  END test_proc3;
  6  /
Procedure created.
scott@ORA92> -- function used in output:
scott@ORA92> CREATE OR REPLACE FUNCTION remove_extra_spaces
  2    (p_string IN VARCHAR2)
  3    RETURN VARCHAR2
  4  AS
  5    v_string VARCHAR2 (32767);
  6  BEGIN
  7    v_string := REPLACE (LTRIM (RTRIM (REPLACE (p_string, CHR(10), ''))), '     ', ' ');
  8    IF INSTR (v_string, '  ') > 0
  9    THEN
10        RETURN remove_extra_spaces (v_string);
11    ELSE
12        RETURN v_string;
13    END IF;
14  END remove_extra_spaces;
15  /
Function created.
scott@ORA92> -- information you requested:
scott@ORA92> COLUMN tables FORMAT A30
scott@ORA92> COLUMN dml    FORMAT A3
scott@ORA92> SELECT DISTINCT ud.name AS procedures,
  2           ud.referenced_name AS tables,
  3           'i' AS dml
  4  FROM   user_dependencies ud,
  5           (SELECT name, type,
  6                text || ' '
  7                || LEAD (text) OVER (PARTITION BY name, type ORDER BY line) AS text
  8            FROM   user_source
  9            WHERE  type = 'PROCEDURE') us
10  WHERE  ud.type = 'PROCEDURE'
11  AND    ud.referenced_type = 'TABLE'
12  AND    ud.name = us.name
13  AND    (INSTR (remove_extra_spaces (UPPER (us.text)),
14                'INSERT INTO ' || ud.referenced_name) > 0
15            OR INSTR (remove_extra_spaces (UPPER (us.text)),
16                   'INSERT INTO ' || ud.referenced_owner || '.' || ud.referenced_name) > 0)
17  UNION ALL
18  SELECT DISTINCT ud.name AS procedures,
19           ud.referenced_name AS tables,
20           'u' AS dml
21  FROM   user_dependencies ud,
22           (SELECT name, type,
23                text || ' '
24                || LEAD (text) OVER (PARTITION BY name, type ORDER BY line) AS text
25            FROM   user_source
26            WHERE  type = 'PROCEDURE') us
27  WHERE  ud.type = 'PROCEDURE'
28  AND    ud.referenced_type = 'TABLE'
29  AND    ud.name = us.name
30  AND    (INSTR (remove_extra_spaces (UPPER (us.text)),
31                'UPDATE ' || ud.referenced_name) > 0
32            OR INSTR (remove_extra_spaces (UPPER (us.text)),
33                   'UPDATE ' || ud.referenced_owner || '.' || ud.referenced_name) > 0)
34  UNION ALL
35  SELECT DISTINCT ud.name AS procedures,
36           ud.referenced_name AS tables,
37           'd' AS dml
38  FROM   user_dependencies ud,
39           (SELECT name, type,
40                text || ' '
41                || LEAD (text) OVER (PARTITION BY name, type ORDER BY line) AS text
42            FROM   user_source
43            WHERE  type = 'PROCEDURE') us
44  WHERE  ud.type = 'PROCEDURE'
45  AND    ud.referenced_type = 'TABLE'
46  AND    ud.name = us.name
47  AND    (INSTR (remove_extra_spaces (UPPER (us.text)),
48                'DELETE ' || ud.referenced_name) > 0
49            OR INSTR (remove_extra_spaces (UPPER (us.text)),
50                   'DELETE FROM ' || ud.referenced_name) > 0
51            OR INSTR (remove_extra_spaces (UPPER (us.text)),
52                   'DELETE ' || ud.referenced_owner || '.' || ud.referenced_name) > 0
53            OR INSTR (remove_extra_spaces (UPPER (us.text)),
54                   'DELETE FROM ' || ud.referenced_owner || '.' || ud.referenced_name) > 0)
55  ORDER  BY procedures, tables, dml
56  /
PROCEDURES                     TABLES                         DML
TEST_PROC1                     DEPT                           i
TEST_PROC1                     DEPT                           u
TEST_PROC2                     DEPT                           d
TEST_PROC2                     EMP                            u
TEST_PROC3                     EMP                            d
scott@ORA92> --
scott@ORA92> -- output you requested:
scott@ORA92> set serveroutput on size 1000000
scott@ORA92> DECLARE
  2    v_insert VARCHAR2(69);
  3    v_update VARCHAR2(69);
  4    v_delete VARCHAR2(69);
  5    v_text     VARCHAR2(32767);
  6  BEGIN
  7    FOR procedure_rec IN
  8        (SELECT DISTINCT name
  9         FROM      user_dependencies
10         WHERE  type = 'PROCEDURE'
11         AND      referenced_type = 'TABLE'
12         ORDER  BY name)
13    LOOP
14        DBMS_OUTPUT.PUT_LINE ('proc  ' || procedure_rec.name);
15        FOR table_rec IN
16          (SELECT referenced_owner, referenced_name
17           FROM   user_dependencies
18           WHERE  name = procedure_rec.name
19           AND    referenced_type = 'TABLE'
20           ORDER  BY referenced_name)
21        LOOP
22          v_insert := NULL;
23          v_update := NULL;
24          v_delete := NULL;
25          FOR text_rec IN
26            (SELECT UPPER (text) AS text
27             FROM   user_source
28             WHERE  name = procedure_rec.name
29             AND    type = 'PROCEDURE'
30             ORDER  BY line)
31          LOOP
32            v_text := v_text || remove_extra_spaces (text_rec.text);
33            IF INSTR (v_text, 'INSERT INTO ' || table_rec.referenced_name) > 0
34              OR INSTR (v_text, 'INSERT INTO '
35                  || table_rec.referenced_owner || '.' || table_rec.referenced_name) > 0
36            THEN
37              v_insert := 'table ' || table_rec.referenced_name || ' i';
38            END IF;
39            IF INSTR (v_text, 'UPDATE ' || table_rec.referenced_name) > 0
40              OR INSTR (v_text, 'UPDATE '
41                  || table_rec.referenced_owner || '.' || table_rec.referenced_name) > 0
42            THEN
43              v_update := 'table ' || table_rec.referenced_name || ' u';
44            END IF;
45            IF INSTR (v_text, 'DELETE ' || table_rec.referenced_name) > 0
46              OR INSTR (v_text, 'DELETE '
47                  || table_rec.referenced_owner || '.' || table_rec.referenced_name) > 0
48              OR INSTR (v_text, 'DELETE FROM ' || table_rec.referenced_name) > 0
49              OR INSTR (v_text, 'DELETE FROM '
50                  || table_rec.referenced_owner || '.' || table_rec.referenced_name) > 0
51            THEN
52              v_delete := 'table ' || table_rec.referenced_name || ' d';
53            END IF;
54            IF SUBSTR (v_text, -11) = 'INSERT INTO '
55              THEN v_text := 'INSERT INTO ';
56            ELSIF SUBSTR (v_text, -6) = 'INSERT'
57              THEN v_text := 'INSERT ';
58            ELSIF SUBSTR (v_text, -6) = 'UPDATE'
59              THEN v_text := 'UPDATE ';
60            ELSIF SUBSTR (v_text, -6) = 'DELETE'
61              THEN v_text := 'DELETE ';
62            ELSIF SUBSTR (v_text, -11) = 'DELETE FROM'
63              THEN v_text := 'DELETE FROM ';
64            ELSE
65              v_text := NULL;
66            END IF;
67          END LOOP;
68          IF v_insert IS NOT NULL
69          THEN DBMS_OUTPUT.PUT_LINE (v_insert);
70          END IF;
71          IF v_update IS NOT NULL
72          THEN DBMS_OUTPUT.PUT_LINE (v_update);
73          END IF;
74          IF v_delete IS NOT NULL
75          THEN DBMS_OUTPUT.PUT_LINE (v_delete);
76          END IF;
77        END LOOP;
78        DBMS_OUTPUT.PUT_LINE ('------------------------------------');
79    END LOOP;
80  END;
81  /
proc  TEST_PROC1
table DEPT i
table DEPT u
proc  TEST_PROC2
table DEPT d
table EMP u
proc  TEST_PROC3
table EMP d