Program is taking lot of time for execution

Question

Hi all,
TYPES: BEGIN OF TY_MARA,
       MATNR       TYPE  MATNR,         " Material Number
       ZZBASE_CODE TYPE  ZBASE_CODE,    " Base Code
       END OF TY_MARA,
       BEGIN OF TY_MAKT,
       MATNR       TYPE  MATNR,         " Material
       MAKTX       TYPE  MAKTX,         " Material Description
       END OF TY_MAKT,
       BEGIN OF TY_MARC,
       MATNR       TYPE  MATNR ,        " Material Number
       WERKS       TYPE  WERKS_D,      " Plant
       END OF TY_MARC,
       BEGIN OF TY_QMAT,
       MATNR        TYPE  MATNR,         " Material Number
       ART           TYPE  QPART,         " Inspection Type
       END OF TY_QMAT,
       BEGIN OF TY_MAPL,
       MATNR        TYPE  MATNR,        " Material
       PLNTY        TYPE  PLNTY,        " Task List Type
       END OF TY_MAPL,
       BEGIN OF TY_PLKO,
       PLNTY          TYPE     PLNTY,         " Task List Type
       VERWE             TYPE     PLN_VERWE,     "     Task list usage
       END OF TY_PLKO,
       BEGIN OF TY_KLAH,
       CLASS          TYPE    KLASSE_D,       "     Class Number
       END OF TY_KLAH,
       BEGIN OF TY_FINAL,
       MATNR          TYPE    MATNR,          " Material Number
       MAKTX          TYPE    MAKTX,          " Material Description
       ZZBASE_CODE    TYPE    ZBASE_CODE,     " Base Code
       WERKS          TYPE    WERKS_D,        " Plant
       CLASS          TYPE    KLASSE_D,       "     Class Number
       ART             TYPE    QPART,           " Inspection Type
       VERWE             TYPE    PLN_VERWE,       " Task list usage
       MESSAGE        TYPE    STRING,          " Message
       END OF TY_FINAL.
DATA: I_MARA  TYPE  STANDARD TABLE OF TY_MARA  ,
      I_MAKT  TYPE  STANDARD TABLE OF TY_MAKT  ,
      I_MARC  TYPE  STANDARD TABLE OF TY_MARC  ,
      I_QMAT  TYPE  STANDARD TABLE OF TY_QMAT  ,
      I_MAPL  TYPE  STANDARD TABLE OF TY_MAPL  ,
      I_PLKO  TYPE  STANDARD TABLE OF TY_PLKO  ,
      I_KLAH  TYPE  STANDARD TABLE OF TY_KLAH  ,
      I_FINAL TYPE  STANDARD TABLE OF TY_FINAL ,
      WA_MARA  TYPE  TY_MARA,
      WA_MAKT  TYPE  TY_MAKT,
      WA_MARC  TYPE  TY_MARC,
      WA_QMAT  TYPE  TY_QMAT,
      WA_MAPL  TYPE  TY_MAPL,
      WA_PLKO  TYPE  TY_PLKO,
      WA_KLAH  TYPE  TY_KLAH,
      WA_FINAL TYPE  TY_FINAL.
DATA: V_MTART         TYPE    MARA-MTART,
      V_MATNR         TYPE    MARA-MATNR,
      V_ZZBASE_CODE   TYPE    MARA-ZZBASE_CODE,
      V_WERKS         TYPE    T001W-WERKS,
      V_BESKZ         TYPE    MARC-BESKZ.
*selection-screen
SELECTION-SCREEN SKIP 1.
SELECTION-SCREEN BEGIN OF BLOCK B1 WITH FRAME TITLE TEXT-001.
SELECT-OPTIONS: S_MTART    FOR V_MTART DEFAULT 'halb' TO 'zraw',
                S_MATNR    FOR V_MATNR,
                S_ZZBASE   FOR V_ZZBASE_CODE,
                S_WERKS    FOR V_WERKS OBLIGATORY,
                S_BESKZ    FOR V_BESKZ.
SELECTION-SCREEN END OF BLOCK B1.
START-OF-SELECTION.
  SELECT MATNR
         ZZBASE_CODE
         FROM  MARA INTO TABLE I_MARA
         WHERE MTART IN S_MTART       "Material Type
         AND   MATNR IN S_MATNR        "Material
         AND   ZZBASE_CODE IN S_ZZBASE."Base Code
IF NOT I_MARA IS INITIAL.
  SELECT MATNR
         MAKTX
         FROM MAKT INTO TABLE I_MAKT FOR ALL ENTRIES IN I_MARA
         WHERE MATNR = I_MARA-MATNR.
