Switch playlist of itunes dj automatically after certain time

Question

hello,
i have 2 playlists in itunes.  i would like to do the following:
1) itunes plays the first playlist by playing the songs in a random order and continues to do this, until
2) after a certain time (say 30 minutes), itunes switches to the second playlist and plays these songs in a random order and continues to do this for another 30 minutes. 
now, for the randomization, i could use shuffle with repeat, but the problem with that is that after all songs are played in the playlist, the exact order repeats again.  i don't want this.  i want itunes to choose a random song from the playlist each time, even if it is the same one twice in a row.  as i understand it, the itunes dj allows this possibility.
for the automatic switching, i read that i can use apple's automator to accomplish this.  however, this is my first time using it.  i chose workflow, and then music under 'actions'.  i see a bunch of stuff for itunes but there is no itunes dj. 
i don't know where to go from here or if there is an easier way to do this.  does anyone have any ideas?
thank you.

Answer 1

In my first script : if the user press the "Camcel" button in the dialogue, the script will give an error.
Here is the corrected script.
global tPlaylists, DJ_Playlist, tIndex, firstTime
property durationTime : 1800 --seconds, equal 30 minutes
on run
    set tPlaylists to {}
    set tIndex to 1
    set firstTime to true
    tell application "iTunes" to set {tnames, uPlaylists} to {name, it} of (user playlists whose its special kind is none)
    set j to (count tnames)
    repeat with i from 1 to j
        set item i of tnames to "" & i & " -  " & item i of tnames
    end repeat
    set n to my choosePlaylist(tnames, "first")
    if n is not "" then
        set end of tPlaylists to item n of uPlaylists
        set item n of tnames to missing value
        set tnames to text of tnames -- remove name of first selected playlist from tnames
        set n to my choosePlaylist(tnames, "second")
        if n is not "" then
            set end of tPlaylists to item n of uPlaylists
            tell application "iTunes"
                set DJ_Playlist to (first playlist whose special kind = Party Shuffle) -- iTunes DJ playlist
                tell front browser window to if exists then set view to DJ_Playlist
                activate
            end tell
            my mixTracks() -- add random tracks in the iTunes DJ playlist
        end if
    end if
    if n is "" then quit -- the user pressed the Cancel button
end run
on idle
    -- set the next index
    if tIndex = 1 then
        set tIndex to 2 -- the second playlist selected by the user
    else
        set tIndex to 1 -- the first playlist selected by the user
    end if
    my mixTracks() -- add 30+ minutes of random tracks from the next playlist
    return durationTime
end idle
on mixTracks()
    set selPlaylist to (item tIndex of tPlaylists)
    tell application "iTunes"
        set b to running
        if b then
            set tTime to durationTime + (duration of DJ_Playlist)
            set trackIndex to (count tracks of DJ_Playlist)
            -- add tracks to iTunes DJ playlist until its duration > (aproximately 30+ minutes of added tracks)
            repeat until duration of DJ_Playlist > tTime
                duplicate (some track of selPlaylist) to DJ_Playlist
            end repeat
            if firstTime then -- play immediately the first added track in the iTunes DJ playlist
                set firstTime to false
                play track (trackIndex + 1) of DJ_Playlist
            end if -- else continues to play tracks normally.
        end if
    end tell
    if not b then quit -- iTunes is closed by the user, quit this script
end mixTracks
on quit
    continue quit -- quit this application
end quit
on choosePlaylist(l, t)
    activate
    set x to (choose from list l with prompt "Select your " & t & " playlist") as string
    if x is not "false" then return (word 1 of x) as integer
    return ""
end choosePlaylist
Also, I added a condition to exit the script if the user quit iTunes, but the script only works once every thirty minutes.