Storing MS-Word and PDF documents in database uploaded through APEX

Question

I want to allow users to upload MS-Word and PDF documents they have created / edited outside of the APEX app for storage in the database along with the other app data.
I know that I should use a file browse item in a region for this purpose.
I have a some questions:
1. What database datatype is best for storing MS-Word and PDF docs? CLOB?
2. How can the user see that the file has been uploaded? In other words, how can they see that the filename has been uploaded? I want to show this on the page for later viewing. I have uploaded a document, but later, I have no way to see that the document has in fact been uploaded. From the APEX page, the file browse item does not indicate whether or not a file has previously been uploaded.
3. How can the user download the previously uploaded document?
4. Is there a way to give users the capability to edit a document in an APEX app where they can do MS-Word-like editing (font size, font type, bold, italics, etc.)?
I know I've asked a lot here and I appreciate your input.
-Reid

Answer 1

In my case, I am uploading screenshots of my application and then displaying them. You can feel free to use it if you want, the code was mostly taken from examples of file uploads posted by others. Here is some code to get you started:
File Table description
CREATE TABLE FILE_UPLOAD
   (name           VARCHAR2(4000) PRIMARY KEY,
    subject        VARCHAR2(4000),
    id             NUMBER,
    blob_content   BLOB,
    mime_type      VARCHAR2(4000),
    PAGE_ID        NUMBER);File Upload Procedure
IF ( :P20_FILE_NAME is not null ) THEN
     INSERT INTO FILE_UPLOAD (id, NAME, SUBJECT, BLOB_CONTENT, MIME_TYPE, PAGE_ID)
      SELECT ID,:P20_FILE_NAME,:P20_SUBJECT, blob_content, mime_type, :P20_PAGE_ID
            FROM APEX_APPLICATION_FILES
            WHERE name = :P20_FILE_NAME;
   DELETE from APEX_APPLICATION_FILES WHERE name = :P20_FILE_NAME;
  END IF;Download Image Procedure Definition
CREATE OR REPLACE PROCEDURE download_my_file(p_file in number) AS
        v_mime  VARCHAR2(48);
        v_length  NUMBER;
        v_file_name VARCHAR2(2000);
        Lob_loc  BLOB;
BEGIN
  SELECT MIME_TYPE, BLOB_CONTENT, name,DBMS_LOB.GETLENGTH(blob_content)
         INTO v_mime,lob_loc,v_file_name,v_length
    FROM FILE_UPLOAD
   WHERE id = p_file;
    -- set up HTTP header
    -- use an NVL around the mime type and
    -- if it is a null set it to application/octect
    -- application/octect may launch a download window from windows
  owa_util.mime_header( nvl(v_mime,'application/octet'), FALSE );
    -- set the size so the browser knows how much to download
  htp.p('Content-length: ' || v_length);
    -- the filename will be used by the browser if the users does a save as
  htp.p('Content-Disposition:  attachment; filename="'||replace(replace(substr(v_file_name,instr(v_file_name,'/')+1),chr(10),null),chr(13),null)|| '"');
    -- close the headers           
  owa_util.http_header_close;
    -- download the BLOB
  wpg_docload.download_file( Lob_loc );
end download_my_file;
/make sure to grant the procedure rights for use by anyone
GRANT EXECUTE ON download_my_file TO PUBLICDisplay Image Procedure Definition
create or replace PROCEDURE "DISPLAY_IMAGE"
  inID NUMBER
AS
  vMIME VARCHAR2(48);
  vLENGTH NUMBER;
  vFILENAME VARCHAR2(2000);
  vBLOB BLOB;
BEGIN
  SELECT MIME_TYPE, BLOB_CONTENT, NAME, DBMS_LOB.GETLENGTH(BLOB_CONTENT)
    INTO vMIME, vBLOB, vFILENAME, vLENGTH
  FROM FILE_UPLOAD
  WHERE ID = inID;
  owa_util.mime_header(nvl(vMIME, 'application/octet'), FALSE);
  htp.p('Content-length: ' || vLENGTH);
  owa_util.http_header_close;
  wpg_docload.download_file(vBLOB);
END;
/Again, make sure everyone has rights to execute the procedure.
GRANT EXECUTE ON DISPLAY_IMAGE TO PUBLICThis doesn't create an editor inside the browser, it just creates a simple upload/display process. For a WYSIWYG editor that handles PDF or Docs, you'll need something far more sophisticated, and I can't suggest anything there.