ENDIF.
IF NOT I_MARA IS INITIAL.
  SELECT MATNR
         WERKS
         FROM MARC INTO TABLE I_MARC FOR ALL ENTRIES IN I_MARA
         WHERE MATNR = I_MARA-MATNR
         AND WERKS IN S_WERKS "plant
         AND BESKZ IN S_BESKZ."Procurement Type
ENDIF.
IF NOT I_MARA IS INITIAL.
  SELECT MATNR
         ART
         FROM QMAT INTO TABLE I_QMAT FOR ALL ENTRIES IN I_MARA
         WHERE MATNR = I_MARA-MATNR
         AND WERKS IN S_WERKS.
ENDIF.
IF NOT I_MARA IS INITIAL.
  SELECT MATNR
         PLNTY FROM MAPL INTO TABLE I_MAPL FOR ALL ENTRIES IN I_MARA
         WHERE MATNR = I_MARA-MATNR.
ENDIF.
IF NOT I_MAPL IS INITIAL.
  SELECT PLNTY
         VERWE
         FROM PLKO INTO TABLE I_PLKO FOR ALL ENTRIES IN I_MAPL
         WHERE PLNTY = I_MAPL-PLNTY.
  ENDIF.
  LOOP AT I_MARA INTO WA_MARA.
    CALL FUNCTION 'CLFC_BATCH_ALLOCATION_TO_CLASS'
      EXPORTING
        MATERIAL                  = WA_MARA-MATNR
       PLANT                     =  WA_MARC-WERKS
       CLASSTYPE                 =  '023'
  I_IGNORE_MATMASTER        = ' '
  I_BATCHES_ONLY            =
  I_IGNORE_BUFFER           = ' '
     IMPORTING
  CLASSTYPE                 =
       CLASS                     = WA_KLAH-CLASS
     EXCEPTIONS
       WRONG_FUNCTION_CALL       = 1
       NO_CLASS_FOUND            = 2
       NO_CLASSTYPE_FOUND        = 3
       OTHERS                    = 4 .
*IF SY-SUBRC <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
        WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
*ENDIF.
APPEND WA_KLAH TO I_KLAH.
  ENDLOOP.
  LOOP AT I_MARA INTO WA_MARA.
    WA_FINAL-MATNR       = WA_MARA-MATNR.
    WA_FINAL-ZZBASE_CODE = WA_MARA-ZZBASE_CODE.
    APPEND WA_FINAL TO I_FINAL.
    SORT I_MAKT BY MATNR.
   READ TABLE I_MAKT INTO WA_MAKT WITH KEY MATNR = WA_MARA-MATNR BINARY
   SEARCH.
   IF SY-SUBRC EQ 0.
    WA_FINAL-MAKTX = WA_MAKT-MAKTX.
  ENDIF.
    APPEND WA_FINAL TO I_FINAL.
    SORT I_MARC BY MATNR.
   READ TABLE I_MARC INTO WA_MARC WITH KEY MATNR = WA_MARA-MATNR BINARY
   SEARCH.
   IF SY-SUBRC EQ 0.
    WA_FINAL-WERKS = WA_MARC-WERKS.
  ENDIF.
    APPEND WA_FINAL TO I_FINAL.
    SORT I_QMAT BY MATNR.
   READ TABLE I_QMAT INTO WA_MARC WITH KEY MATNR = WA_MARA-MATNR BINARY
   SEARCH.
   IF SY-SUBRC EQ 0.
    WA_FINAL-ART = WA_QMAT-ART.
ENDIF.
    APPEND WA_FINAL TO I_FINAL.
SORT I_MAPL BY MATNR.
READ TABLE I_MAPL INTO WA_MAPL WITH KEY MATNR = WA_MARA-MATNR BINARY
SEARCH.
IF SY-SUBRC EQ 0.
SORT I_PLKO BY PLNTY.
READ TABLE I_PLKO INTO WA_PLKO WITH KEY PLNTY = WA_MAPL-PLNTY BINARY
SEARCH.
ENDIF.
WA_FINAL-VERWE = WA_PLKO-VERWE.
APPEND WA_FINAL TO I_FINAL.
ENDLOOP.
LOOP AT I_KLAH INTO WA_KLAH.
WA_FINAL-CLASS = WA_KLAH-CLASS.
APPEND WA_FINAL TO I_FINAL.
ENDLOOP.
LOOP AT I_FINAL INTO WA_FINAL.
WRITE:/ WA_FINAL-MATNR,
        WA_FINAL-MAKTX,
        WA_FINAL-ZZBASE_CODE,
        WA_FINAL-WERKS,
        WA_FINAL-CLASS,
        WA_FINAL-ART,
        WA_FINAL-VERWE.
ENDLOOP.
This is my program. it is giving out put.but it is taking lot of time for execution. what might be the porblem.pls let me know.
Thanks,

