Scroll Bar in ALV Top Of Page

Question

Hi Ppl,
I am using REUSE_ALV_COMMENTARY_WRITE to display top of page in ALV. The issue is i want to restrict the top-of-page height.
As of now if i have 10 lines to print...the top-of-page comes with 10 lines in display.
But i want some (say 4 or 5) to be visible with scroolbar and rest can be viewed by use of the scroll--bar movement!!
Any soln?? Please reply
Regards,
Santosh!!

Answer 1

Hi Santosh,
I am not sure if that is possible by using FM approach. - REUSE_ALV_COMMENTARY_WRITE
But yes its possible if you are using Docking Container. with split container approach. ie. OOPs .
Refer sample code.
Constants Declaration
CONSTANTS: c_x             TYPE c          VALUE 'X',
           c_mode          TYPE char1      VALUE 'O',
           c_mask          TYPE char9      VALUE ',*.*,*.*.',
           c_error_log     TYPE tabname    VALUE 'ZERROR_LOG',
           c_succ          TYPE iconname   VALUE '@01@',    "#EC *
           c_fail          TYPE iconname   VALUE '@02@',
           c_object        TYPE emg_object VALUE 'PARTNER'," Legacy obj
           c_opbuk         TYPE opbuk_kk   VALUE 'UK01',
           c_split         TYPE c
                           VALUE cl_abap_char_utilities=>horizontal_tab,
           c_path          TYPE char100
                           VALUE '/local/data/interface/A28/DM/OUT'.
*Variables Declaration
DATA:  flg_pre     TYPE c,             " Flag -  Presentation browse
       flg_x       TYPE c,
       cnt_total   TYPE char8,         " Total Records processed
       cnt_success TYPE char8,         " Total Records success
       cnt_failed  TYPE char8,        " Total Records failed
       cnt_repeat  TYPE char8.
*-- ALV Grid data declaration
      CLASS v_lcl_event_receiver DEFINITION
CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
    METHODS:
     handle_print_top_of_page FOR EVENT print_top_of_page OF
                                        cl_gui_alv_grid,
     handle_top_of_page       FOR EVENT top_of_page OF
                                        cl_gui_alv_grid.
ENDCLASS.                    "o_lcl_event_receiver DEFINITION
      ALV Data declaration
DATA : o_alvgrid          TYPE REF TO cl_gui_alv_grid,
       o_split            TYPE REF TO cl_gui_easy_splitter_container,
       o_dockingcontainer TYPE REF TO cl_gui_docking_container,
      <b> o_container_top    TYPE REF TO cl_gui_container,
       o_container_bot    TYPE REF TO cl_gui_container,
       o_html             TYPE REF TO cl_dd_document,</b>       o_event_receiver   TYPE REF TO lcl_event_receiver,
       ok_code            LIKE sy-ucomm,
       i_fieldcat         TYPE lvc_t_fcat,
       wa_fieldcat        TYPE lvc_s_fcat,
       wa_layout          TYPE lvc_s_layo.
      CLASS LCL_EVENT_RECEIVER IMPLEMENTATION
CLASS lcl_event_receiver IMPLEMENTATION.
*-- Top of Page
  METHOD handle_print_top_of_page.
  ENDMETHOD.                    "handle_print_top_of_page
  METHOD handle_top_of_page.
  ENDMETHOD.                    "handle_top_of_page
ENDCLASS.                    "lcl_event_receiver IMPLEMENTATION
*-- ALV List data declaration
DATA:  i_field_cat1       TYPE slis_t_fieldcat_alv,
       w_lay_out1         TYPE slis_layout_alv,
       w_field_cat        TYPE slis_fieldcat_alv,
       i_events1          TYPE slis_t_event,
       w_event            TYPE slis_alv_event,
       w_print            TYPE slis_print_alv.
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'STANDARD'.
  SET TITLEBAR 'TITLE'.
*-- Create Instances
  PERFORM f0040_create_object.
*-- Create Field catalog
  PERFORM f0050_field_catalog
                    TABLES i_fieldcat
                    USING c_error_log.
