Reading URL parameters in ABAP webdynpro

Question

I have a requirements to run my ABAP Webdynpro application view based on two parameters passed to it from portal. How can I read the parameters in ABAP webdynpro and use them to write my condition in the run time. I would appreciate it if someone has any code that would help me also.
Again your help and support is highly appreciated.
Lily

Answer 1

Hi Lily,
To read the URL parameters, you need to right the following code in the HANDLEDEFAULT method
of the your default window controller.
DATA : it_parameter TYPE tihttpnvp,
         wa_parameter  TYPE ihttpnvp.
  DATA lo_nd_url_param TYPE REF TO if_wd_context_node.
  DATA ls_url_param TYPE wd_this->element_url_param.
  " Get all URL parameters
  CALL METHOD wdevent->get_data
    EXPORTING
      name  = if_wd_application=>all_url_parameters
    IMPORTING
      value = it_parameter.
  " Get parameter values
  CLEAR wa_parameter.
  READ TABLE it_parameter WITH KEY name = 'PERNR' INTO wa_parameter.
  IF sy-subrc EQ 0.
    ls_url_param-pernr = wa_parameter-value.
  ENDIF.
  CLEAR wa_parameter.
  READ TABLE it_parameter WITH KEY name = 'SUBTY' INTO wa_parameter.
  IF sy-subrc EQ 0.
    ls_url_param-subty = wa_parameter-value.
  ENDIF.
  CLEAR wa_parameter.
  READ TABLE it_parameter WITH KEY name = 'BEGDA' INTO wa_parameter.
  IF sy-subrc EQ 0.
    ls_url_param-begda = wa_parameter-value.
  ENDIF.
  CLEAR wa_parameter.
  READ TABLE it_parameter WITH KEY name = 'ZZPRNTOPT' INTO wa_parameter.
  IF sy-subrc EQ 0.
    ls_url_param-zzprntopt = wa_parameter-value.
  ENDIF.
  " Save URL parameter to context
  lo_nd_url_param = wd_context->get_child_node( name = wd_this->wdctx_url_param ).
  lo_nd_url_param->set_static_attributes(
     static_attributes = ls_url_param ).
Regards,
Vikrant