Reg. Converting a package level cursor into a Ref cursor

Question

Hi Guru's,
I am in need of converting a package level cursor which contains "FOR UPDATE OF" clause into a Ref cursor where the query will be dynamically built in with the needed table name and other parameters.
Using that cursor many Update statement's were performed with "WHERE CURRENT OF" clause included in it.
Now I changed my cursor into Ref cursor, but when i compile the cursor that is built dynamical is not identified, since i am getting error.
Can any one tell me how to proceed in order to implement it?
Do I need only go for dynamic bulding of the whole procedure.
With Best Regards,
Vijayasekaran.N

Answer 1

May be you can work it around with ROWID. Like this
Say this is your actual code.
declare
     cursor c
     is
     select *
       from t
        for update of name;
     lno t.no%type;
     lname t.name%type;
begin
     open c;
     loop
          fetch c into lno, lname;
          exit when c%notfound;
          update t set name = lno||lname
           where current of c;
     end loop;
     close c;
end;
/With refcursor you can do this.
declare
     type rc is ref cursor;
     c rc;
     lno t.no%type;
     lname t.name%type;
     lrowid rowid;
begin
     open c for 'select rowid rid, t.*
               from t
                for update of name';
     loop
          fetch c into lrowid,lno, lname;
          exit when c%notfound;
          update t set name = lno||lname
           where rowid = lrowid;
     end loop;
     close c;
end;
/Edited by: Karthick_Arp on Dec 26, 2008 2:00 AM