Trying to raise a named exception, in an exception handler

Question

We have some converted code that I'm trying to fix. Usually, the code isn't modularized, and is an EXCEPTION named at the top of a package gets raised, the code falls into the EXCEPTION handler and everything works fine.
create or replace package tmp_pg
as
  procedure main;
end tmp_pg;
create or replace package body tmp_pg
as
  x_datacheck EXCEPTION;
  wk_num      NUMBER(1);
begin
  wk_num := 1;
exception
  when x_datacheck then
    raise_application_error(-20500, 'datacheck');
  when others then
    raise;
end tmp_pg;
/The problem we're seeing for some of the code, is that inside the private methods in the PACKAGE BODY, the EXCEPTION defined at the PACKAGE BODY-level is raised, which results in a "ORA-06510: PL/SQL: unhandled user-defined exception" error:
create or replace package body tmp_pg
as
  x_datacheck EXCEPTION;
  wk_num      NUMBER(1);
  procedure main is
  begin
    if wk_num = 1 then
      raise x_datacheck;
    end if;
  end main;
begin
  wk_num := 1;
exception
  when x_datacheck then
    raise_application_error(-20500, 'datacheck');
  when others then
    raise;
end tmp_pg;So the code above compiles, but fails at runtime. I tried both of the following, which doesn't work:
- adding an exception handler in the procedure MAIN( ), which raises X_DATACHECK
  procedure main is
  begin
    if wk_num = 1 then
      raise x_datacheck;
    end if;
  exception
    when x_datacheck then
      raise x_datacheck
  end main;- adding a locally defined exception handler in MAIN( ), raising that, which in turn raises X_DATACHECK from the exception handler in MAIN( )
  procedure main is
    lx_datacheck EXCEPTION;
  begin
    if wk_num = 1 then
      raise lx_datacheck;
    end if;
  exception
    when lx_datacheck then
      raise x_datacheck;
  end main;Does anyone have another solution I could try?
Thanks,
--=Chuck

Answer 1

This block of code:
begin
  wk_num := 1;
exception
  when x_datacheck then
    raise_application_error(-20500, 'datacheck');
  when others then
    raise;
end tmp_pg;executes only once, the first time the package is accessed in a session. Since it does not raise x_datacheck, the exception block will not catch it. When x_datacheck is raised in main, the initialisation section has already finished running, so main needs to be the one catching and re-raising. Something like:
SQL> create package tmp_pg as
  2    procedure main;
  3  end tmp_pg;
  4  /
Package created.
SQL> create or replace package body tmp_pg as
  2    x_datacheck EXCEPTION;
  3    wk_num      NUMBER(1);
  4
  5    procedure main is
  6    begin
  7      if wk_num = 1 then
  8        raise x_datacheck;
  9      end if;
10    exception
11      when x_datacheck then
12        raise_application_error(-20500, 'datacheck');
13    end main;
14
15  begin
16    wk_num := 1;
17  end tmp_pg;
18  /
Package body created.
SQL> exec tmp_pg.main;
BEGIN tmp_pg.main; END;
ERROR at line 1:
ORA-20500: datacheck
ORA-06512: at "OPS$ORACLE.TMP_PG", line 12
ORA-06512: at line 1This would work even if some procedure called by main raised x_datacheck. If you want the initialisation section to catch x_datacheck, then either it needs to raise it itself, or call a procedure that raises x_datacheck.
John
John