*-- Modify Field Catalog
  PERFORM f0060_modify_fldcatalog
                    TABLES i_fieldcat.
*-- Set ALV Layout
  PERFORM f0070_layout.
*-- Generate ALV Grid
  PERFORM f0080_display_list
                    TABLES  i_error
                            i_fieldcat
                      USING wa_layout.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&      Form  f0040_create_object
FORM f0040_create_object .
  IF cl_gui_alv_grid=>offline( ) IS INITIAL.
*-- Create Container
    CREATE OBJECT o_dockingcontainer
      EXPORTING
        ratio                     = '95'
     EXCEPTIONS
      cntl_error                  = 1
      cntl_system_error           = 2
      create_error                = 3
      lifetime_error              = 4
      lifetime_dynpro_dynpro_link = 5
      OTHERS                      = 6.
    IF sy-subrc NE 0.
      MESSAGE i000 WITH text-013.   " Error in object creation
      LEAVE LIST-PROCESSING.
    ENDIF.
*--Create Splitter Container
    CREATE OBJECT o_split
      EXPORTING
        parent            = o_dockingcontainer
        sash_position     = 20
        with_border       = 0
      EXCEPTIONS
        cntl_error        = 1
        cntl_system_error = 2
        OTHERS            = 3.
*--Get the containers of the splitter control
    o_container_top = o_split->top_left_container.
    o_container_bot = o_split->bottom_right_container.
  ENDIF.
  CREATE OBJECT o_alvgrid
     EXPORTING
       i_parent = o_container_bot.
*-- Print Top of Page
  PERFORM f0041_top_of_page.
ENDFORM.                    " f0040_create_object
<b>&----
*&      Form  f0041_top_of_page</b>
FORM f0041_top_of_page .
  DATA: lws_text  TYPE sdydo_text_element.
  IF cl_gui_alv_grid=>offline( ) IS INITIAL.
*-- Object for HTML top container
    CREATE OBJECT o_html
        EXPORTING style            = 'ALV_GRID'
                  background_color = 35.
*-- Top of Page
    CALL METHOD o_alvgrid->list_processing_events
      EXPORTING
        i_event_name = 'TOP_OF_PAGE'
        i_dyndoc_id  = o_html.
*-- Total Record Text
    CALL METHOD o_html->add_text
      EXPORTING
        text         = text-014
        sap_emphasis = text-017.
    CALL METHOD o_html->add_gap
      EXPORTING
        width = 8.
**-- Total record Value
    lws_text = cnt_total.
    CALL METHOD o_html->add_text
      EXPORTING
        text         = lws_text
        sap_emphasis = text-017.
    CLEAR  lws_text.
    CALL METHOD o_html->new_line
      EXPORTING
        repeat = 1.
**-- Total Success text
    CALL METHOD o_html->add_text
      EXPORTING
        text         = text-015
        sap_emphasis = text-017
        fix_lines    = c_x.
    CALL METHOD o_html->add_gap
      EXPORTING
        width = 12.
    lws_text = cnt_success.
    CALL METHOD o_html->add_text
      EXPORTING
        text         = lws_text
        sap_emphasis = text-017
        fix_lines    = c_x.
    CLEAR  lws_text.
    CALL METHOD o_html->new_line
      EXPORTING
        repeat = 1.
*-- Total Failed text
    CALL METHOD o_html->add_text
      EXPORTING
        text         = text-016
        sap_emphasis = text-017
        fix_lines    = c_x.
    CALL METHOD o_html->add_gap
      EXPORTING
        width = 16.
    lws_text = cnt_failed.
    CALL METHOD o_html->add_text
      EXPORTING
        text         = lws_text
        sap_emphasis = text-017
        fix_lines    = c_x.
    CLEAR  lws_text.
*-- Display Report Header
<b>    CALL METHOD o_html->display_document
      EXPORTING
        parent = o_container_top.</b>
  ENDIF.
ENDFORM.                    " f0041_top_of_page
*&      Form  f0050_field_catalog
FORM f0050_field_catalog  TABLES   p_fieldcat STRUCTURE lvc_s_fcat
                          USING value(p_structure).
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name       = p_structure
    CHANGING
      ct_fieldcat            = p_fieldcat[]
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2
      OTHERS                 = 3.
  IF sy-subrc <> 0.
    MESSAGE i000(zo_spa) WITH text-017.
    LEAVE LIST-PROCESSING.
  ENDIF.
