Rename and Delete Files

Question

Hi everyones, i'm new to this forum and to applescript
i need help to make a little script. i got a folder that look like this :
FOLDER_TOP
--FOLDER_1111a
-----AAAAA_1.jpg
-----BBBBB_2.jpg
-----PHOTO_3.jpg
--FOLDER_2222b
-----ABCDE_111.jpg
-----BBBB_233.jpg
-----PHOTO_456.jpg
The folder FOLDER_TOP can contain hundred of subfolder like FOLDER_1111a and FOLDER_2222b and each subfolder contain a lot of photos like AAAAA_1.jpg, BBBBB_2.jpg and PHOTO_3.jpg
I need to be able to rename the first photo of each subfolder by the name of the subfolder and delete the remaining ones (AAAAA_1.jpg must became FOLDER_1111a.jpg. BBBBB_2.jpg and PHOTO_3.jpg must be deleted)
Many thanks for yours help
Message was edited by: BOBaGINETTE

Answer 1

Hello
You're quite welcome. Glad to hear it works well so far.
As for variable extension, are you trying to do this? -
Provided a subfolder is named 'ddd' and its 1st file in lexical order is named 'mmm.eee' (mmm is a name stem and eee is a name extension), you are to rename the 1st file as 'ddd.eee' regardless of what the 'eee' is.
If so, try the following script.
I also revised the code a bit so that it can now properly handle the cases where less than 2 files is in a subfolder.
Hope this may help,
H
--SCRIPT b
main()
on main()
script o
property dd : {}
property ff : {}
property mss0 : "Choose top folder."
property mss1 : "You're processing items in tree rooted at:" & return & return
property mss2 : "Done."
set d0 to choose folder with prompt mss0
display dialog mss1 & d0 with icon 1
tell application "Finder"
try
set dd to d0's folders as alias list
on error from erob -- optional (not required) under OSX 10.5 or later
set dd to erob as alias as list
end try
end tell
repeat with d in my dd
set d to d's contents
tell application "Finder"
set ff to (d's files) as list
if ff is not {} then
set ff to (sort ff by name) as list -- optional if Finder always gets items in lexical order
set f1 to my ff's item 1
set e1 to f1's name extension
if e1 is not "" then set e1 to "." & e1
set f1's name to d's name & e1
set ff to my ff's rest
if ff is not {} then delete ff
end if
end tell
end repeat
display dialog mss2 with icon 1 giving up after 2
end script
tell o to run
end main
--END OF SCRIPT b