Retrive a new sequence value from a table using Stored Procedure

Question

Dear experts
i have written the following stored procedure, but i want this to return itemid to the environment. Please help as i am absolutely new to oracle.
create or replace procedure "SP_ITEMS"
(vitem IN VARCHAR2,
vqty IN NUMBER,
vrate IN NUMBER)
is
begin
INSERT INTO ITEMS (item,qty,rate)
VALUES (vitem,vqty,vrate);
end;
Thanks
With regards
Manish Sawjiani

Answer 1

If you want a column to be automatically populated with a sequence, then you need to create a sequence, and create a trigger to populate the column with the sequence. You can use the returning clause in a select statement to return the value of the inserted sequence. You can do this with just sql or you can put it in a procedure. I have demonstrated both below. This is a general sql and pl/sql problem, not something specific to the Express Edition, so please post future such questions in the sql and pl/sql discussion group instead.
SCOTT@10gXE> CREATE TABLE items
  2    (itemid NUMBER,
  3       item   VARCHAR2 (50),
  4       qty    NUMBER (10, 3),
  5       rate   NUMBER (10, 3))
  6  /
Table created.
SCOTT@10gXE> CREATE SEQUENCE item_sequence
  2  /
Sequence created.
SCOTT@10gXE> CREATE OR REPLACE TRIGGER items_bir
  2    BEFORE INSERT ON items
  3    FOR EACH ROW
  4  BEGIN
  5    SELECT item_sequence.NEXTVAL
  6    INTO   :NEW.itemid
  7    FROM   DUAL;
  8  END items_bir;
  9  /
Trigger created.
SCOTT@10gXE> SHOW ERRORS
No errors.
SCOTT@10gXE> VARIABLE g_itemid NUMBER
SCOTT@10gXE> INSERT INTO items (item, qty, rate)
  2  VALUES ('item1', 2, 3)
  3  RETURNING itemid INTO :g_itemid
  4  /
1 row created.
SCOTT@10gXE> PRINT g_itemid
  G_ITEMID
         1
SCOTT@10gXE> CREATE OR REPLACE PROCEDURE sp_items
  2    (p_item      IN  VARCHAR2,
  3       p_qty      IN  NUMBER,
  4       p_rate      IN  NUMBER,
  5       p_itemid OUT NUMBER)
  6  AS
  7  BEGIN
  8    INSERT INTO ITEMS (item, qty, rate)
  9    VALUES (p_item, p_qty, p_rate)
10    RETURNING itemid INTO p_itemid;
11  END sp_items;
12  /
Procedure created.
SCOTT@10gXE> SHOW ERRORS
No errors.
SCOTT@10gXE> EXECUTE sp_items ('item2', 3, 4, :g_itemid)
PL/SQL procedure successfully completed.
SCOTT@10gXE> PRINT g_itemid
  G_ITEMID
         2
SCOTT@10gXE> SELECT * FROM items
  2  /
    ITEMID ITEM                                                      QTY       RATE
         1 item1                                                       2          3
         2 item2                                                       3          4
2 rows selected.
SCOTT@10gXE>