Trigger to Update in the same table.

Question

Hi,
I would like to create a trigger that when we insert into table ALL_CAPACITY_SNS_CELL1 it updates column Action on teh same table,if teher is an update, it will update the same table , column ACTION.
This is what I have attempted but seems to be technically wrong.
<pre>
create table ALL_CAPACITY_SNS_CELL1
( A varchar2,
action char(2),
date_executed date);
create or replace
TRIGGER ALL_CAPACITY_HISTORY_TRACKING
AFTER INSERT OR DELETE OR UPDATE ON ALL_CAPACITY_SNS_CELL1 FOR EACH ROW
DECLARE
v_operation VARCHAR2(10) := NULL;
BEGIN
IF INSERTING THEN
v_operation := 'I';
ELSIF UPDATING THEN
v_operation := 'U';
ELSE
v_operation := 'D';
END IF;
IF INSERTING
UPDATE ALL_CAPACITY_SNS_CELL1
SET ACTION =v_operation,
DATE_EXECUTED =sysdate ;
ELSIF UPDATING THEN
UPDATE ALL_CAPACITY_SNS_CELL1
SET ACTION =v_operation,
DATE_EXECUTED =sysdate ;
END IF;
END;
</pre>

Answer 1

CrackerJack wrote:
But above query made all ACTION nul...so we shoudl after insert or update trigger right?Obviously it is not working. You modified my code the way it does not make sense.
IF INSERTING
THEN
:NEW.ACTION := 'I';
IF UPDATING
THEN
:NEW.ACTION := 'U';
ELSE
:NEW.ACTION := 'X';
END IF;The code above checks if trigger fired on INSERT (IF INSERTING). In THEN branch of that IF you check if trigger fired on UPDATE. It makes no sense. Now, if you would use my trigger:
SQL> create table ALL_CAPACITY_SNS_CELL1
  2  ( A varchar2(1),
  3  action char(2),
  4  date_executed date);
Table created.
SQL> create or replace
  2    TRIGGER ALL_CAPACITY_HISTORY_TRACKING
  3      BEFORE INSERT
  4         OR UPDATE
  5      ON ALL_CAPACITY_SNS_CELL1
  6      FOR EACH ROW
  7      BEGIN
  8          IF INSERTING
  9            THEN
10              :NEW.ACTION := 'I';
11            ELSE
12              :NEW.ACTION := 'U';
13          END IF;
14          :NEW.DATE_EXECUTED := sysdate ;
15  END;
16  /
Trigger created.
SQL> insert into ALL_CAPACITY_SNS_CELL1(a) values('A')
  2  /
1 row created.
SQL> insert into ALL_CAPACITY_SNS_CELL1(a) values('B')
  2  /
1 row created.
SQL> alter session set nls_date_format='mm/dd/yyyy hh24:mi:ss'
  2  /
Session altered.
SQL> select * from ALL_CAPACITY_SNS_CELL1
  2  /
A AC DATE_EXECUTED
A I  05/13/2009 08:56:02
B I  05/13/2009 08:56:09
SQL> update ALL_CAPACITY_SNS_CELL1
  2  set a = 'X'
  3  where a = 'B'
  4  /
1 row updated.
SQL> select * from ALL_CAPACITY_SNS_CELL1
  2  /
A AC DATE_EXECUTED
A I  05/13/2009 08:56:02
X U  05/13/2009 08:57:05
SQL> update ALL_CAPACITY_SNS_CELL1
  2  set a = 'Y'
  3  /
2 rows updated.
SQL> select * from ALL_CAPACITY_SNS_CELL1
  2  /
A AC DATE_EXECUTED
Y U  05/13/2009 08:57:21
Y U  05/13/2009 08:57:21
SQL> insert into ALL_CAPACITY_SNS_CELL1(a) values('C')
  2  /
1 row created.
SQL> select * from ALL_CAPACITY_SNS_CELL1
  2  /
A AC DATE_EXECUTED
Y U  05/13/2009 08:57:21
Y U  05/13/2009 08:57:21
C I  05/13/2009 08:57:53
SQL> SY.