Trapping - "Do you want to save changes" alert button pressed

Question

When exiting a data block with unsaved changes, the user is prompted with "Do you want to save the changes you have made ?" The possible button click responses are "Yes", "No", "Cancel"
Is there a way to programmatically catch the click on the "Cancel" button ?
Oracle Forms 10g

Answer 1

Thanks for the suggestion W1zard. Here is the solution that I have come up based on the recommendation.
Essentially I create my own custom alert that mimics the system generated alert. In this manner I am able to control the behavior based on the alert button pressed by the user. This method also suppresses the system generated alert, so the user isn't prompted twice.
At the form level I have created the KEY-EXIT and the KEY-ENTQRY triggers. Additionally I created an ALERT titled SAVE_CHANGES with buttons Yes, No, Cancel.
h4. KEY-EXIT Trigger
DECLARE
     alert_id     ALERT;
     alert_button     NUMBER;
BEGIN
     IF :SYSTEM.FORM_STATUS IN ('CHANGED') THEN
          alert_id := FIND_ALERT('SAVE_CHANGES');
          alert_button := SHOW_ALERT(alert_id);
          -- ALERT_BUTTON1 is Yes, ALERT_BUTTON2 is No, ALERT_BUTTON3 is Cancel
          IF alert_button = ALERT_BUTTON1 THEN
               EXIT_FORM(DO_COMMIT);
          ElSIF alert_button = ALERT_BUTTON2 THEN
               EXIT_FORM(NO_COMMIT);
          ELSE
               RAISE FORM_TRIGGER_FAILURE;
          END IF;
     ELSE
          EXIT_FORM;
     END IF;
END;h4. KEY-ENTQRY Trigger
DECLARE
     alert_id     ALERT;
     alert_button     NUMBER;
BEGIN
     IF :SYSTEM.FORM_STATUS IN ('CHANGED') THEN
          alert_id := FIND_ALERT('SAVE_CHANGES');
          alert_button := SHOW_ALERT(alert_id);
          -- ALERT_BUTTON1 is Yes, ALERT_BUTTON2 is No, ALERT_BUTTON3 is Cancel
          IF alert_button = ALERT_BUTTON1 THEN
               COMMIT_FORM;
               ENTER_QUERY;
          ElSIF alert_button = ALERT_BUTTON2 THEN
               CLEAR_FORM(TO_SAVEPOINT);
               ENTER_QUERY;
          ELSE
               RAISE FORM_TRIGGER_FAILURE;
          END IF;
     ELSE
          ENTER_QUERY;
     END IF;
END;