Record level lock on SAP ABAP table editing

Question

Hello All,
I have a requirement wherein I need to give users ability to be able to update contents of a table. Currently, there are using maintenance view on the table for adding/editing contents of this table. However, this prevents other users from being able to enter the table and edit contents of other records within the table.
Can anybody please guide me how do I go about giving record level edit lock on the table instead of entire table edit lock.
Appreciate all responses.
Thanks and Regards,
Samta.

Answer 1

Ok
I  have had a request like yours, i.e the users could manage the same table in the same time.
The standard behavior avoids it, because a lock of entire table is set.
This was my solution:
A) I've created a maintenance view for my table, and I set the attibute S (for subset) for all fields will be the key I want to lock.
B) I've generated the maintenance table program for the view above.
In this way if it try to manage the view by SM30, it'll be possible only to indicate the  values of the fields for the subset, so not all data of the table will be loaded, but only the records satisfying  the key.
C) I've created a program to run SM30 for my view, using the fm VIEW_MAINTENANCE_CALL:
.CALL FUNCTION 'VIEW_MAINTENANCE_CALL'
       EXPORTING
            action      = 'S'  "Display mode
            view_name   = <table name>
       TABLES
            dba_sellist = tb_sellist
       EXCEPTIONS
            OTHERS      = 14.
As you can see above, the SM30 is always called for DISPLAY only, in this way no standard lock is set
D) I've use the event 19 in order to change the mode and set my lock:
DATA: BEGIN OF MY_LOCK,
          MANDT       TYPE ZPPTA019-MANDT,
          WERKS       TYPE ZPPTA019-WERKS,
          /TRILOG/SE  TYPE ZPPTA019-/TRILOG/SE,
          COD_MOD_TAG TYPE ZPPTA019-COD_MOD_TAG,
        END OF MY_LOCK.
  DATA: W_SEL_LIST TYPE VIMSELLIST.
  DATA: VARKEY TYPE RSTABLE-VARKEY.
  FIELD-SYMBOLS: <MY_KEY> TYPE ANY.
  LOOP AT DBA_SELLIST INTO W_SEL_LIST
    WHERE VIEWFIELD = 'WERKS'
      OR  VIEWFIELD = '/TRILOG/SE'
      OR  VIEWFIELD = 'COD_MOD_TAG'.
    ASSIGN COMPONENT W_SEL_LIST-VIEWFIELD
       OF STRUCTURE MY_LOCK TO <MY_KEY>.
    IF SY-SUBRC = 0.
      MOVE W_SEL_LIST-VALUE TO <MY_KEY>.
    ENDIF.
  ENDLOOP.
  IF SY-SUBRC = 0.
    IF NOT MY_LOCK IS INITIAL.
      MY_LOCK-MANDT = SY-MANDT.
      VARKEY = MY_LOCK.
      CALL FUNCTION 'ENQUEUE_E_TABLEE'
        EXPORTING
          MODE_RSTABLE   = 'E'
          TABNAME        = 'ZPPTA019'
          VARKEY         = VARKEY
        EXCEPTIONS
          FOREIGN_LOCK   = 1
          SYSTEM_FAILURE = 2
          OTHERS         = 3.
      IF SY-SUBRC <> 0.
        MESSAGE ID SY-MSGID TYPE 'S' NUMBER SY-MSGNO
                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ELSE.
        MAINT_MODE = VIEW_ACTION = 'U'.
      ENDIF.
    ENDIF.
  ENDIF.
  CLEAR OLD_019.
I hope it can help you
Max