Sync manually managed iPod played count etc with multiple iTunes libraries

Question

I have my music and podcasts spread out in different iTunes libraries. So if I sync items, tracks from another library are deleted from my iPod therefore I manually manage my tracks. The downside is when you connect a manual iPod to iTunes your ratings, played date, count don't get synced with the iTunes Library. So I created a simple applescript that syncs tracks on specified playlists on your iPod with matching ones in iTunes. I realise applescripts exist to do this already but I wanted something which required no user input and simply did what would happen if the iPod was in sync mode.
The applescript:
tell application "iTunes"
    set iPodName to ""
    set syncPlaylists to {"Music", "Podcasts"}
    repeat with syncPlaylist in syncPlaylists
        repeat with i from 1 to count of sources
            if the kind of source i is iPod then
                set iPodName to name of source i as string
                set ipodPlaylistId to (first playlist of source iPodName whose name is syncPlaylist)
            end if
        end repeat
        set musicLibraryId to (first playlist whose name is syncPlaylist)
        --update every track itunes syncPlaylist with data from ipod syncPlaylist
        repeat with ipodPlaylistTracksCounter from 1 to count of tracks of ipodPlaylistId
            set ipodTrack to track ipodPlaylistTracksCounter of ipodPlaylistId
            set ipodTrackData to {name, artist, album, played date, played count, rating} of ipodTrack
            set foundTracksInPlaylist to (every track of musicLibraryId whose ((name is item 1 of ipodTrackData) and (artist is item 2 of ipodTrackData) and (album is item 3 of ipodTrackData)))
            repeat with eachFoundTrackInPlaylist in foundTracksInPlaylist
                --use try blocks in case of missing data
                try
                    set played date of eachFoundTrackInPlaylist to item 4 of ipodTrackData
                end try
                try
                    set played count of eachFoundTrackInPlaylist to item 5 of ipodTrackData
                end try
                try
                    set rating of eachFoundTrackInPlaylist to item 6 of ipodTrackData
                end try
            end repeat
        end repeat
    end repeat
end tell
Mac Mini G4   Mac OS X (10.4.8)   1 GB RAM, ATI 9200 32MB, Samsung 940BW 19" Widescreen TFT LCD monitor

Answer 1

btw if you don't know how to use applescripts. Open script editor, you'll find it in Applications/Applescript/. Open a new window and copy the code in it and press compile. Save as a script and place in your home folder at ~/Library/iTunes/Scripts, create a Scripts folder if it doesn't exist. Alternatively, save as an application, on opening it will do its magic! Make sure an iPod is mounted in iTunes otherwise an error message will pop up.