Rules and scripting

Question

Does iChat support "rules" the way that mail does? Can iChat parse contents of messages or run scripts? Alternately, does Adium support that, or would anyone recommend another chat application?
I'm trying to run scripts on my computer from my phone using AIM.

Answer 1

I found my own answer buried in iChat. Their scripts directory has a script on parsing IM's:
using terms from application "iChat"
-- Basic "Current track" message to use as a default response message.
on getCurrentiTunesTrack()
-- start with "not playing," just in case.
set theCurrentTrackMessage to "Not playing."
tell application "iTunes"
if player state is playing then
-- response to "status" message is of the form "Now playing "<Song>" by <Artist>"
set theCurrentTrackMessage to "Now playing \"" & (name of current track) & "\""
-- if artist is missing, use track title only.
if (artist of the current track) is not missing value then
set theCurrentTrackMessage to theCurrentTrackMessage & " by " & (artist of the current track)
end if
-- add a message if the volume is muted
if mute then
set theCurrentTrackMessage to theCurrentTrackMessage & " (muted)"
end if
end if
end tell
return theCurrentTrackMessage
end getCurrentiTunesTrack
-- handler to respond to all incoming messages.
on runiTunesRemoteControl(theMessage)
-- use default "unknown" command, just in case.
set theResponse to "Unknown command."
if theMessage is "status" then
-- "status" command displays current track
set theResponse to getCurrentiTunesTrack()
else if theMessage is "next" then
-- "next" command moves to next track.
tell application "iTunes"
next track
end tell
-- set the response message and add the status.
set theResponse to "Playing next track. " & getCurrentiTunesTrack()
else if theMessage is "previous" then
-- "previous" track moves to previous track.
tell application "iTunes"
previous track
end tell
set theResponse to "Playing previous track. " & getCurrentiTunesTrack()
else if theMessage is "mute" then
-- "mute" turns the volume off.
tell application "iTunes"
set mute to true
end tell
set theResponse to "iTunes muted. " & getCurrentiTunesTrack()
else if theMessage is "unmute" then
-- "unmute" turns the volume on.
tell application "iTunes"
set mute to false
end tell
set theResponse to "iTunes unmuted. " & getCurrentiTunesTrack()
else if theMessage is "play" then
-- "play" tells iTunes to start playing.
tell application "iTunes"
play
end tell
set theResponse to getCurrentiTunesTrack()
else if theMessage is "pause" then
-- "pause" pauses the current track.
tell application "iTunes"
pause
end tell
set theResponse to "Paused. " & getCurrentiTunesTrack()
else if theMessage is "help" then
-- display available commands on "help"
set theResponse to "Available commands: status, next, previous, mute, unmute, help, play, pause"
end if
return theResponse
end runiTunesRemoteControl
-- When first message is received, accept the invitation and send a greeting message from iTunes Remote Control.
on received text invitation theMessage from theBuddy for theChat
accept theChat
send "Welcome to iTunes Remote Control. " & runiTunesRemoteControl("help") to theChat
end received text invitation
-- On subsequent messages, pass the message directly to iTunes Remote Control.
on message received theMessage from theBuddy for theChat
-- run the iTunesRemoteControl parser.
set theResponse to runiTunesRemoteControl(theMessage)
-- send back the response.
send theResponse to theChat
end message received
-- Sample, so you can test run this through Script Editor.
display dialog "Send a command to iTunes Remote Control:" default answer "status"
set theMessage to the text returned of the result
set theResponse to runiTunesRemoteControl(theMessage)
display dialog theResponse
end using terms from