Transpose formatted table into raw data style using a Macro

Question

Hi there, 
Need a wizz to advise how to use a macro to transpose Sport A data presently displayed like this...
Oct-12
Nov-12
Dec-12
Jan-13
Feb-13
Mar-13
Apr-13
May-13
Jun-13
Jul-13
Aug-13
Sep-13
Oct-13
Nov-13
Dec-13
Jan-14
a
£56,515.99
£51,766.62
£61,609.73
£44,293.19
£46,076.85
£43,590.94
£43,963.03
£39,659.15
£49,787.18
£53,569.27
£48,589.30
£62,287.33
£49,197.83
61379.25
76478.38
80613.88
into this...
Discipline
Month
Revenue
Sport A
Oct-12
56515.99
Sport A
Nov-12
51766.62
Sport A
Dec-12
61609.73
Sport A
Jan-13
44293.19
Sport A
Feb-13
46076.85
Sport A
Mar-13
43590.94
Sport A
Apr-13
43963.03
Sport A
May-13
39659.15
Sport A
Jun-13
49787.18
Sport A
Jul-13
53569.27
Sport A
Aug-13
48589.3
Sport A
Sep-13
62287.33
Sport A
Oct-13
49197.83
Sport A
Nov-13
61379.25
Sport A
Dec-13
76478.38
Sport A
Jan-14
80613.88
Would prefer to not manually transpose this data. I have 22 Sports to do this for so you can appreciate the question. 
Is there a macro template in excel that creates a loop through the rows that then stops when it has no more data to process? At times there are gaps. I.e. some months there is no data. 
Can anybody help?

Answer 1

Here you go:
Sub TransposeData()
Dim wshS As Worksheet
Dim wshT As Worksheet
Dim lngSRow As Long
Dim lngSCol As Long
Dim lngLastSRow As Long
Dim lngLastSCol As Long
Dim lngTRow As Long
Dim strDiscipline As String
Application.ScreenUpdating = False
Set wshS = ActiveSheet
lngLastSRow = wshS.Cells(wshS.Rows.Count, 1).End(xlUp).Row
lngLastSCol = wshS.Cells(1, wshS.Columns.Count).End(xlToLeft).Column
Set wshT = Worksheets.Add(After:=wshS)
wshT.Cells(1, 1).Value = "Discipline"
wshT.Cells(1, 2).Value = "Month"
wshT.Cells(1, 3).Value = "Revenue"
lngTRow = 1
For lngSRow = 2 To lngLastSRow
strDiscipline = "Sport " & UCase(wshS.Cells(lngSRow, 1).Value)
For lngSCol = 2 To lngLastSCol
lngTRow = lngTRow + 1
wshT.Cells(lngTRow, 1).Value = strDiscipline
wshT.Cells(lngTRow, 2).Value = wshS.Cells(1, lngSCol).Value
wshT.Cells(lngTRow, 3).Value = wshS.Cells(lngSRow, lngSCol).Value
Next lngSCol
Next lngSRow
wshT.Range("B2:B" & lngTRow).NumberFormat = wshS.Cells(1, 2).NumberFormat
wshT.Range("C2:C" & lngTRow).NumberFormat = wshS.Cells(2, 2).NumberFormat
Application.ScreenUpdating = True
End Sub
Regards, Hans Vogelaar (http://www.eileenslounge.com)