Split string into an array (Skip first character)

Question

I have a string like:
,open,close,open
I want to parse the data into an array (without the first ','). I found and tweaked the following code, but the result was:
+<blank line> (think this is coming from the first ',')+
off
on
off
FUNCTION SPLIT (p_in_string VARCHAR2, p_delim VARCHAR2) RETURN t_array
IS
i number :=0;
pos number :=0;
lv_str varchar2(50) := p_in_string;
strings t_array;
BEGIN
-- determine first chuck of string
pos := instr(lv_str,p_delim,1,1);
-- while there are chunks left, loop
WHILE ( pos != 0) LOOP
-- increment counter
i := i + 1;
-- create array element for chuck of string
strings(i) := substr(lv_str,1,pos-1);
-- remove chunk from string
lv_str := substr(lv_str,pos+1,length(lv_str));
-- determine next chunk
pos := instr(lv_str,p_delim,1,1);
-- no last chunk, add to array
IF pos = 0 THEN
strings(i+1) := lv_str;
END IF;
END LOOP;
-- return array
RETURN strings;
END SPLIT;
I am working on a 9i database.

Answer 1

How is your collection defined? Assuming you are doing something like
SQL> create type t_array as table of varchar2(100);
  2  /
Type created.then you would just need to add an LTRIM to the code that initializes LV_STR and add appropriate EXTEND calls when you want to extend the nested table
SQL> ed
Wrote file afiedt.buf
  1  create or replace FUNCTION SPLIT (p_in_string VARCHAR2, p_delim VARCHAR2)
  2    RETURN t_array
  3  IS
  4    i number :=0;
  5    pos number :=0;
  6    lv_str varchar2(50) := ltrim(p_in_string,p_delim);
  7    strings t_array := t_array();
  8  BEGIN
  9    -- determine first chuck of string
10    pos := instr(lv_str,p_delim,1,1);
11    -- while there are chunks left, loop
12    WHILE ( pos != 0)
13    LOOP
14      -- increment counter
15      i := i + 1;
16      -- create array element for chuck of string
17      strings.extend;
18      strings(i) := substr(lv_str,1,pos-1);
19      -- remove chunk from string
20      lv_str := substr(lv_str,pos+1,length(lv_str));
21      -- determine next chunk
22      pos := instr(lv_str,p_delim,1,1);
23      -- no last chunk, add to array
24      IF pos = 0
25      THEN
26        strings.extend;
27        strings(i+1) := lv_str;
28      END IF;
29    END LOOP;
30    -- return array
31    RETURN strings;
32* END SPLIT;
SQL> /
Function created.
SQL> select split( ',a,b,c', ',' ) from dual;
SPLIT(',A,B,C',',')
T_ARRAY('a', 'b', 'c')If T_ARRAY is defined as an associative array, you wouldn't need to have the EXTEND calls but then you couldn't call the function from SQL.
Justin