Runtime error while trying to execute custom F4 help in OOP ALV grid.

Question

Dear All,
I am trying to add custom search help for one of my column in ALV grid. I'm using OOP ALV, when i click for search help for that column, the system shows runtime error like below.
I am new to OOP concept and tried to follow program BCALV_EDIT_03. But not getting this error occur. Please help me.
With regards.

Answer 1

Hi,
In order to be able to provide a search help for a field in an ALV you must do the following things.
1) The field where F4 help need to be attached needs to be made editable.
2) Create an event handler class to handle the ONF4 event. You can refer the following code:
    CLASS lcl_alv1_handler DEFINITION.
    PUBLIC SECTION.
       "Tohandle F4 helps
       METHODS handle_f4 FOR EVENT onf4 OF cl_gui_alv_grid
               IMPORTING e_fieldname e_fieldvalue es_row_no er_event_data
                         et_bad_cells e_display.
    ENDCLASS.
   CLASS lcl_alv1_handler IMPLEMENTATION.
      METHOD handle_f4.
CASE e_fieldname.
     WHEN 'LIFNR'.               "Set F4 for courier vendor
         SELECT lifnr name1 FROM lfa1 INTO TABLE lt_lifnr.
       IF lt_lifnr IS NOT INITIAL.
         CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
           EXPORTING
             retfield           = 'LIFNR'
             window_title   = 'Vendors'
             value_org       = 'S'
           TABLES
             value_tab       = lt_lifnr
             return_tab      = lt_return
           EXCEPTIONS
             parameter_error = 1
             no_values_found = 2
             OTHERS          = 3.
         IF sy-subrc = 0.
           READ TABLE gt_final INTO wa_final_t INDEX es_row_no-row_id.
           IF sy-subrc = 0.
             READ TABLE lt_return INTO wa_return INDEX 1.
             IF sy-subrc = 0.
               CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
                 EXPORTING
                   input  = wa_return-fieldval
                 IMPORTING
                   output = lv_lifnr.
               wa_final_t-lifnr  = lv_lifnr.
               MODIFY gt_final FROM wa_final_t INDEX es_row_no-row_id.
             ENDIF.
           ENDIF.
         ENDIF.
       ENDIF.
      ENDCASE.
         CALL METHOD o_alv->refresh_table_display.
      ENDMETHOD.
   ENDCLASS.
    In the above method, GT_FINAL-LIFNR is being overwritten by the LIFNR you had selected       from F4 help. So we will call the refresh_table_display after it to see the result in the ALV.
3) After creating the ALV object, add the fields to which the F4 has to be added. For this you
    need to declare an internal table based on  lvc_t_f4. Use the following code. Here O_ALV is    my ALV object.:
   CREATE OBJECT o_container
       EXPORTING
         container_name              = 'CUSTCON'
       EXCEPTIONS
         cntl_error                  = 1
         cntl_system_error           = 2
         create_error                = 3
         lifetime_error              = 4
         lifetime_dynpro_dynpro_link = 5
         OTHERS                      = 6.
     IF sy-subrc <> 0.
*     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
     ENDIF.
     CREATE OBJECT o_alv
       EXPORTING
         i_parent          = o_container
       EXCEPTIONS
         error_cntl_create = 1
         error_cntl_init   = 2
         error_cntl_link   = 3
         error_dp_create   = 4
         OTHERS            = 5.
     IF sy-subrc <> 0.
*     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
     ENDIF.
   CLEAR : gt_f4, wa_f4.
   wa_f4-fieldname   = 'LIFNR'.
   wa_f4-register    = 'X'.
   wa_f4-getbefore   = space.
   wa_f4-chngeafter  = space.
   APPEND wa_f4 TO gt_f4.
   Here I am assigning F4 to LIFNR field in the final internal table that is displayed using ALV.
   After this register this field for F4.
    CALL METHOD o_alv->register_f4_for_fields
       EXPORTING
          it_f4 = gt_f4.
   CREATE OBJECT o_alv_handler.
   SET HANDLER : o_alv_handler->handle_f4 FOR o_alv1.
   The object o_alv_handler is created based on the event handler class.
I hope that this will solve your issue. Revert if this is solved.
Rgards,
Abijith