Answer 1

Hi Mythily,
Try the following code.
TYPES: BEGIN OF ty_mara,
         matnr TYPE matnr, " Material Number
         zzbase_code TYPE zbase_code, " Base Code
       END OF ty_mara,
       BEGIN OF ty_makt,
         matnr TYPE matnr, " Material
         maktx TYPE maktx, " Material Description
       END OF ty_makt,
       BEGIN OF ty_marc,
         matnr TYPE matnr , " Material Number
         werks TYPE werks_d, " Plant
       END OF ty_marc,
       BEGIN OF ty_qmat,
         art   TYPE qpart  , " Inspection Type
         matnr TYPE matnr  , " Material Number
         werks TYPE werks_d, "Plant
       END OF ty_qmat,
       BEGIN OF ty_mapl,
         matnr TYPE matnr    , " Material
         werks TYPE werks_d  , "Plant
         plnty TYPE plnty    , " Task List Type
         plnnr TYPE plnnr    , " Key for Task List Group
         plnal TYPE plnal    , " Group Counter
         zkriz TYPE dzkriz   , " Counter for additional criteria
         zaehl TYPE cim_count, " Internal counter
       END OF ty_mapl,
       BEGIN OF ty_plko,
         plnty TYPE plnty    , " Task List Type
         plnnr TYPE plnnr    , " Key for Task List Group
         plnal TYPE plnal    , " Group Counter
         zaehl TYPE cim_count, " Internal counter
         verwe TYPE pln_verwe, " Task list usage
       END OF ty_plko,
       BEGIN OF ty_klah,
         class TYPE klasse_d, " Class Number
       END OF ty_klah,
       BEGIN OF ty_final,
         matnr TYPE matnr, " Material Number
         maktx TYPE maktx, " Material Description
         zzbase_code TYPE zbase_code, " Base Code
         werks TYPE werks_d, " Plant
         class TYPE klasse_d, " Class Number
         art TYPE qpart, " Inspection Type
         verwe TYPE pln_verwe, " Task list usage
         message TYPE string, " Message
       END OF ty_final.
DATA: i_mara     TYPE STANDARD TABLE OF ty_mara ,
      i_makt     TYPE HASHED   TABLE OF ty_makt
        WITH UNIQUE KEY matnr,
      i_marc     TYPE SORTED   TABLE OF ty_marc
        WITH NON-UNIQUE KEY matnr,
      i_qmat     TYPE SORTED   TABLE OF ty_qmat
        WITH NON-UNIQUE KEY matnr werks,
      i_mapl     TYPE SORTED   TABLE OF ty_mapl
        WITH NON-UNIQUE KEY matnr werks,
      i_mapl_tmp TYPE STANDARD TABLE OF ty_mapl ,
      i_plko     TYPE SORTED   TABLE OF ty_plko
        WITH NON-UNIQUE KEY plnty
                            plnnr
                            plnal,
      i_final    TYPE STANDARD TABLE OF ty_final,
      wa_mara TYPE ty_mara,
      wa_makt TYPE ty_makt,
      wa_marc TYPE ty_marc,
      wa_qmat TYPE ty_qmat,
      wa_mapl TYPE ty_mapl,
      wa_plko TYPE ty_plko,
      wa_klah TYPE ty_klah,
      wa_final TYPE ty_final.
DATA: v_mtart TYPE mara-mtart,
      v_matnr TYPE mara-matnr,
      v_zzbase_code TYPE mara-zzbase_code,
      v_werks TYPE t001w-werks,
      v_beskz TYPE marc-beskz.
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
SELECT-OPTIONS: s_mtart FOR v_mtart DEFAULT 'halb' TO 'zraw',
                s_matnr FOR v_matnr,
                s_zzbase FOR v_zzbase_code,
                s_werks FOR v_werks OBLIGATORY,
                s_beskz FOR v_beskz.
