Select most recent file and display

Question

I've been considerig this and I am closer to how I expect it to work
This is what I have so far but can't peice together just yet.
Get the current open folder window look for the last item if shot within the last 30 secs of the creation date, if shot within 30 secs then select/highlight the file and use system events to press keystroke y using cmd and option down.(to put it on the screen in full screen) Display for 15 secs, or if esc hit then wait for next file to arrive and so on.
If the window is closed of the current open folder then end applescript.
This is how far I have got but can't link the ideas together well.
set theWindow to name of front window of application "Finder"
set theWindow to name of front window of application "Finder"
set theFldr to path of theWindow
tell application "Finder"
          set theContents to sort items of theFldr by creation date
          set theLastimage to (contents of item 1 of theContents) as text
  --is it within the last 30 seconds?
  -- yes, then
          tell application "System Events"
  keystroke "y" using {command down, option down}
                    delay 15
  key code 53
  --then wait for arrival of next image. and repeat.
  --if theWindow is close end applescript.
          end tell
end tell

Answer 1

Hi,
If you don't want to use a folder action, try this :
try
      tell application "Finder" to set currFolder to name of front Finder window
on error
      return -- no Finder window
end try
set tDate to (current date) - 30
repeat
      set b to false
      tell application "Finder"
            set fWindows to Finder windows whose it's name is currFolder
            if (fWindows is not {}) then
                  set tWind to item 1 of fWindows
                  set nFiles to document files of tWind whose creation date > tDate -- get newer files
                  set tDate to (current date)
                  if nFiles is not {} then
                        reveal nFiles
                        my selectionfullScreen(currFolder, count nFiles)
                        set b to true
                  end if
            else
                  exit repeat -- quit the script, the current Folder is closed
            end if
      end tell
      if not b then delay 5 -- no recent files, wait 5 seconds
end repeat
on selectionfullScreen(tName, n)
      tell application "System Events"
            tell process "Finder"
                  set frontmost to true
                  keystroke "y" using {command down, option down}
                  repeat (15 * n) times
                        tell window 1 to if (exists) and (its title is tName) then return -- the user close QuickLook
                        delay 1
                  end repeat
                  tell window 1 to if (exists) and (its title is not tName) then key code 53 -- close QuickLook after (15 seconds X (number of images))
            end tell
      end tell
end selectionfullScreen