Tcode exit

Question

hi all,
       is there any tcode where i enter the tcode and it gives me the exits implemented for that tcode , not the list of exits for the tcode.

Answer 1

There is no Tcode but you can use the following custom program to find out the Active exits in a package.
*& Report  ZTEST_READ_EXIT
REPORT  ztest_read_exit.
TYPE-POOLS: abap.
TYPES: BEGIN OF types_exits,
       obj_name TYPE obj_name,
       korrnum  TYPE trkorr_old,
       cproject TYPE cproject,
       project  TYPE modname,
       active   TYPE abadr_flag,
       END OF types_exits.
CONSTANTS: c_prog TYPE pgmid     VALUE 'R3TR',
           c_exit TYPE trobjtype VALUE 'SMOD'.
DATA: gt_exits TYPE STANDARD TABLE OF types_exits.
SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE text-s01.
PARAMETER: p_dev TYPE devclass OBLIGATORY,
           p_act TYPE boole_d DEFAULT abap_true.
SELECTION-SCREEN: END OF BLOCK b1.
** Start of Selection
START-OF-SELECTION.
  SELECT obj_name
         korrnum
         cproject
         FROM tadir INTO TABLE gt_exits
         WHERE pgmid    = c_prog
           AND object   = c_exit
           AND devclass = p_dev.
  IF sy-subrc = 0.
** Modify the table to find only active exits.
    PERFORM sub_find_active.
** Display the output
    PERFORM sub_display_output.
  ELSE.
  ENDIF.
*&      Form  SUB_FIND_ACTIVE
*       Find Only Active Exits
FORM sub_find_active .
  FIELD-SYMBOLS: <l_exit> TYPE types_exits.
  DATA: l_mod TYPE modmember.
  LOOP AT gt_exits ASSIGNING <l_exit>.
    l_mod = <l_exit>-obj_name.
    CALL FUNCTION 'ABADR_CHECK_EXIT_ACTIVE'
      EXPORTING
        i_enhancement = l_mod
      IMPORTING
        e_project     = <l_exit>-project
        e_is_active   = <l_exit>-active.
  ENDLOOP.
  IF p_act = abap_true.
    DELETE gt_exits WHERE active EQ abap_false.
  ENDIF.
ENDFORM.                    " SUB_FIND_ACTIVE
*&      Form  SUB_DISPLAY_OUTPUT
*       text
FORM sub_display_output .
  DATA: lt_return   TYPE REF TO cl_salv_table.
** Call the SALV table
  TRY.
      CALL METHOD cl_salv_table=>factory
        IMPORTING
          r_salv_table = lt_return
        CHANGING
          t_table      = gt_exits.
    CATCH cx_salv_msg .
  ENDTRY.
** Display the output
  lt_return->display( ).
ENDFORM.                    " SUB_DISPLAY_OUTPUT
Hope That Helps
Anirban M.