Prompting user for their choice of mailbox in Mail.app

Question

All I want to do is ask the user to choose a mailbox in Mail.app. But, there is a problem:
"mailbox Y of account X" shows
mailbox "FULL/PATH/TO/Y" of account X of application "Mail"
while "name of mailbox Y of account X" shows
"Y"
This makes it awfully hard to prompt users for their choice of mailbox. I could go up the containers of mailbox Y, until I get to account, but this takes quite a long time.
Is there a good reason for this behavior of the "name" property?

Answer 1

Similar to Hiroto - 'I'm not sure what you're looking after.'
Thus, below is some sample code to work with:
tell application "Mail"
set tMailboxes to mailboxes of account "sl-ugs" -- Obtain mailboxes of specific account.
set nList to {} -- List to contain mailboxes names.
repeat with i in tMailboxes -- Cycle through mailboxes of specific account.
copy (name of i) to end of nList -- The name of each mailbox is placed into 'nList'.
end repeat
-- Provide an interface for the user to select a desired mailbox.
set tSelection to (choose from list nList without multiple selections allowed and empty selection allowed) as string
repeat with i from 1 to (count tMailboxes) -- Cycle through the list of mailboxes.
if ((item i of nList) is equal to tSelection) then exit repeat -- Determine list location of selected mailbox (in 'tMailboxes')
end repeat
set tMailbox to item i of tMailboxes -- Obtain full listing of selected mailbox
set tMessages to messages of tMailbox -- The messages of the selected mailbox.
set mList to {} -- List to contain 'subject', 'from' and 'date received' field items of each message of the selected mailbox.
repeat with j in tMessages -- Cycle through the list of messages.
-- The 'subject', 'from', and 'date received' field items of each message of the selected mailbox are placed into 'mList'.
tell j to copy {subject, sender, date received} to end of mList
end repeat
-- Example code showing 'tMailbox', 'nList', 'tSelection', list location of selected mailbox, messages of 'tMailbox', and finally - the 'subject', 'from', and 'date received' field items of each message of 'tMailbox'.
tMailboxes & return & return & nList & return & return & tSelection & return & return & i & return & return & (messages of tMailbox) & return & return & mList
end tell