Slow SQL Function, can it be made to run faster?

Question

Hi there,
I am using Oracle 11.1
I have a simple OWB map that uses the transformation object calling the below function to return a value. The source table for the map contains ~17,000 records, The look-up table used below (BCGDHSC) contains ~180,000 records. My problem is the job takes 17 minutes to run with this function being called, if I comment out the look-up portion it takes about 3 seconds? Any ideas on how I can speed this up or ideas as to what I am doing wrong?
CREATE OR REPLACE FUNCTION "F_GET_PLAN"("EMPLOYEE_ID_IN" IN VARCHAR2, "REGION_CD_IN" IN VARCHAR2) RETURN VARCHAR2 PARALLEL_ENABLE IS
--init variable
control_plan_out varchar2(2);
rec_count int;
BEGIN
--Get the record count to see if it exists
select count(*) into rec_count from BCGDHSC WHERE HSC_REGION_CD = REGION_CD_IN and HSC_EMPLOYEE_ID = EMPLOYEE_ID_IN and rownum=1;
if rec_count <1 then
return '00';
else
select distinct NVL(control_plan,'00') into control_plan_out from BCGDHSC WHERE HSC_REGION_CD = REGION_CD_IN and HSC_EMPLOYEE_ID = EMPLOYEE_ID_IN and rownum=1;
end if;
return control_plan_out;
EXCEPTION
WHEN NO_DATA_FOUND THEN
control_plan_out := '00'; -- exception code here
RETURN control_plan_out;
WHEN OTHERS THEN
NULL;
RETURN NULL;
END;
Thanks,

Answer 1

This is not the fastest way, but it should be better then your current version.
Fast would be to use plain SQL instead of PL/SQL. The select that is inside the function can be written as a subquery inside the other SELECT. if you avoid the function then you avoid many pl/sql context swichts. My version of the functions avoids only half of them since I removed one select.
CREATE OR REPLACE FUNCTION "F_GET_PLAN"("EMPLOYEE_ID_IN" IN VARCHAR2, "REGION_CD_IN" IN VARCHAR2)
  RETURN VARCHAR2 PARALLEL_ENABLE IS
--init variable
  control_plan_out varchar2(2);
  rec_count int;
BEGIN
select NVL(control_plan,'00')
into control_plan_out
from BCGDHSC
WHERE HSC_REGION_CD = REGION_CD_IN  /*  number or string comparsion here ? */
and HSC_EMPLOYEE_ID = EMPLOYEE_ID_IN /*  number or string comparsion here ? */
and rownum=1;
return control_plan_out;
EXCEPTION
WHEN NO_DATA_FOUND THEN
  -- this already takes care of the count = 0 logic
  control_plan_out := '00'; -- exception code here
  RETURN control_plan_out;
END;Also I note that all your "IDs" are strings. Is this intended ? if not you might want to change them into proper number data types.