Reading archived data of different archive objects in Z programs

Question

Hi,
   I have Z programs which are getting data from various tables. Now i needt to read archived data of those tables in my Z programs also. i.e. i need to modify those programs so that data archived for those tables should also be extracted. Now for exmple if the program is fetching data from MARA, EKKO, LIKP, KONP tables based on certain selection criteria, then how do i fetch archived data for same criteria as each of these tables may belong to different archive objects ? Please help me. Thanks in advance.

Answer 1

Hie Naganath
Using transaction SARA you can identify the archive objects for the tables you want to use. 
For material master you can use object MM_MATNR, for Purchasing documents use object MM_EKKO, for conditions use SD_COND and for deliveries use object RV_LIKP.
Retrieve the archive key and offset from table ZARIXMM5 (for Purchasing documents) for your select options and pass the offset and key to function ARCHIVE_READ_OBJECT to get the handle and then pass the handle to function ARCHIVE_GET_TABLE to read the record.  Have a look at the below code
select archivekey archiveofs into corresponding fields of table lt_arch_keys
               from zarixsd1 "SD Index table for billing documents
              where vbeln in s_docrng
                and kunrg in s_arc_kn
                and fkdat in s_arc_dt
                and fkart in s_arc_rt
                and vkorg in s_arc_og.
  loop at lt_arch_keys assigning <fs_lt_arch_keys>.
*Read information from archive
    call function 'ARCHIVE_READ_OBJECT'
      exporting
        object         = 'SD_VBRK'
        archivkey      = <fs_lt_arch_keys>-archivekey
        offset         = <fs_lt_arch_keys>-archiveofs
      importing
        archive_handle = ls_handle
      exceptions
        others         = 1.
*Get the requested header detail data for billing document
    call function 'ARCHIVE_GET_TABLE'
      exporting
        archive_handle          = ls_handle
        record_structure        = 'VBRK'
        all_records_of_object   = 'X'
        automatic_conversion    = 'X'
      tables
        table                   = lt_vbrk "Header data
      exceptions
        end_of_object           = 1
        internal_error          = 2
        wrong_access_to_archive = 3
        others                  = 4.
*Get the requested line item detail data for billing document
    call function 'ARCHIVE_GET_TABLE'
      exporting
        archive_handle          = ls_handle
        record_structure        = 'VBRP'
        all_records_of_object   = 'X'
        automatic_conversion    = 'X'
      tables
        table                   = lt_vbrp "Line item data
      exceptions
        end_of_object           = 1
        internal_error          = 2
        wrong_access_to_archive = 3
        others                  = 4.
    clear: ls_vbrk.
    loop at lt_vbrp assigning <fs_lt_vbrp>.
      read table lt_vbrk into ls_vbrk with key vbeln = <fs_lt_vbrp>-vbeln.
      move-corresponding <fs_lt_vbrp> to lt_archive_records.
      move-corresponding ls_vbrk to lt_archive_records.
      append lt_archive_records to gt_archive_records.
    endloop.
  endloop.
Do the same for your material master and condition records as well.
regards
Isaac Prince