Strip resource forks and .DS_Store files from folder

Question

I'm transferring stuff from my Mac to a Windows machine using a FAT32 formatted keydrive, and want to eliminate the various dot files from folders before I copy them to the Windows box. I had tried using a Terminal command, which was tedious and at one point I mistyped something and managed to nuke one of the folders on the drive. After a search, I found this script at MacOSXHints:
on run
display dialog "Drag a removable disk icon here to have it cleaned and ejected"
end run
on open selectedItem
-- get a text version of the volume name and remove the trailing colon :
set volumeName to selectedItem as string
set volumeName to characters 1 thru (the (length of volumeName) - 1) of volumeName as string
if (list disks) contains volumeName then
do shell script "find '/Volumes/" & volumeName & "' -name '.DS_Store' -exec rm '{}' \\;"
do shell script "find '/Volumes/" & volumeName & "' -name '._*' -exec rm '{}' \\;"
try
do shell script "rm -rd '/Volumes/" & volumeName & "/.Trashes'"
do shell script "rm -rd '/Volumes/" & volumeName & "/.TemporaryItems'"
end try
try
tell application "Finder" to eject disk volumeName
end try
end if
end open
It worked great, but took a bit of time to run. I no longer need to clean the whole drive again, just specific folders I add to the drive now. Unfortunately I don't actually know how to write Applescript, I can just sometimes adapt an existing script to my needs, but this adaptation is beyond my meagre abilities. Last night I was copying a couple of folders to the drive, then using the Terminal "find execute remove" command to get rid of the dot files after the fact. I would like to have an Applescript droplet, so that I drop the folder onto it and the resource forks are stripped off and the .DS_Store files are removed before I copy the folder to the key drive.
Any help appreciated!
Francine
Francine
Schwieder

Answer 1

Make a duplicate of the folder you want to transfer on your hard disk, and then run the following on the duplicate:
on open droppedItems
repeat with anItem in droppedItems
if (folder of (info for anItem)) is false then
display dialog (anItem as string) & " was not proccessed." & return & return & "Folders only please"
else
do shell script "find " & quoted form of POSIX path of anItem & " -name \".DS_Store\" -exec rm '{}' \\;"
do shell script "find " & quoted form of POSIX path of anItem & " -name \"._*\" -exec rm '{}' \\;"
do shell script "ditto --norsrc " & quoted form of POSIX path of anItem & " '/Volumes/volumename/pathname/'"
end if
end repeat
end open
The second do shell script line may not be needed in this variation.
(21517)