ENDFORM.                    " f0050_field_catalog
*&      Form  f0070_layout
FORM f0070_layout .
  wa_layout-zebra      = c_x.
  wa_layout-cwidth_opt = c_x.
ENDFORM.                    " f0070_layout
*&      Form  f0080_display_list
FORM f0080_display_list  TABLES  p_output
                                 p_fieldcat
                         USING value(p_layout).
*-- Display Report
  CALL METHOD o_alvgrid->set_table_for_first_display
    EXPORTING
      i_save                        = 'A'
      is_layout                     = p_layout
    CHANGING
      it_outtab                     = p_output[]
      it_fieldcatalog               = p_fieldcat[]
    EXCEPTIONS
      invalid_parameter_combination = 1
      program_error                 = 2
      too_many_lines                = 3
      OTHERS                        = 4.
  IF sy-subrc <> 0.
    MESSAGE i000(zo_spa) WITH text-022.    " Error in Displaying
    LEAVE LIST-PROCESSING.
  ENDIF.
**-- Create Event object
  CREATE OBJECT o_event_receiver.
  SET HANDLER o_event_receiver->handle_print_top_of_page
                                 FOR o_alvgrid.
ENDFORM.                    " f0080_display_list
*&      Module  USER_COMMAND_0100  INPUT
MODULE user_command_0100 INPUT.
  ok_code = sy-ucomm.
  CASE ok_code.
    WHEN 'EXIT' OR  'CANC'.
      PERFORM f4000_free_objects:
               USING o_alvgrid 'ALV' text-031,
               USING o_dockingcontainer 'DOCKING' text-032.
      LEAVE PROGRAM.
    WHEN 'BACK'.
      PERFORM f4000_free_objects:
               USING o_alvgrid 'ALV' text-031,
               USING o_dockingcontainer 'DOCKING' text-032.
      SET SCREEN '0'.
      LEAVE SCREEN.
    WHEN OTHERS.
      PERFORM f4000_free_objects:
                USING o_alvgrid 'ALV' text-031,
                USING o_dockingcontainer 'DOCKING' text-032.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
*&      Form  f4000_free_objects
FORM f4000_free_objects  USING pobject
                        value(ptype)
                        value(ptext) TYPE c.
  DATA: lo_objectalv TYPE REF TO cl_gui_alv_grid.
  CASE ptype.
    WHEN 'ALV'.
      lo_objectalv = pobject.
      IF NOT ( lo_objectalv IS INITIAL ).
        CALL METHOD lo_objectalv->free
          EXCEPTIONS
            cntl_error        = 1
            cntl_system_error = 2
            OTHERS            = 3.
        CLEAR: pobject, lo_objectalv.
        PERFORM f4010_error_handle USING ptext.
      ENDIF.
    WHEN 'DOCKING'.
      DATA: lo_objectdock TYPE REF TO cl_gui_docking_container.
      lo_objectdock = pobject.
      IF NOT ( lo_objectdock IS INITIAL ).
        CALL METHOD lo_objectdock->free
          EXCEPTIONS
            cntl_error        = 1
            cntl_system_error = 2
            OTHERS            = 3.
        CLEAR: pobject, lo_objectdock.
        PERFORM f4010_error_handle USING ptext.
      ENDIF.
    WHEN OTHERS.
      sy-subrc = 1.
      PERFORM f4010_error_handle
                   USING text-031.
  ENDCASE.
ENDFORM.                    " f4000_free_objects
*&      Form  f4010_error_handle
FORM f4010_error_handle  USING value(ptext) TYPE c.
  IF sy-subrc NE 0.
    CALL FUNCTION 'POPUP_TO_INFORM'
      EXPORTING
        titel = text-031
        txt2  = sy-subrc
        txt1  = ptext.
  ENDIF.
ENDFORM.                    " f4010_error_handle
Reward points if this Helps.
Manish