SELECTION-SCREEN END OF BLOCK b1.
START-OF-SELECTION.
  SELECT matnr
         zzbase_code
    FROM mara
    INTO TABLE i_mara
    WHERE mtart       IN s_mtart "Material Type
    AND   matnr       IN s_matnr. "Material
    AND   zzbase_code IN s_zzbase."Base Code
  IF NOT i_mara[] IS INITIAL.
    SELECT matnr
           maktx
      FROM makt
      INTO TABLE i_makt
      FOR ALL ENTRIES IN i_mara
      WHERE matnr EQ i_mara-matnr
      AND   spras EQ sy-langu.
    SELECT matnr
           werks
      FROM marc
      INTO TABLE i_marc
      FOR ALL ENTRIES IN i_mara
      WHERE matnr EQ i_mara-matnr
      AND   werks IN s_werks "plant
      AND   beskz IN s_beskz."Procurement Type
    IF sy-subrc EQ 0.
      SELECT art
             matnr
             werks
        FROM qmat
        INTO TABLE i_qmat
        FOR ALL ENTRIES IN i_marc
        WHERE matnr EQ i_marc-matnr
        AND   werks EQ i_marc-werks.
      SELECT matnr
             werks
             plnty
             plnnr
             plnal
             zkriz
             zaehl
        FROM mapl
        INTO TABLE i_mapl
        FOR ALL ENTRIES IN i_marc
        WHERE matnr EQ i_marc-matnr
        AND   werks EQ i_marc-werks.
      IF NOT i_mapl[] IS INITIAL.
        i_mapl_tmp[] = i_mapl[].
        SORT i_mapl_tmp BY plnty
                           plnnr
                           plnal.
        DELETE ADJACENT DUPLICATES FROM i_mapl_tmp
          COMPARING
            plnty
            plnnr
            plnal.
        SELECT plnty
               plnnr
               plnal
               zaehl
               verwe
          FROM plko
          INTO TABLE i_plko
          FOR ALL ENTRIES IN i_mapl_tmp
          WHERE plnty EQ i_mapl_tmp-plnty
          AND   plnnr EQ i_mapl_tmp-plnnr
          AND   plnal EQ i_mapl_tmp-plnal.
      ENDIF.
    ENDIF.
  ENDIF.
  LOOP AT i_mara INTO wa_mara.
    wa_final-matnr       = wa_mara-matnr.
    wa_final-zzbase_code = wa_mara-zzbase_code.
    READ TABLE i_makt INTO wa_makt
      WITH KEY matnr = wa_mara-matnr
      TRANSPORTING
        maktx.
    IF sy-subrc EQ 0.
      wa_final-maktx = wa_makt-maktx.
    ENDIF.
    REFRESH i_final.
    LOOP AT i_marc INTO wa_marc
      WHERE matnr EQ wa_mara-matnr.
      CLEAR wa_klah-class.
      CALL FUNCTION 'CLFC_BATCH_ALLOCATION_TO_CLASS'
        EXPORTING
          material            = wa_mara-matnr
          plant               = wa_marc-werks
          classtype           = '023'
        IMPORTING
          class               = wa_klah-class
        EXCEPTIONS
          wrong_function_call = 1
          no_class_found      = 2
          no_classtype_found  = 3
          OTHERS              = 4.
      IF sy-subrc EQ 0.
        wa_final-class = wa_klah-class.
      ENDIF.
      READ TABLE i_qmat
        WITH KEY matnr = wa_mara-matnr
                 werks = wa_marc-werks
                 TRANSPORTING NO FIELDS.
      IF sy-subrc EQ 0.
        LOOP AT i_qmat INTO wa_qmat
          WHERE matnr EQ wa_mara-matnr
          AND   werks EQ wa_marc-werks.
          wa_final-art = wa_qmat-art.
          READ TABLE i_mapl
            WITH KEY matnr = wa_marc-matnr
                     werks = wa_marc-werks
                     TRANSPORTING NO FIELDS.
          IF sy-subrc EQ 0.
            LOOP AT i_mapl INTO wa_mapl
              WHERE matnr EQ wa_marc-matnr
              AND   werks EQ wa_marc-werks.
              LOOP AT i_plko INTO wa_plko
                WHERE plnty EQ wa_mapl-plnty
                AND   plnnr EQ wa_mapl-plnnr
                AND   plnal EQ wa_mapl-plnal.
                wa_final-verwe = wa_plko-verwe.
                APPEND wa_final TO i_final.
              ENDLOOP.
            ENDLOOP.
          ELSE.
            APPEND wa_final TO i_final.
          ENDIF.
        ENDLOOP.
      ELSE.
        LOOP AT i_mapl INTO wa_mapl
          WHERE matnr EQ wa_marc-matnr
          AND   werks EQ wa_marc-werks.
          LOOP AT i_plko INTO wa_plko
            WHERE plnty EQ wa_mapl-plnty
            AND   plnnr EQ wa_mapl-plnnr
            AND   plnal EQ wa_mapl-plnal.
            wa_final-verwe = wa_plko-verwe.
            APPEND wa_final TO i_final.
          ENDLOOP.
        ENDLOOP.
      ENDIF.
    ENDLOOP.
    CLEAR wa_final.
  ENDLOOP.
  LOOP AT i_final INTO wa_final.
    WRITE:/ wa_final-matnr      ,
            wa_final-maktx      ,
            wa_final-zzbase_code,
            wa_final-werks      ,
            wa_final-class      ,
            wa_final-art        ,
            wa_final-verwe      .
  ENDLOOP.