Received error when using Execute_Immediate proc in Oracle 8.0

Question

Hi,
I was trying to use the execute_immediate proc (slightly
revised, for testing). When I run it with a 'Delete' statement
in it (or passed in), it works fine. But, when I use
an 'Update' or 'Insert' statement in it, I get the error below,
even though the proc compiled okay and it's in the database okay.
SQL> exec Exec_Immed;
begin Exec_Immed; end;
ERROR at line 1:
ORA-06550: line 1, column 7:
PLS-00905: object TEST.EXEC_IMMED is invalid
ORA-06550: line 1, column 7:
PL/SQL: Statement ignored
I tried using both the SQL stmts below (one at a time), but got
the same error.
CREATE OR REPLACE PROCEDURE Exec_Immed /*(v_SQLStmt IN VARCHAR2)
IS
v_CursorID INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
v_SQLStmt VARCHAR2(100);
v_RetRows INTEGER;
BEGIN
v_SQLStmt := 'Update emp SET fname = ''David'' WHERE empno =
40';
v_SQLStmt := 'Insert into softlookup
(softno,softname,updatedon,updatetype) values
(50,''VS7'',sysdate,''A'')';
DBMS_SQL.PARSE (v_CursorID, v_sqlstmt, DBMS_SQL.native);
v_RetRows := DBMS_SQL.EXECUTE(v_CursorID);
DBMS_SQL.CLOSE_CURSOR(v_CursorID);
END;

Answer 1

The simplest way to do what you are doing is to use a SQL
statement by itself, either from the SQL prompt or from a .sql
file:
SQL> Update emp
  2  SET    ename = 'David'
  3  WHERE  empno = 40
  4  /
0 rows updated.
SQL> Insert into softlookup
  2    (softno,softname,updatedon,updatetype)
  3  values (50,'VS7',sysdate,'A')
  4  /
1 row created.
Or, if you want to do it from an anonymous pl/sql block:
SQL> BEGIN
  2    Update emp
  3    SET    ename = 'David'
  4    WHERE  empno = 40;
  5    Insert into softlookup
  6      (softno,softname,updatedon,updatetype)
  7    values (50,'VS7',sysdate,'A');
  8  END;
  9  /
PL/SQL procedure successfully completed.
Or, if you want to do it in a procedure:
SQL> CREATE OR REPLACE PROCEDURE procedure_name
  2  AS
  3  BEGIN
  4    Update emp
  5    SET    ename = 'David'
  6    WHERE  empno = 40;
  7    Insert into softlookup
  8      (softno,softname,updatedon,updatetype)
  9    values (50,'VS7',sysdate,'A');
10  END procedure_name;
11  /
Procedure created.
SQL> EXEC procedure_name
PL/SQL procedure successfully completed.
If you want to use DBMS_SQL to do it, even though it is
unnecessary:
SQL> CREATE OR REPLACE PROCEDURE procedure_name
  2  IS
  3    v_CursorID        INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
  4    v_RetRows         INTEGER;
  5    v_SQLStmt         VARCHAR2 (4000);
  6  BEGIN
  7    v_SQLStmt := 'Update emp
  8                 SET    ename = ''David''
  9                 WHERE  empno = 40';
10    DBMS_OUTPUT.PUT_LINE (v_SQLStmt);
11    DBMS_SQL.PARSE (v_CursorID, v_SQLStmt, DBMS_SQL.NATIVE);
12    v_RetRows := DBMS_SQL.EXECUTE (v_CursorID);
13    DBMS_SQL.CLOSE_CURSOR (v_CursorID);
14    v_SQLStmt := 'Insert into softlookup '
15               || ' (softno,softname,updatedon,updatetype) '
16             || ' values (50,''VS7'',sysdate,''A'')';
17    v_CursorID := DBMS_SQL.OPEN_CURSOR;
18    DBMS_OUTPUT.PUT_LINE (v_SQLStmt);
19    DBMS_SQL.PARSE (v_CursorID, v_SQLStmt, DBMS_SQL.NATIVE);
20    v_RetRows := DBMS_SQL.EXECUTE (v_CursorID);
21    DBMS_SQL.CLOSE_CURSOR (v_CursorID);
22  END procedure_name;
23  /
Procedure created.
SQL> EXEC procedure_name
Update emp
               SET    ename = 'David'
               WHERE  empno =
40
Insert into softlookup  (softno,softname,updatedon,updatetype) 
values
(50,'VS7',sysdate,'A')
PL/SQL procedure successfully completed.
Since you are using Oracle 8.0 and cannot use EXECUTE IMMEDIATE,
if you want to use some variation, which is also unnecessary,
then you can do something like I have shown below.  Note that
the Exec_Immed procedure needs to be a procedure all by itself
and not be modified.  Otherwise, you are defeating the purpose
of substituting it for EXECUTE IMMEDIATE and not having to
duplicate code.  The idea of using the Exec_Immed is to only
create that procedure which contains all of the DBMS_SQL once,
then use the really simple code below that to execute SQL
statements from a pl/sql block.  If you are going to modify it,
then you might as well use the DBMS_SQL method listed above.  In
the version below, I have used the variable names and so forth
that you have substituted for the original, as much as possible:
SQL> CREATE OR REPLACE PROCEDURE Exec_Immed
  2    (v_SQLStmt IN VARCHAR2)
  3  IS
  4    v_CursorID       INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
  5    v_RetRows        INTEGER;
  6  BEGIN
  7    DBMS_SQL.PARSE (v_CursorID, v_SQLStmt, DBMS_SQL.NATIVE);
  8    v_RetRows := DBMS_SQL.EXECUTE (v_CursorID);
  9    DBMS_SQL.CLOSE_CURSOR (v_CursorID);
10  END Exec_Immed;
11  /
Procedure created.
Then, to use your Exec_Immed procedure from an anonymous pl/sql
block:
SQL> BEGIN
  2    Exec_Immed ('Update emp
  3                 SET    ename = ''David''
  4                 WHERE  empno = 40');
  5    Exec_Immed ('Insert into softlookup
  6                   (softno,softname,updatedon,updatetype)
  7                 values (50,''VS7'',sysdate,''A'')');
  8  END;
  9  /
PL/SQL procedure successfully completed.
Or, to call your Exec_Immed procedure from another procedure:
SQL> CREATE OR REPLACE PROCEDURE procedure_name
  2  AS
  3  BEGIN
  4    Exec_Immed ('Update emp
  5                 SET    ename = ''David''
  6                 WHERE  empno = 40');
  7    Exec_Immed ('Insert into softlookup
  8                   (softno,softname,updatedon,updatetype)
  9                 values (50,''VS7'',sysdate,''A'')');
10  END procedure_name;
11  /
Procedure created.
SQL> EXEC procedure_name
PL/SQL procedure successfully completed.