SQL FUNCTION to compute MEDIAN

Question

Hi
Just as we use MAX and MIN to compute the maximum and minimum values using SELECT query in SQL, does anyone know of a direct/indirect function/method to calculate the MEDIAN of a given set of values. Powerbuilder provides median function. I am looking forward to doing this using SQL/PLSQL.

Answer 1

CREATE PROCEDURE mymedian (tbl_name IN VARCHAR2,
                 col_name IN VARCHAR2,
                 rows_at_a_time IN NUMBER DEFAULT 10,
                 where_clause IN VARCHAR2 DEFAULT NULL) IS
/* Procedure to return Median value of a column in a given table */
/* Parameters                                                   */
/* tbl_name          name of table to use                       */
/* column_name       column to calculate median for             */
/* where_clause      SQL where clause without the WHERE         */
/* rows_at_a_time    number of rows to fetch into array at once */
/* If odd number of rows returns calculates average of the two  */
/* middle numbers, otherwise returns middle number.             */
f_cur INTEGER;
sql_stmnt VARCHAR2(2000);
u_tbl DBMS_SQL.Number_Table;
rows_returned NUMBER;
median_count NUMBER;
rval NUMBER;
BEGIN
   DBMS_OUTPUT.Enable(2000);
   /* Build SQL statement */
   sql_stmnt := 'SELECT '||col_name||' FROM '||tbl_name;
   IF where_clause IS NOT NULL THEN
      sql_stmnt := sql_stmnt ||' WHERE '||where_clause;
   END IF;
   sql_stmnt := sql_stmnt||' ORDER BY '||col_name;
   f_cur := DBMS_SQL.Open_Cursor;
   DBMS_SQL.Parse(f_cur,sql_stmnt,1);
   DBMS_SQL.Define_Array(f_cur,1,u_tbl,rows_at_a_time,1);
   rows_returned := DBMS_SQL.Execute(f_cur);
   /* Step through cursor getting rows_at_a_time rows */
   LOOP
      rows_returned := DBMS_SQL.Fetch_Rows(f_cur);
      DBMS_SQL.Column_Value(f_cur,1,u_tbl);
      EXIT WHEN rows_returned <> rows_at_a_time;
   END LOOP;
   DBMS_SQL.Close_Cursor(f_cur);
   median_count := u_tbl.Count;
   IF MOD(median_count,2) = 0 THEN
      rval := (u_tbl(median_count/2) + u_tbl((median_count/2) + 1))/2;
   ELSE
      rval := u_tbl(CEIL(median_count/2));
   END IF;
   DBMS_OUTPUT.Put_Line ('Median of column '||col_name||' for table '||
                         tbl_name||' is '||rval);
EXCEPTION WHEN OTHERS THEN
   IF DBMS_SQL.Is_Open(f_cur) THEN
      DBMS_SQL.Close_Cursor(f_cur);
      DBMS_OUTPUT.Put_Line('Error: '||sqlerrm);
   END IF;
END;Set serveroutput on before calling this proc.