Sending An email from BSP

Question

Hi All
i need to send an email  from BSP application when check box is clicked .
I have the details such as pernr of an employeee by using this i need to retrieve email id of that employee and have to send an email to that employee with some text
1. How  to retireve email id of an employee using pernr 
2.How to send email from bsp application
Thanks

Answer 1

Hi ,
<b>To get the Email for the given PERNR:</b>
* Get the Communication detail from Infotype 0105
      SELECT
       USRID_LONG
       FROM PA0105 INTO
         RECEIVER_EMAIL
       WHERE PERNR = PERNR AND
             BEGDA <= SY-DATLO     AND
             ENDDA >= SY-DATLO     AND
             SUBTY = '0010'
<b>Look at this code which will send a email from BSP..</b>
DATA:
   SEND_REQUEST       TYPE REF TO CL_BCS,
   DOCUMENT           TYPE REF TO CL_DOCUMENT_BCS,
   SENDER             TYPE REF TO CL_SAPUSER_BCS,
   RECIPIENT          TYPE REF TO IF_RECIPIENT_BCS,
   EXCEPTION_INFO     TYPE REF TO IF_OS_EXCEPTION_INFO,
   BCS_EXCEPTION      TYPE REF TO CX_BCS,
   WA_MESSAGE TYPE BAPIRET2.
  DATA:
   LEN   TYPE I,
   TEXTLENGTH TYPE SO_OBJ_LEN,
   ITAB_MESSAGE TYPE SOLI_TAB,
   WA_SOLI TYPE SOLI.
*Load class defnitions
  CLASS CL_CAM_ADDRESS_BCS DEFINITION LOAD.
  CLASS CL_ABAP_CHAR_UTILITIES DEFINITION LOAD.
* Create persistent send request
  TRY.
      SEND_REQUEST = CL_BCS=>CREATE_PERSISTENT( ).
* Format the message content to be sent into internal table
      IF NOT MESSAGE IS INITIAL.
        WA_SOLI-LINE = MESSAGE.
        APPEND WA_SOLI TO ITAB_MESSAGE.
      ELSE.
        WA_MESSAGE-MESSAGE = `Enter some Message and then Click "Send Your Message" button.`.
        APPEND WA_MESSAGE TO RETURN.
        ERROR = 'X'.
        RETURN.
      ENDIF.
      LEN = STRLEN( MESSAGE ).
      TEXTLENGTH = LEN.
* Create document
      CALL METHOD CL_DOCUMENT_BCS=>CREATE_DOCUMENT
        EXPORTING
          I_TYPE    = 'RAW'
          I_SUBJECT = SUBJECT
          I_LENGTH  = TEXTLENGTH
          I_TEXT    = ITAB_MESSAGE
        RECEIVING
          RESULT    = DOCUMENT.
* Add document to send request
      CALL METHOD SEND_REQUEST->SET_DOCUMENT
        EXPORTING
          I_DOCUMENT = DOCUMENT.
* Get sender object
      CALL METHOD CL_SAPUSER_BCS=>CREATE
        EXPORTING
          I_USER = SY-UNAME
        RECEIVING
          RESULT = SENDER.
* Add sender
      CALL METHOD SEND_REQUEST->SET_SENDER
        EXPORTING
          I_SENDER = SENDER.
* Create recipient
      CALL METHOD CL_CAM_ADDRESS_BCS=>CREATE_INTERNET_ADDRESS
        EXPORTING
          I_ADDRESS_STRING = RECEIVER
        RECEIVING
          RESULT           = RECIPIENT.
* Add recipient with its respective attributes to send request
      CALL METHOD SEND_REQUEST->ADD_RECIPIENT
        EXPORTING
          I_RECIPIENT  = RECIPIENT
          I_EXPRESS    = ' '
          I_COPY       = ' '
          I_BLIND_COPY = ' '.
      SEND_REQUEST->SET_SEND_IMMEDIATELY( 'X' ).
* Send document
      CALL METHOD SEND_REQUEST->SEND
        RECEIVING
          RESULT = SENT.
      IF SENT IS NOT INITIAL.
        COMMIT WORK.
        WA_MESSAGE-MESSAGE = 'Your Message sent Successfully!!!'.
        APPEND WA_MESSAGE TO RETURN.
      ELSE.
        ERROR = 'X'.
        WA_MESSAGE-MESSAGE = 'Your Message could not be sent. Please try again later'.
        APPEND WA_MESSAGE TO RETURN.
      ENDIF.
    CATCH CX_ADDRESS_BCS .
    CATCH CX_SEND_REQ_BCS.
    CATCH CX_DOCUMENT_BCS.
      WA_MESSAGE-MESSAGE = 'Your Message could not be sent. Please try again later'.
      APPEND WA_MESSAGE TO RETURN.
      ERROR = 'X'.
  ENDTRY.
Raja T