Salmple at How to Create Dynamical Object for RTTC

Question

Hi all, I need a sample at How to Create Dynamical Object for RTTC.
  you can help me?.

Answer 1

Hello Martinez,
I have attached a sample for structure types. With the Where-Used-List on the Create() Method of the various RTTC classes one may find more samples. If you meant with object on OO Type then it is to mention that this is not possible yet.
Regards
  Klaus
PROGRAM sample.
DATA: sdescr1 TYPE REF TO cl_abap_structdescr,
      sdescr2 TYPE REF TO cl_abap_structdescr,
      tdescr1 TYPE REF TO cl_abap_tabledescr,
      tdescr2 TYPE REF TO cl_abap_tabledescr,
      tref1   TYPE REF TO data,
      tref2   TYPE REF TO data,
      comp    TYPE abap_component_tab,
      wa      TYPE t100,
      xbuf    TYPE xstring.
FIELD-SYMBOLS: <tab1> TYPE table,
               <tab2> TYPE table.
sdescr1 ?= cl_abap_typedescr=>describe_by_name( 'T100' ).
comp     = sdescr1->get_components( ).
sdescr2  = cl_abap_structdescr=>create( comp ).
tdescr1  = cl_abap_tabledescr=>create( sdescr2 ).
tdescr2  = cl_abap_tabledescr=>create( sdescr2 ).
CREATE DATA: tref1 TYPE HANDLE tdescr1,
             tref2 TYPE HANDLE tdescr2.
ASSIGN: tref1->* TO <tab1>,
        tref2->* TO <tab2>.
wa-sprsl = 'E'. wa-arbgb = 'SY'. wa-msgnr = '123'. wa-text = 'first text'.   INSERT wa INTO TABLE <tab1>.
wa-sprsl = 'D'. wa-arbgb = 'SY'. wa-msgnr = '456'. wa-text = 'second text'.  INSERT wa INTO TABLE <tab1>.
wa-sprsl = 'D'. wa-arbgb = 'XY'. wa-msgnr = '001'. wa-text = 'third text'.   INSERT wa INTO TABLE <tab1>.
wa-sprsl = 'D'. wa-arbgb = 'ZZ'. wa-msgnr = '123'. wa-text = 'fourth text'.  INSERT wa INTO TABLE <tab1>.
wa-sprsl = 'E'. wa-arbgb = 'SY'. wa-msgnr = '123'. wa-text = 'ABAP is a miracle'. INSERT wa INTO TABLE <tab1>.
EXPORT tab = <tab1> TO DATA BUFFER xbuf.
IMPORT tab = <tab2> FROM DATA BUFFER xbuf.
LOOP AT <tab2> INTO wa.
  WRITE: / wa-sprsl, wa-arbgb, wa-msgnr, wa-text.
ENDLOOP.