ROW_NUMBER() and complex expression of ORDER BY

Question

Hi everybody,
I am getting confused and can not figure out how to incorporate different sort order (ASC or DESC) into this complex expression. I can possible do this using IF /ELSE construct but I am not sure I like it.
I am re-writing the stored procedure I wrote 2 weeks ago to incorporate server side paging rather than client site. I have ng-grid working fine and filtering / paging quite quickly client side, but an account can have 400,000 invoices and sending all of
this to the client doesn't seem right.
So, this is what I wrote so far and I am confused as how to add asc/desc order into that procedure:
ALTER PROCEDURE dbo.siriussp_GetAccountInvoices
(@acctName CHAR(10),
@Finalized BIT = 0,
@PageSize INT = 15,
@PageNumber INT = 1,
@SearchText VARCHAR(max) = '',
@OrderBy VARCHAR(20) = '',
@SortOrder VARCHAR(4) = 'ASC',
@TotalRows INT OUTPUT)
AS
BEGIN
SET NOCOUNT ON;
IF OBJECT_ID('TempDb..#AccountInvoices', N'U') IS NOT NULL DROP TABLE #AccountInvoices;
SELECT i.invoice_no, i.descrip1 as Descrip, i.hidden, i.finalized, i.date_time as Created,
COALESCE(Bal.Balance,0) as Balance, ROW_NUMBER() OVER (ORDER BY
CASE WHEN @OrderBy ='InvoiceNo' OR @OrderBy = '' THEN i.invoice_no END,
CASE WHEN @OrderBy = 'Descrip' THEN i.descrip1 END,
CASE WHEN @OrderBy = 'Balance' THEN Bal.Balance END,
CASE WHEN @OrderBy = 'Created' THEN i.date_time END) AS Rn
INTO #AccountInvoices
FROM dbo.invoices i
OUTER APPLY (SELECT SUM(extension) as Balance FROM dbo.transact t
WHERE t.invoice_no = i.invoice_no) Bal
WHERE i.account = @acctName
AND (@Finalized = 0 OR (@Finalized = 1 and i.finalized = 1))
AND (@SearchText = '' OR (CAST(i.invoice_no AS VARCHAR(17)) LIKE @SearchText + '%' OR i.descrip1 LIKE '%' + @SearchText + '%'
OR CAST(Bal.Balance AS VARCHAR(20)) LIKE @SearchText + '%'))
OPTION (RECOMPILE);
SET @TotalRows = @@ROWCOUNT;
SELECT * FROM #AccountInvoices WHERE Rn >= (@PageNumber-1) * @PageSize AND Rn < @PageNumber * @PageSize
ORDER BY Rn;
END
Thanks in advance.
For every expert, there is an equal and opposite expert. - Becker's Law
My blog
My TechNet articles

Answer 1

I like that, quite creative.
My current procedure is simple enough, I think, although I am not sure that using temp table is a very good idea, but I don't see lots of alternatives. One account can have up to 400000 (or more) invoices for big clients. My current test database only has
28 invoices per account (it's a maximum). I would also want to somehow figure an approach of doing client vs. server side paging on the fly (depending on total numbers) as it seems a bit silly to go to the server for next 15 rows while we have only 30 in total.
That (applying 2 separate approaches on the fly) will be a challenge in itself.
Anyway, here is my current procedure and I'd welcome advices of improving it. The client side filtering right now applies 'contains' filter against all 4 columns but I think it's wrong and we better use filter for only 3 columns (excluding the date column)
and use starts with for the invoice number or balance rather than include.
ALTER PROCEDURE dbo.siriussp_GetAccountInvoicesWithPaging
(@acctName CHAR(10),
@Finalized BIT = 0,
@PageSize INT = 15,
@PageNumber INT = 1,
@SearchText VARCHAR(max) = '',
@OrderByColumn VARCHAR(20) = '',
@SortOrder VARCHAR(4) = 'ASC',
@TotalRows INT OUTPUT)
AS
BEGIN
SET NOCOUNT ON;
IF OBJECT_ID('TempDb..#AccountInvoices', N'U') IS NOT NULL DROP TABLE #AccountInvoices;
CREATE TABLE #AccountInvoices (invoice_no numeric(17,0) NOT NULL,
Descrip VARCHAR(25) COLLATE DATABASE_DEFAULT NOT NULL,
hidden BIT NOT NULL, finalized BIT NOT NULL, Created DATETIME NULL,
Balance MONEY, Rn Int)
DECLARE @Sql NVARCHAR(MAX);
SET @Sql = 'SELECT i.invoice_no, i.descrip1 as Descrip, i.hidden, i.finalized, i.date_time as Created,
COALESCE(Bal.Balance,0) as Balance, ROW_NUMBER() OVER (ORDER BY ' +
CASE WHEN @OrderByColumn ='InvoiceNo' OR @OrderByColumn = '' THEN 'i.invoice_no'
WHEN @OrderByColumn = 'Descrip' THEN 'i.descrip1'
WHEN @OrderByColumn = 'Balance' THEN 'Bal.Balance'
WHEN @OrderByColumn = 'Created' THEN 'i.date_time' END
+ CASE WHEN @SortOrder = 'DESC' THEN ' DESC' ELSE '' END + ') AS Rn
FROM dbo.invoices i
OUTER APPLY (SELECT SUM(extension) as Balance FROM dbo.transact t
WHERE t.invoice_no = i.invoice_no) Bal
WHERE i.account = @acctName ' +
CASE WHEN @Finalized = 0 THEN '' ELSE ' AND i.finalized = 1' END +
CASE WHEN @SearchText = '' THEN '' ELSE ' AND (CAST(i.invoice_no AS VARCHAR(17)) LIKE @SearchText + ''%''
OR i.descrip1 LIKE ''%'' + @SearchText + ''%''
OR CAST(Bal.Balance AS VARCHAR(20)) LIKE @SearchText + ''%'')' END;
PRINT @SQL;
INSERT INTO #AccountInvoices (invoice_no, Descrip, hidden, finalized, Created, Balance, Rn)
EXECUTE sp_executeSQL @Sql, N'@acctName CHAR(10), @SearchText VARCHAR(max)', @acctName = @acctName, @SearchText = @SearchText;
SET @TotalRows = @@ROWCOUNT;
SELECT * FROM #AccountInvoices WHERE Rn >= (@PageNumber-1) * @PageSize AND Rn < @PageNumber * @PageSize
ORDER BY Rn;
END
/* Test
DECLARE @TotalRows INT = 0
execute dbo.siriussp_GetAccountInvoicesWithPaging @acctName = '*GUESTS*', @Finalized = 0,
@TotalRows = @TotalRows OUTPUT, @SearchText = '', @SortOrder = 'DESC', @OrderByColumn = 'Balance'
SELECT @TotalRows
Hmm, I thought I commented out print @SQL, but apparently I didn't.
I am also thinking I'd add a check for ISNUMERIC(@Search) because otherwise there is no need to compare balances and invoices.
For every expert, there is an equal and opposite expert. - Becker's Law
My blog
My TechNet articles