Scripting menu items

Question

I desperatly ned to find out how to use applescript for exporting pages document.
One way could be through menu scripting.
I am able to show the ruler of a pages document with the code at the end of this message.
But how can I Export a pages document to word format using menu items.
Thanks
Jitse
tell application "Pages"
activate
end tell
tell application "System Events"
tell process "Pages"
activate
set frontmost to true
tell menu bar 1
tell menu bar item "View"
tell menu "View"
click menu item "Show Rulers"
(*click button "PDF" of radio group of sheet 1 of window 1 *)
end tell
end tell
end tell
end tell
end tell

Answer 1

If you don't mind using [GUI Scripting|http://www.macosxautomation.com/applescript/uiscripting/index.html], then the following script (which runs flawlessly on my computer) should do what you are asking for:
--BEGINNING OF SCRIPT
set theName to "Pages document.doc"
tell application "Pages" to activate
tell application "System Events" to tell process "Pages"
click menu item "Export…" of menu 1 of menu bar item "File" of menu bar 1
repeat until sheet 1 of window 1 exists
end repeat
click radio button "Word" of radio group 1 of sheet 1 of window 1
click button "Next…" of sheet 1 of window 1
keystroke "a" using command down -- Select All (⌘A)
keystroke theName
keystroke "d" using command down -- save to Desktop (⌘D)
keystroke return
end tell
--END OF SCRIPT
Hope it can help.
(The above script was tested with Pages ’09 and Mac OS X 10.6.2 “Snow Leopard”.)
Message was edited by: Pierre L.