SQL%BULK_ROWCOUNT collection type

Question

Hello,
My goal is to create a procedure that takes as IN parameter SQL%BULK_ROWCOUNT and count number of rows that was inserted.
PROCEDURE count_rows(rows_in IN ???)
AS
     l_counter NUMBER := 0;
BEGIN
     FOR indx IN rows_in.FIRST..rows_in.LAST LOOP
          l_counter := l_counter + rows_in(indx)
     END LOOP;
     DBMS_OUTPUT.PUT_LINE(l_counter);
END;
Does anybody knows what to put in place of ???.
Thanks!

Answer 1

34MCA2K2 wrote:
It is after all an array of positive integer. You can create nested table as below & use it.
No, you can not. Two PL/SQL associative array types are not same types even thogh they have identical definitions:
SQL> declare
  2      type type1 is table of pls_integer index by pls_integer;
  3      type type2 is table of pls_integer index by pls_integer;
  4      v_type1 type1;
  5      v_type2 type2;
  6  begin
  7      v_type2 := v_type1;
  8  end;
  9  /
    v_type2 := v_type1;
ERROR at line 7:
ORA-06550: line 7, column 16:
PLS-00382: expression is of wrong type
ORA-06550: line 7, column 5:
PL/SQL: Statement ignored
SQL>
So without knowing SQL%BULK_ROWCOUNT type name we can't create procedure. And since Oracle is not telling us type name this can't be done. Well, technically it can, but it beats the purpose:
SQL> CREATE OR REPLACE
  2    PROCEDURE count_rows(rows_in IN sys.OdciNumberList)
  3      AS
  4       l_counter NUMBER := 0;
  5  BEGIN
  6       FOR indx IN rows_in.FIRST..rows_in.LAST LOOP
  7         l_counter := l_counter + rows_in(indx);
  8       END LOOP;
  9       DBMS_OUTPUT.PUT_LINE(l_counter);
10  END;
11  /
Procedure created.
SQL> DECLARE
  2    TYPE NumList IS TABLE OF NUMBER;
  3    depts NumList := NumList(30, 50, 60);
  4    v_counts sys.OdciNumberList := sys.OdciNumberList();
  5  BEGIN
  6    FORALL j IN depts.FIRST..depts.LAST
  7      DELETE FROM emp_temp WHERE department_id = depts(j);
  8    FOR i IN depts.FIRST..depts.LAST LOOP
  9      v_counts.extend;
10      v_counts(i) := SQL%BULK_ROWCOUNT(i);
11    END LOOP;
12    count_rows(v_counts);
13  END;
14  /
56
PL/SQL procedure successfully completed.
SQL>
SY.