Renaming Existing Member Names

Question

We are trying to do a long list of outline Member name changes (~200 changes) for Level 0 or Parent Level members and noticed the API function ESBOTLRENAMEMEMBER . It looks like this could be used by others and have seen several Threads in OTN talking about the function, but I haven't seen any posts pointing to a working Excel VBA to do a Find/Replace with this function. Can Anyone point to a working VBA code to do a find/ replace?
what I am trying to do is have a worksheet with a "Original Names" and a column with "New Names" and have the code to a loop through the list.
This sounds like a basic task that many folks could use. Does anyone have something similar that they have created?
Thanks ahead of time!
Robert

Answer 1

I was doing exactly this recently with a 9.3.1 ASO cube. The forum will screw up the formatting but you can probably work out what's going on. Note the ???? placeholder for the number of lines and placeholders for APPNAME etc. This is very basic and features no error trapping - it was for a one time deal in a development environment, not regular and / or production use.
Any use is entirely at your own risk.
Good luck!
============================
Public Sub UpdateOutline()
Dim Init As ESB_INIT_T
Dim ObjDef As ESB_OBJDEF_T
Dim ProcState As ESB_PROCSTATE_T
Dim lngCount As Long
Dim strOldName As String
Dim strNewName As String
Dim lngInst As Long
Dim lngCtx As Long
Dim lngStatus As Long
Dim lngOutline As Long
Dim lngMember As Long
Dim intItems As Integer
'Init API
Init.Version = ESB_API_VERSION
lngStatus = EsbInit(Init, lngInst)
'Log in
lngStatus = EsbLogin(lngInst, "SERVER", "USERNAME", "PASSWORD", intItems, lngCtx)
'Open the outline
lngStatus = EsbSetActive(lngCtx, "APPNAME", "DBNAME", intItems)
With ObjDef
.AppName = "APPNAME"
.DbName = "DBNAME"
.FileName = "DBNAME"
.hCtx = lngCtx
.Type = ESB_OBJTYPE_OUTLINE
End With
lngStatus = EsbOtlOpenOutline(lngCtx, ObjDef, ESB_YES, ESB_YES, lngOutline)
'Loop through all members in the sheet
For lngCount = 1 To ????
strNewName = ActiveSheet.Cells(lngCount, 1)
strOldName = ActiveSheet.Cells(lngCount, 2)
lngStatus = EsbOtlFindMember(lngOutline, strOldName, lngMember)
lngStatus = EsbOtlRenameMember(lngOutline, lngMember, strNewName)
Next
'Write the outline
lngStatus = EsbOtlWriteOutline(lngOutline, ObjDef)
'Restructure
lngStatus = EsbOtlRestructure(lngCtx, ESB_DOR_ALLDATA)
'Call EsbGetProcessState until completed
lngStatus = EsbGetProcessState(lngCtx, ProcState)
While ProcState.State <> ESB_STATE_DONE
     Application.Wait DateAdd("s", 10, Now())
     lngStatus = EsbGetProcessState(lngCtx, ProcState)
Wend
'Unlock the outline
lngStatus = EsbUnlockObject(lngCtx, ESB_OBJTYPE_OUTLINE, "APPNAME", "DBNAME", "DBNAME")
'Close the outline
lngStatus = EsbOtlCloseOutline(lngOutline)
'Log out of server
lngStatus = EsbLogout(lngCtx)
'Terminate API instance
lngStatus = EsbTerm(lngInst)
End Sub