Small change to script and it doesn't work?

Question

This is my working script, and it counts the files of the desktop ready to use elsewhere in a larger script,
It references the desktop.
(do shell script "ls -F ~/Desktop | grep '/' | cut -d'/' -f1"
Now  I need it to reference the folders within a different location so I changed it.
(do shell script "ls -F ~/Pictures/CompletedFolders | grep '/' | cut -d'/' -f1"
And I then get the error>
tell application "Finder"
  count every file of folder "BHS_WK3_PSD"
  --> error number -1728 from folder "BHS_WK3_PSD"
Result:
error "Finder got an error: Can’t get folder \"BH_WK3_PSD\"." number -1728 from folder "BH_WK3_PSD"
How is so different?
set dtF to paragraphs of (do shell script "ls -F ~/Desktop | grep '/' | cut -d'/' -f1")
set tc to (count dtF)
set dialogString to ""
set folderCount to {}
repeat with i from 1 to tc
          set folderName to item i of dtF --<:  is the folder name, no need to use text item delimiters -->":"
          tell application "Finder"
                    set end of folderCount to {fName:folderName, fCount:count of (files in folder folderName)}
          end tell
end repeat
set totalFiles to 0
repeat with theFolder in folderCount
          set totalFiles to totalFiles + (fCount of theFolder)
          set dialogString to dialogString & return & theFolder's fName & tab & tab & tab & tab & theFolder's fCount
end repeat

Answer 1

Hello
You get the said error because the folder "BHS_WK3_PSD" is not in ~/Desktop but in ~/Pictures/CompletedFolders.
E.g., the following script returs Finder object representing ~/Desktop/a because Finder assumes folder "a" is in desktop if its container is not specified.
tell application "Finder"
    folder "a" --> folder "a" of desktop
end tell
If you want to get folder "a" in ~/Pictures/CompletedFolders, you'd need to write something like this -
set dir to (path to pictures folder from user domain as Unicode text) & "CompletedFolders" as alias
tell application "Finder"
    folder "a" of dir
end tell
Thus, as a whole:
set dir to (path to pictures folder from user domain as Unicode text) & "CompletedFolders" as alias
set dtF to paragraphs of (do shell script "ls -F " & dir's POSIX path's quoted form & " | grep '/' | cut -d'/' -f1")
set tc to (count dtF)
set dialogString to ""
set folderCount to {}
repeat with i from 1 to tc
    set folderName to item i of dtF
    tell application "Finder"
        set end of folderCount to {fName:folderName, fCount:count of (files in folder folderName of dir)}
    end tell
end repeat
set totalFiles to 0
repeat with theFolder in folderCount
    set totalFiles to totalFiles + (fCount of theFolder)
    set dialogString to dialogString & return & theFolder's fName & tab & tab & tab & tab & theFolder's fCount
end repeat
return folderCount -- # for test
Hope this helps,
H