Replace pages in a PDF with acrobat

Question

Please help me find a solution for my problem, i believe there are many good Applescript gurus here, i´m not one of them!:)
Basic needs:
i have a pdf coming from a text and picture system and i want it to merge to a templet with buttons and functionality.
same amount of pages to replace every time.
If i do this in Acrobat 8 i just open my template, i go to Document->Replace Pages, selected replace from 1-24 and execute.
Is this possible in applescript? i can se the argument in the Acrobat Library, but i don´t know how!
Please post a solution if you can.
Best regards
Inge

Answer 1

Hello Inge Eidem,
If I'm not much mistaken about your intention, the following script may help.
A few things.
• I'm not sure but you seem to be deleting the template 'ipdfmal.pdf' every time the folder action is triggered and I presume that it's probably not your intention, so I modified the code a bit. (It would now delete the finished source files, that are dropped files in the folder where the folder action is attached, when you enable the corresponding lines which I currently commented out)
• The tempalte file is to be found at templateFdPath and the finished files are to be saved in finishedFdPath.
• The script is NOT tested, for I don't have Acrobat Professional v8.
• You can find some essential documents at Adobe's site:
(See p.161 of 'Interapplication Communication API Reference' for 'save' command syntax and example)
* Acrobat Developer Center : Interapplication communication
http://www.adobe.com/devnet/acrobat/interapplication.html
* Interapplication Communication API Reference
http://www.adobe.com/devnet/acrobat/pdfs/iacapireference.pdf
Good luck,
H
-- SCRIPT
on adding folder items to thefolder after receiving theAddedItems
set rootFdPath to (path to desktop folder from user domain) as string -- # root folder path
set templateFdPath to rootFdPath & "template:" -- # template folder path
set finishedFdPath to rootFdPath & "finished:" -- # finished folder path
set templateName to "ipdfmal.pdf" -- # template file name
set templateFile to (templateFdPath & templateName) as alias
repeat with i from 1 to (count theAddedItems) -- note that theAddedItems is generally a list of aliases
set addedItem to item i of theAddedItems
-- get source file name
try
set oldDelims to AppleScript's text item delimiters
set AppleScript's text item delimiters to {":"}
set addedItemName to last text item of (addedItem as text)
set AppleScript's text item delimiters to oldDelims
on error errs number errn
set AppleScript's text item delimiters to oldDelims -- always guarantee to reset ASTID
error errs number errn
end
tell application "Adobe Acrobat Professional"
-- activate -- avoid this, if possible, in such processes launched in background as in folder action
-- open source
open addedItem
-- open template
open templateFile
-- merge source pages to template
replace pages document templateName over 1 ¬
from document addedItemName starting with 1 number of pages 25
-- close source document
close document addedItemName
-- save merged template as new file named after source file
save document templateName to file (finishedFdPath & addedItemName)
-- close renamed template document
(* in case template document name is set to new name in previous 'save as' *)
close document addedItemName saving no
-- (OR) close template document
(* in case template document name is NOT set to new name in previous 'save as' *)
-- close document templateName saving no
end tell
-- delete each finished source file
-- tell application "Finder" to delete addedItem
end repeat
-- empty trash
-- tell application "Finder" to empty trash
end adding folder items to
-- END OF SCRIPT
  Mac OS 9.1.x