Script to print a file ending with specific characters

Question

Hi all
Can anyone help me with a script that will automatically print to a laser, any file within various sub folders on a NAS that end in '_IMP.pdf'???
total newb to scripting!
thanks

Answer 1

Folder actions don't handle subfolders well, and I forget whether they can cope with network drives.  I'm sure you could make it work, but since we already have the script as given here's how you modify it to do what you want. Save the following as a stay-open application (save it as an application, and check the "application stays open after run handler" checkbox), and leave it running in the background. it will label files with a color as they are processed, which will tell both you and it what files have been printed.
property nameCue : "_IMP.pdf" -- file ending
property folderPath : "/Path/To/Folder" -- posix path to folder that holds pdfs
property intervalMinutes : 10 -- time in minutes between iterations
property labelColor : 3 -- integer between 1 and 7; 3 is yellow by default
on idle
  -- use an idle handler to run the recursive search and print periodically
          set filesToPrint to recursiveFolderSearch(folderPath)
          tell application "<printer name>" -- set this to the correct printer name
                    activate
                    print filesToPrint
          end tell
          return 60 * intervalMinutes
end idle
on recursiveFolderSearch(folderPath)
  -- a handler to do a recursive folder search
          tell application "System Events"
                    set folderItems to disk items of folder folderPath whose visible is true
                    set chosenFiles to {}
                    repeat with thisDiskItem in folderItems
                              if class of thisDiskItem is folder then
  -- folder: recurse
                                        set chosenFiles to chosenFiles & my recursiveFolderSearch(POSIX path of thisDiskItem)
                              else
  -- file: check file name for correct ending and then check to see if it's labeled
                                        if name of thisDiskItem ends with nameCue and my checkLabel(path of thisDiskItem) then
                                                  set end of chosenFiles to POSIX path of thisDiskItem
                                        end if
                              end if
                    end repeat
          end tell
          return chosenFiles
end recursiveFolderSearch
on checkLabel(f)
     check if the file is labeled, which means it has already been printed.
     if it hasn't been printed, label it with the appropriate color and return true
     to tell the calling handler the file should be printed
          tell application "Finder"
                    if (label index of file f) = 0 then
                              set label index of file f to labelColor
                              return true
                    else
                              return false
                    end if
          end tell
end checkLabel