Trying to import iPhoto 6.0.2 Library to Aperture 1.1 - Need help!

Question

I just installed aperture and updated to version 1.1 I attempted import my iphoto library into aperture, but ran into a serious problem. A large number of my jpg pictures are coming up as "Unsupported Image Format." I have figured out that all the pictures that have this problem are original unedited jpg. All the edited pictures seem to appear.
I suspect it has something to do with my setting in iPhoto to not copy pictures when importing them into the library. So instead of a copy of these originals, iPhoto merely has a alias or link to the original picture in the actual iPhoto library. While I can see why this might be a problem, it's a bit frustrating that the feature was introduced in iPhoto6, but then causes problem when you want to go from iPhoto6 to Aperture.
Any suggestions or advice on how I might be able to work around this would be GREATLY appreciated. I'm eager to start my workflow in Aperture, but all my pictures are stuck in iPhoto.
Thanks!

Answer 1

1. make a backup of your iPhoto library folder or the 'Originals' folder within.
2. paste this script into Script Editor and save it as an Application.
3. in the Finder, drop the 'Originals' folder from within the iPhoto library onto the new application; what we call a Droplet. the Finder will replace all aliases within the folder and nested folders with their original image files.
the script:
-- begin
to open theFolders
   repeat with i from 1 to theFolders's length
      copy theFolders's item i to theFolder
      if (theFolder as string) ends with ":" then
         replaceWithOriginal(theFolder)
      end if
   end repeat
   return
end open
to replaceWithOriginal(theFolder)
   tell application "Finder"
      set containedItems to every alias file of theFolder
      repeat with i from 1 to containedItems's length
         copy containedItems's item i to theAlias
         try
            copy theAlias's original item to theOriginal
            duplicate theOriginal to theAlias's container with replacing
         on error number -1728 -- orphaned alias
            delete theAlias
         end try
      end repeat
      set containedFolders to every folder of theFolder
      repeat with i from 1 to containedFolders's length
         replaceWithOriginal(containedFolders's item i) of me
      end repeat
   end tell
end replaceWithOriginal
-- end