Table Control[Accept Input Only] - "ENTER" Key

Question

Hi Folks,
I'm reviving this unanswered thread in relation to table control: when the user press enter, all the values entered disappear.
[url]Re: Table control (Enter key)[url]
I have a table control that accepts "ONLY" input, meaning to say, there will be no pre-loading of data in the PBO, so it will loop through the table control itself instead of looping from an internal table.
Issue: Whenever I press "ENTER" in any column/row of my table control, ALL the values I entered disappear.
PBO:
PROCESS BEFORE OUTPUT.
  MODULE CLEAR_OKCODE.
  MODULE LOAD_TABLECTRL.
  LOOP WITH CONTROL TC_DATA.
    MODULE READ_DATA.
  ENDLOOP.
module READ_DATA output.
  READ TABLE T_DATA INTO WA_DATA INDEX TC_DATA-current_line.
  data : line_count type i.
  "to increase the number of lines in table control dynamically
  describe TABLE t_data lines line_count.
  TC_DATA-lines = line_count + 10.
endmodule. 
PAI:
PROCESS AFTER INPUT.
  LOOP WITH CONTROL TC_DATA.
    MODULE MODIFY_DATA.
  ENDLOOP.
module MODIFY_DATA input.
WHEN 'CREATE'.
  "subroutines are here, etc.
WHEN 'DELETE'.
WHEN 'BACK'.
  LEAVE TO SCREEN 0.
endmodule.
In my ABAP Debug, the value of SY-UCOMM is BLANK whenever I press Enter.
Thanks.

Answer 1

Hi
Your code seems to be rght only the MODIFY statament is useless:
module READ_DATA output.
  READ TABLE T_ID_CHECK INTO WA_ID_CHECK INDEX TC_ID-current_line.
  IF SY-SUBRC EQ 0.
    ZQID_CHECK-WERKS = WA_ID_CHECK-WERKS.
    ZQID_CHECK-MATNR = WA_ID_CHECK-MATNR.
    ZQID_CHECK-LICHA = WA_ID_CHECK-LICHA.
    ZQID_CHECK-LIFNR = WA_ID_CHECK-LIFNR.
  ELSE.
    CLEAR ZQID_CHECK.
  ENDIF.
endmodule.
Now before LOOP of PBO try to set the lines of table control to be display, I've created this report on my system and it works fine:
.CONTROLS T_CTRL TYPE TABLEVIEW USING SCREEN 100.
DATA: BEGIN OF ITAB OCCURS 0,
          WERKS LIKE MARC-WERKS,
          MATNR LIKE MARC-MATNR,
          LIFNR LIKE LFA1-LIFNR,
      END   OF ITAB.
DATA: WA LIKE ITAB.
START-OF-SELECTION.
  DO 4 TIMES.
    ITAB-WERKS = '5010'.
    ITAB-MATNR = '1234567890'.
    ITAB-LIFNR = '0000000001'.
    APPEND ITAB.
  ENDDO.
  CALL SCREEN 100.
PROCESS BEFORE OUTPUT.
  MODULE SET_T_CTRL.
  LOOP WITH CONTROL T_CTRL.
    MODULE READ_DATA.
  ENDLOOP.
PROCESS AFTER INPUT.
  LOOP WITH CONTROL T_CTRL.
    MODULE MODIFY_DATA.
  ENDLOOP.
MODULE SET_T_CTRL OUTPUT.
  DESCRIBE TABLE ITAB LINES T_CTRL-LINES.
ENDMODULE.                 " SET_T_CTRL  OUTPUT 
MODULE READ_DATA OUTPUT.
  READ TABLE ITAB INDEX T_CTRL-CURRENT_LINE.
  IF SY-SUBRC = 0.
    MOVE-CORRESPONDING ITAB TO WA.
  ELSE.
    CLEAR WA.
  ENDIF.
ENDMODULE.                 " READ_DATA  OUTPUT
MODULE MODIFY_DATA INPUT.
  MODIFY ITAB FROM WA INDEX T_CTRL-CURRENT_LINE.
  IF SY-SUBRC NE 0.
    CHECK NOT WA IS INITIAL.
    APPEND WA TO ITAB.
  ENDIF.
ENDMODULE.                 " MODIFY_DATA  INPUT