SSO Validation from OAF custom page.

Question

Hi All,
We have 11.5.10Cu2 configured with Single Sign On.
Both are running in different servers.
I have a custom OAF Page(Approval Page) from that page I want to validate
a Single Sign on user id.
ie, I don't want to set any session value or cookies just want to validate a SSO username from my OAF Controller or from my AMImpl.
Like giving a request to SSO Server with username/password and get true or false according to the validation and return to my custom page.
Thanks.
With Regards,
Kali.
OSSI.

Answer 1

Yes Tapash,
Here is the sample code,
Spec:
CREATE OR REPLACE PACKAGE APPS.xxpo_oa_pdt_ordering_pkg AS
PROCEDURE authenticate_user
(p_username IN VARCHAR2
,p_password IN VARCHAR2
,p_validation_type IN VARCHAR2 DEFAULT 'SSO'-- FND or SSO
,p_check_approver IN VARCHAR2 DEFAULT 'Y'
,x_return_status IN OUT NOCOPY VARCHAR2
,x_msg_data IN OUT NOCOPY VARCHAR2
,x_msg_count IN OUT NOCOPY NUMBER
Body:
PROCEDURE authenticate_user
(p_username IN VARCHAR2
,p_password IN VARCHAR2
,p_validation_type IN VARCHAR2 DEFAULT 'SSO' -- FND or SSO
,p_check_approver IN VARCHAR2 DEFAULT 'Y'
,x_return_status IN OUT NOCOPY VARCHAR2
,x_msg_data IN OUT NOCOPY VARCHAR2
,x_msg_count IN OUT NOCOPY NUMBER
AS
l_return PLS_INTEGER;
ldap_host VARCHAR2(256);
ldap_port PLS_INTEGER;
ldap_user VARCHAR2(256);
ldap_passwd VARCHAR2(256);
ldap_base VARCHAR2(256);
retval PLS_INTEGER;
my_session DBMS_LDAP.SESSION;
subscriber_handle DBMS_LDAP_UTL.HANDLE;
sub_type PLS_INTEGER;
subscriber_id VARCHAR2(2000);
my_pset_coll DBMS_LDAP_UTL.PROPERTY_SET_COLLECTION;
my_property_names DBMS_LDAP.STRING_COLLECTION;
my_property_values DBMS_LDAP.STRING_COLLECTION;
user_handle DBMS_LDAP_UTL.HANDLE;
user_id VARCHAR2(2000);
user_type PLS_INTEGER;
user_password VARCHAR2(2000);
my_mod_pset DBMS_LDAP_UTL.MOD_PROPERTY_SET;
my_attrs DBMS_LDAP.STRING_COLLECTION;
user_dn VARCHAR2(256);
BEGIN
write_to_log(FND_LOG.LEVEL_PROCEDURE,'Start of authenticate_user');
write_to_log(FND_LOG.LEVEL_STATEMENT,'Parameters: p_username='||p_username||' p_validation_type='||p_validation_type||' p_check_approver= '||p_check_approver);
x_return_status := FND_API.G_RET_STS_SUCCESS;
x_msg_data := NULL;
x_msg_count:= NULL;
IF p_check_approver = 'Y' THEN
IF xxpo_oa_pdt_util_pkg.is_valid_approver(xxpo_oa_pdt_util_pkg.get_fnd_user_id(p_username)) <> 'Y' THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error: User is not a valid approver.');
x_return_status := FND_API.G_RET_STS_ERROR;
x_msg_data := 'XXPO_OA_PDT_INVALID_APPR';
x_msg_count:= 1;
RAISE FND_API.G_EXC_ERROR;
END IF;
END IF;
IF p_validation_type = 'FND' THEN
l_return := FND_SSO.authenticate_user
(p_user => p_username
,p_password => p_password
IF l_return <> 0 THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error: Invalid FND user name and password.');
x_return_status := FND_API.G_RET_STS_ERROR;
x_msg_data := 'XXPO_OA_PDT_INVALID_USER';
x_msg_count:= 1;
RAISE FND_API.G_EXC_ERROR;
END IF;
ELSE
--verify that the XXPO%LDAP% profiles are set
IF FND_PROFILE.VALUE('XXPO_OA_PDT_LDAP_HOST') IS NULL OR
FND_PROFILE.VALUE('XXPO_OA_PDT_LDAP_PORT') IS NULL OR
FND_PROFILE.VALUE('XXPO_OA_PDT_LDAP_ADMIN_USER') IS NULL OR
FND_PROFILE.VALUE('XXPO_OA_PDT_LDAP_ADMIN_PWD') IS NULL OR
FND_PROFILE.VALUE('XXPO_OA_PDT_LDAP_BASE') IS NULL OR
FND_PROFILE.VALUE('XXPO_OA_PDT_LDAP_USER_TYPE') IS NULL THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error: One or more of XXPO%LDAP% Profiles are not set.');
x_msg_data := 'XXPO_OA_PDT_LDAP_PROF_MISSING';
x_msg_count := 1;
RAISE FND_API.G_EXC_ERROR;
END IF;
-- Please customize the following variables as needed
ldap_user := gc_ldap_user;
ldap_passwd := gc_ldap_passwd;
sub_type := DBMS_LDAP_UTL.TYPE_DEFAULT;
subscriber_id := NULL;
user_type := gc_ldap_user_type;
user_id := p_username;
user_password := p_password;
-- Choosing exceptions to be raised by DBMS_LDAP library.
DBMS_LDAP.USE_EXCEPTION := TRUE;
write_to_log(FND_LOG.LEVEL_STATEMENT,'Input Parameters: ');
write_to_log(FND_LOG.LEVEL_STATEMENT,'LDAP HOST: ' || gc_ldap_host );
write_to_log(FND_LOG.LEVEL_STATEMENT,'LDAP PORT: ' || gc_ldap_port);
write_to_log(FND_LOG.LEVEL_STATEMENT,'LDAP BIND USER: ' || ldap_user);
write_to_log(FND_LOG.LEVEL_STATEMENT,'USER ID : ' || user_id);
write_to_log(FND_LOG.LEVEL_STATEMENT,'----------------------------------');
-- Connect to the LDAP server
-- and obtain and ld session.
write_to_log(FND_LOG.LEVEL_STATEMENT,'Connecting to ' || gc_ldap_host || ' ...');
my_session := DBMS_LDAP.init(gc_ldap_host, gc_ldap_port);
write_to_log(FND_LOG.LEVEL_STATEMENT,': Connected.');
-- Bind to the directory
write_to_log(FND_LOG.LEVEL_STATEMENT,'Binding to directory as ' || ldap_user || ' ... ');
retval := DBMS_LDAP.simple_bind_s(my_session, ldap_user, ldap_passwd);
write_to_log(FND_LOG.LEVEL_STATEMENT,': Successful.');
-- Create Subscriber Handle
write_to_log(FND_LOG.LEVEL_STATEMENT,'Creating Subscriber Handle ... ');
retval := DBMS_LDAP_UTL.create_subscriber_handle(subscriber_handle,
sub_type,
subscriber_id);
IF retval != DBMS_LDAP_UTL.SUCCESS THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error: create_subscriber_handle returns : ' || TO_CHAR(retval));
x_msg_data := 'XXPO_OA_PDT_SUBS_HANDLE_ERROR';
x_msg_count:= 1;
RAISE FND_API.G_EXC_ERROR;
END IF;
write_to_log(FND_LOG.LEVEL_STATEMENT,': Successful.');
-- Create User Handle
write_to_log(FND_LOG.LEVEL_STATEMENT,'Creating user handle for ' || user_id || ' ... ');
retval := DBMS_LDAP_UTL.create_user_handle(user_handle,user_type,user_id);
IF retval != DBMS_LDAP_UTL.SUCCESS THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error: create_user_handle returns : ' || TO_CHAR(retval));
x_msg_data := 'XXPO_OA_PDT_USER_HANDLE_ERROR';
x_msg_count:= 1;
RAISE FND_API.G_EXC_ERROR;
END IF;
write_to_log(FND_LOG.LEVEL_STATEMENT,': Successful.');
-- Set user handle properties
-- (link subscriber to user )
retval := DBMS_LDAP_UTL.set_user_handle_properties(user_handle,
DBMS_LDAP_UTL.SUBSCRIBER_HANDLE,
subscriber_handle);
IF retval != DBMS_LDAP_UTL.SUCCESS THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error: set_user_handle_properties returns : ' || TO_CHAR(retval));
x_msg_data := 'XXPO_OA_PDT_USER_SUBS_ERROR';
x_msg_count:= 1;
RAISE FND_API.G_EXC_ERROR;
END IF;
-- Authenticate User
write_to_log(FND_LOG.LEVEL_STATEMENT,'Authenticating user ' || user_id || ' ... ');
retval := DBMS_LDAP_UTL.authenticate_user(my_session,
user_handle,
DBMS_LDAP_UTL.AUTH_SIMPLE,
user_password,
NULL);
IF retval != DBMS_LDAP_UTL.SUCCESS THEN
-- Handle Errors
write_to_log(FND_LOG.LEVEL_ERROR,'Authentification error : ' || TO_CHAR(retval));
x_msg_data := 'XXPO_OA_PDT_INVALID_USER';
x_msg_count:= 1;
-- below only for debugging purpose
IF retval = -5 THEN
write_to_log(FND_LOG.LEVEL_ERROR,'User unknown');
ELSIF retval = -16 THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Incorrect password');
ELSIF retval = DBMS_LDAP_UTL.PARAM_ERROR THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Invalid input parameters.');
ELSIF retval = DBMS_LDAP_UTL.GENERAL_ERROR THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Authentication failed.');
ELSIF retval = DBMS_LDAP_UTL.NO_SUCH_USER THEN
write_to_log(FND_LOG.LEVEL_ERROR,'USER doesn''t exist.');
ELSIF retval = DBMS_LDAP_UTL.MULTIPLE_USER_ENTRIES THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Multiple NUMBER OF USER DN entries exist IN the DIRECTORY FOR the given USER.');
ELSIF retval = DBMS_LDAP_UTL.INVALID_SUBSCRIBER_ORCL_CTX THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Invalid Subscriber Oracle Context.');
ELSIF retval = DBMS_LDAP_UTL.NO_SUCH_SUBSCRIBER THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Subscriber doesn''t exist.');
ELSIF retval = DBMS_LDAP_UTL.MULTIPLE_SUBSCRIBER_ENTRIES THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Multiple NUMBER OF subscriber DN entries exist IN the DIRECTORY FOR the given subscriber.');
ELSIF retval = DBMS_LDAP_UTL.INVALID_ROOT_ORCL_CTX THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Invalid Root Oracle Context.');
ELSIF retval = DBMS_LDAP_UTL.AUTH_PASSWD_CHANGE_WARN THEN
write_to_log(FND_LOG.LEVEL_ERROR,'PASSWORD should be changed.');
ELSIF retval = DBMS_LDAP_UTL.ACCT_TOTALLY_LOCKED_EXCEPTION THEN
write_to_log(FND_LOG.LEVEL_ERROR,'USER account IS locked.');
ELSIF retval = DBMS_LDAP_UTL.PWD_EXPIRED_EXCEPTION THEN
write_to_log(FND_LOG.LEVEL_ERROR,'USER PASSWORD has expired.');
ELSIF retval = DBMS_LDAP_UTL.PWD_GRACELOGIN_WARN THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Grace login FOR USER.');
ELSE
write_to_log(FND_LOG.LEVEL_ERROR,'Authentification error : ' || TO_CHAR(retval));
END IF ;
RAISE FND_API.G_EXC_ERROR;
ELSE
write_to_log(FND_LOG.LEVEL_STATEMENT,'Authentication: Successful.');
END IF;
-- Free Mod Propertyset
DBMS_LDAP_UTL.free_mod_propertyset(my_mod_pset);
-- Free handles
DBMS_LDAP_UTL.free_handle(subscriber_handle);
DBMS_LDAP_UTL.free_handle(user_handle);
-- unbind from the directory
write_to_log(FND_LOG.LEVEL_STATEMENT,'Unbinding from directory ... ');
retval := DBMS_LDAP.unbind_s(my_session);
IF retval != DBMS_LDAP_UTL.SUCCESS THEN
write_to_log(FND_LOG.LEVEL_ERROR,'unbind_s returns : ' || TO_CHAR(retval));
x_msg_data := 'XXPO_OA_PDT_UNBIND_ERROR';
x_msg_count:= 1;
ELSE
write_to_log(FND_LOG.LEVEL_STATEMENT,': Successful.');
END IF;
write_to_log(FND_LOG.LEVEL_STATEMENT,'OK' ) ;
END IF;
write_to_log(FND_LOG.LEVEL_PROCEDURE,'End of authenticate_user');
EXCEPTION
WHEN FND_API.G_EXC_ERROR THEN
x_return_status := FND_API.G_RET_STS_ERROR;
--message already set
WHEN OTHERS THEN
write_to_log(FND_LOG.LEVEL_ERROR,'Error code : ' || TO_CHAR(SQLCODE));
write_to_log(FND_LOG.LEVEL_ERROR,'Error Message : ' || SQLERRM);
write_to_log(FND_LOG.LEVEL_ERROR,'Exception encountered .. returning');
x_return_status := FND_API.G_RET_STS_ERROR;
x_msg_data := 'XXPO_OA_PDT_INVALID_USER';
x_msg_count:= 1;
END authenticate_user;
Hope this help others.
Thanks.
With Regards,
Kali.
OSSI.