TryParse not passing correct values?

Question

All,
I'm trying to parse text box input to an integer.  Then based on the value of that integer a sub will set values for various other variables (integers).  Then the integers that are obtained from the sub are passed to a sb.appendline.
I am doing this for about 20 text boxes.  However, sometimes it works and sometimes it doesn't.  Sometimes every line in the text file will contain the correct quotas (integers).  Sometimes the first line in the text file contains
all zeros for the quotas and the rest of the lines in the text file contain the correct quotas.  Sometimes all of the lines will contain either incorrect values for the quotas or all zeros for the quotas.
I am baffled as to why.  Any help would be greatly appreciated.
James
Public Class Form1
Public inBW As Integer
Public outBW As Integer
Public inTCP As Integer
Public inUDP As Integer
Public inICMP As Integer
Public inIGMP As Integer
Public outTCP As Integer
Public outUDP As Integer
Public outICMP As Integer
Public outIGMP As Integer
Public tempInt As Integer
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim FileName As String
Dim FileNameAndPath As String
FileName = "Test.txt"
FileNameAndPath = IO.Path.Combine(AppDomain.CurrentDomain.BaseDirectory, FileName)
Dim sb As New System.Text.StringBuilder
'Get Bandwidth 1 Quotas
Integer.TryParse(txtInboundBW1.Text, inBW)
Integer.TryParse(txtOutboundBW1.Text, outBW)
Get_Quotas()
'Write Bandwidth 1 quotas to file
sb.AppendLine(("create Quotas -bw_in ") & txtInboundBW1.Text & (" -bw_out ") & txtOutboundBW1.Text & (" -in_tcp_quota " & inTCP & " -in_udp_quota " & inUDP & " -in_icmp_quota " & inICMP & " -in_igmp_quota " & inIGMP & " -out_tcp_quota " & outTCP & " -out_udp_quota " & outUDP & " -out_icmp_quota " & outICMP & " -out_igmp_quota " & outIGMP))
'Get Bandwidth 2 Quotas
Integer.TryParse(txtInboundBW2.Text, inBW)
Integer.TryParse(txtOutboundBW2.Text, outBW)
Get_Quotas()
'Write Bandwidth 2 quotas to file
sb.AppendLine(("create Quotas -bw_in ") & txtInboundBW2.Text & (" -bw_out ") & txtOutboundBW2.Text & (" -in_tcp_quota " & inTCP & " -in_udp_quota " & inUDP & " -in_icmp_quota " & inICMP & " -in_igmp_quota " & inIGMP & " -out_tcp_quota " & outTCP & " -out_udp_quota " & outUDP & " -out_icmp_quota " & outICMP & " -out_igmp_quota " & outIGMP))
SaveFileDialog1.InitialDirectory = My.Computer.FileSystem.SpecialDirectories.Desktop
SaveFileDialog1.FileName = FileName
SaveFileDialog1.Filter = "txt files (*.txt)|*.txt|All files (*.*)|*.*"
If SaveFileDialog1.ShowDialog = Windows.Forms.DialogResult.OK Then
IO.File.WriteAllText(SaveFileDialog1.FileName, sb.ToString)
Process.Start(SaveFileDialog1.FileName)
End If
End Sub
Public Sub Get_Quotas()
'5,000 kbps = 80,50,10,10
'10,000 kbps = 75,50,9,9
'100,000 kbps= 75,50,2,2
'1,000,000 kbps= 75,50,1,1
'10,000,000 kbps= 75,50,1,1
'40,000,000 kbps= 75,50,1,1
If inBW > 0 And inBW <= 5000 Then
inTCP = 80
inUDP = 50
inICMP = 10
inIGMP = 10
End If
If outBW > 0 And outBW <= 5000 Then
outTCP = 80
outUDP = 50
outICMP = 10
outIGMP = 10
End If
If inBW > 5000 And inBW <= 10000 Then
inTCP = 70
inUDP = 50
inICMP = 9
inIGMP = 9
End If
If outBW > 5000 And outBW <= 10000 Then
outTCP = 70
outUDP = 50
outICMP = 9
outIGMP = 9
End If
If inBW > 10000 And inBW <= 100000 Then
inTCP = 70
inUDP = 50
inICMP = 2
inIGMP = 2
End If
If outBW > 10000 And outBW <= 100000 Then
outTCP = 70
outUDP = 50
outICMP = 2
outIGMP = 2
End If
If inBW > 100000 And inBW <= 4000000 Then
inTCP = 70
inUDP = 50
inICMP = 1
inIGMP = 1
End If
If outBW > 100000 And outBW <= 4000000 Then
outTCP = 70
outUDP = 50
outICMP = 1
outIGMP = 1
End If
End Sub
End Class

Answer 1

Version with XML comments (IntelliSense support):
Option Strict On
Option Explicit On
Option Infer Off
Namespace James
Public Class BandwidthPolicy
''' <summary>
''' An enumerator for the policy type (currently five).
''' </summary>
''' <remarks></remarks>
Public Enum PolicyType
Global_Policy
Web_Policy
Mail_Policy
FTP_Policy
DNS_Policy
End Enum
Private _global_PolicyQuota As BandwidthQuota
Private _web_PolicyQuota As BandwidthQuota
Private _mail_PolicyQuota As BandwidthQuota
Private _fTP_PolicyQuota As BandwidthQuota
Private _dNS_PolicyQuota As BandwidthQuota
Public Sub New()
End Sub
''' <summary>
''' Gets the DNS policy quota.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property DNS_PolicyQuota As BandwidthQuota
Get
Return _dNS_PolicyQuota
End Get
End Property
''' <summary>
''' Gets the FTP policy quota.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property FTP_PolicyQuota As BandwidthQuota
Get
Return _fTP_PolicyQuota
End Get
End Property
''' <summary>
''' Gets the Global policy quota.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property Global_PolicyQuota As BandwidthQuota
Get
Return _global_PolicyQuota
End Get
End Property
''' <summary>
''' Gets the Mail policy quota.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property Mail_PolicyQuota As BandwidthQuota
Get
Return _mail_PolicyQuota
End Get
End Property
''' <summary>
''' Gets the Web policy quota.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property Web_PolicyQuota As BandwidthQuota
Get
Return _web_PolicyQuota
End Get
End Property
''' <summary>
''' A method to set the policy quota for any of the policy types.
''' This method requires that you have already created/initialized
''' the BandwidthQuota.
''' </summary>
''' <param name="type">The enumerator to indicate which policy type
''' to initialize.</param>
''' <param name="bq">The instance of PolicyType to set this policy
''' to.</param>
Public Sub SetPolicy(ByVal type As PolicyType, _
ByVal bq As BandwidthQuota)
Try
Select Case type
Case PolicyType.DNS_Policy
_dNS_PolicyQuota = bq
Case PolicyType.FTP_Policy
_fTP_PolicyQuota = bq
Case PolicyType.Global_Policy
_global_PolicyQuota = bq
Case PolicyType.Mail_Policy
_mail_PolicyQuota = bq
Case PolicyType.Web_Policy
_web_PolicyQuota = bq
End Select
Catch ex As Exception
Throw
End Try
End Sub
''' <summary>
''' A method to set the policy quota for any of the policy types.
''' This method will create/initialize the BandwidthPolicy for any
''' of the policy types.
''' </summary>
''' <param name="type">The enumerator to indicate which policy
''' type to initialize.</param>
''' <param name="bandwidthIn">The bandwidth input value.</param>
''' <param name="bandwidthOut">The bandwidth output value.</param>
''' <remarks></remarks>
Public Sub SetPolicy(ByVal type As PolicyType, _
ByVal bandwidthIn As Integer, _
ByVal bandwidthOut As Integer)
Try
Select Case type
Case PolicyType.DNS_Policy
_dNS_PolicyQuota = New BandwidthQuota(bandwidthIn, bandwidthOut)
Case PolicyType.FTP_Policy
_fTP_PolicyQuota = New BandwidthQuota(bandwidthIn, bandwidthOut)
Case PolicyType.Global_Policy
_global_PolicyQuota = New BandwidthQuota(bandwidthIn, bandwidthOut)
Case PolicyType.Mail_Policy
_mail_PolicyQuota = New BandwidthQuota(bandwidthIn, bandwidthOut)
Case PolicyType.Web_Policy
_web_PolicyQuota = New BandwidthQuota(bandwidthIn, bandwidthOut)
End Select
Catch ex As Exception
Throw
End Try
End Sub
''' <summary>
''' A method which will return a formatted string indicating the
''' values of the BandwidthQuota for any of the policy types.
''' </summary>
''' <param name="type">The enumerator to indicate which policy type
''' to retrieve.</param>
''' <param name="throwIfNotInitialized">OPTIONAL: A boolean value
''' indicating whether or not to throw an exception if the policy
''' type chosen has not been initialized. Default: False.</param>
''' <returns></returns>
''' <remarks></remarks>
Public Function GetFormattedString(ByVal type As PolicyType, _
Optional ByVal throwIfNotInitialized As Boolean = False) As String
Dim retVal As String = String.Empty
Try
Dim bq As BandwidthQuota
Select Case type
Case PolicyType.DNS_Policy
If _dNS_PolicyQuota.BW_In > 0 AndAlso _dNS_PolicyQuota.BW_Out > 0 Then
bq = _dNS_PolicyQuota
With bq
retVal = _
String.Format("create DNSPolicy" & _
" -bw_in {0}" & _
" -bw_out {1}" & _
" -in_tcp_quota {2}" & _
" -in_udp_quota {3}" & _
" -in_icmp_quota {4}" & _
" -in_igmp_quota {5}" & _
" -out_tcp_quota {6}" & _
" -out_udp_quoata {7}" & _
" -out_icmp_quota {8}" & _
" -out_igmp_quota {9}", _
.BW_In, .BW_Out, .TCP_In, _
.UDP_In, .ICMP_In, .IGMP_In, _
.TCP_Out, .UDP_Out, .ICMP_Out, _
.IGMP_Out)
End With
Else
If throwIfNotInitialized Then
Throw New ArgumentException("The DNS policy has not been initialized.")
End If
End If
Case PolicyType.FTP_Policy
If _fTP_PolicyQuota.BW_In > 0 AndAlso _fTP_PolicyQuota.BW_Out > 0 Then
bq = _fTP_PolicyQuota
With bq
retVal = _
String.Format("create FTPPolicy" & _
" -bw_in {0}" & _
" -bw_out {1}" & _
" -in_tcp_quota {2}" & _
" -in_udp_quota {3}" & _
" -in_icmp_quota {4}" & _
" -in_igmp_quota {5}" & _
" -out_tcp_quota {6}" & _
" -out_udp_quoata {7}" & _
" -out_icmp_quota {8}" & _
" -out_igmp_quota {9}", _
.BW_In, .BW_Out, .TCP_In, _
.UDP_In, .ICMP_In, .IGMP_In, _
.TCP_Out, .UDP_Out, .ICMP_Out, _
.IGMP_Out)
End With
Else
If throwIfNotInitialized Then
Throw New ArgumentException("The FTP policy has not been initialized.")
End If
End If
Case PolicyType.Global_Policy
If _global_PolicyQuota.BW_In > 0 AndAlso _global_PolicyQuota.BW_Out > 0 Then
bq = _global_PolicyQuota
With bq
retVal = _
String.Format("create GlobalPolicy" & _
" -bw_in {0}" & _
" -bw_out {1}" & _
" -in_tcp_quota {2}" & _
" -in_udp_quota {3}" & _
" -in_icmp_quota {4}" & _
" -in_igmp_quota {5}" & _
" -out_tcp_quota {6}" & _
" -out_udp_quoata {7}" & _
" -out_icmp_quota {8}" & _
" -out_igmp_quota {9}", _
.BW_In, .BW_Out, .TCP_In, _
.UDP_In, .ICMP_In, .IGMP_In, _
.TCP_Out, .UDP_Out, .ICMP_Out, _
.IGMP_Out)
End With
Else
If throwIfNotInitialized Then
Throw New ArgumentException("The Global policy has not been initialized.")
End If
End If
Case PolicyType.Mail_Policy
If _mail_PolicyQuota.BW_In > 0 AndAlso _mail_PolicyQuota.BW_Out > 0 Then
bq = _mail_PolicyQuota
With bq
retVal = _
String.Format("create MailPolicy" & _
" -bw_in {0}" & _
" -bw_out {1}" & _
" -in_tcp_quota {2}" & _
" -in_udp_quota {3}" & _
" -in_icmp_quota {4}" & _
" -in_igmp_quota {5}" & _
" -out_tcp_quota {6}" & _
" -out_udp_quoata {7}" & _
" -out_icmp_quota {8}" & _
" -out_igmp_quota {9}", _
.BW_In, .BW_Out, .TCP_In, _
.UDP_In, .ICMP_In, .IGMP_In, _
.TCP_Out, .UDP_Out, .ICMP_Out, _
.IGMP_Out)
End With
Else
If throwIfNotInitialized Then
Throw New ArgumentException("The Mail policy has not been initialized.")
End If
End If
Case PolicyType.Web_Policy
If _web_PolicyQuota.BW_In > 0 AndAlso _web_PolicyQuota.BW_Out > 0 Then
bq = _web_PolicyQuota
With bq
retVal = _
String.Format("create WebPolicy" & _
" -bw_in {0}" & _
" -bw_out {1}" & _
" -in_tcp_quota {2}" & _
" -in_udp_quota {3}" & _
" -in_icmp_quota {4}" & _
" -in_igmp_quota {5}" & _
" -out_tcp_quota {6}" & _
" -out_udp_quoata {7}" & _
" -out_icmp_quota {8}" & _
" -out_igmp_quota {9}", _
.BW_In, .BW_Out, .TCP_In, _
.UDP_In, .ICMP_In, .IGMP_In, _
.TCP_Out, .UDP_Out, .ICMP_Out, _
.IGMP_Out)
End With
Else
If throwIfNotInitialized Then
Throw New ArgumentException("The Web policy has not been initialized.")
End If
End If
End Select
Catch ex As Exception
Throw
End Try
Return retVal
End Function
End Class
Public Structure BandwidthQuota
Private Enum InOut
Input
Output
End Enum
''' <summary>
''' Gets the minimum value for bandwidth.
''' </summary>
''' <remarks>Note that this is "hard-coded".</remarks>
Public Shared ReadOnly MinValue As Integer = 1
''' <summary>
''' Gets the maximum value for bandwidth.
''' </summary>
''' <remarks>Note that this is "hard-coded".</remarks>
Public Shared ReadOnly MaxValue As Integer = 40000000
Private _bW_In As Integer
Private _bW_Out As Integer
Private _tCP_In As Integer
Private _tCP_Out As Integer
Private _uDP_In As Integer
Private _uDP_Out As Integer
Private _iCMP_In As Integer
Private _iCMP_Out As Integer
Private _iGMP_In As Integer
Private _iGMP_Out As Integer
''' <summary>
''' The constructor for this structure.
''' </summary>
''' <param name="bandwidthIn">The value of the input bandwidth.</param>
''' <param name="bandwidthOut">The value of the output bandwidth.</param>
''' <remarks></remarks>
Public Sub New(ByVal bandwidthIn As Integer, _
ByVal bandwidthOut As Integer)
Try
If bandwidthIn < MinValue Then
Throw New _
ArgumentOutOfRangeException("Bandwidth In", _
"The minimum value is " & _
MinValue.ToString & _
" kBPS")
ElseIf bandwidthIn > MaxValue Then
Throw New _
ArgumentOutOfRangeException("Bandwidth In", _
"The maximum value is " & _
MaxValue.ToString & _
" kBPS")
ElseIf bandwidthOut < MinValue Then
Throw New _
ArgumentOutOfRangeException("Bandwidth Out", _
"The minimum value is " & _
MinValue.ToString & _
" kBPS")
ElseIf bandwidthOut > MaxValue Then
Throw New _
ArgumentOutOfRangeException("Bandwidth Out", _
"The maximum value is " & _
MaxValue.ToString & _
" kBPS")
Else
_bW_In = bandwidthIn
_bW_Out = bandwidthOut
ComputeValues(bandwidthIn, InOut.Input)
ComputeValues(bandwidthOut, InOut.Output)
End If
Catch ex As Exception
Throw
End Try
End Sub
''' <summary>
''' Gets the value of the input bandwidth.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property BW_In() As Integer
Get
Return _bW_In
End Get
End Property
''' <summary>
''' Gets the value of the output bandwidth.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property BW_Out() As Integer
Get
Return _bW_Out
End Get
End Property
''' <summary>
''' Gets the value for the input ICMP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property ICMP_In() As Integer
Get
Return _iCMP_In
End Get
End Property
''' <summary>
''' Gets the value for the output ICMP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property ICMP_Out() As Integer
Get
Return _iCMP_Out
End Get
End Property
''' <summary>
''' Gets the value for the input IGMP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property IGMP_In() As Integer
Get
Return _iGMP_In
End Get
End Property
''' <summary>
''' Gets the value for the output IGMP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property IGMP_Out() As Integer
Get
Return _iGMP_Out
End Get
End Property
''' <summary>
''' Gets the value for the input TCP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property TCP_In() As Integer
Get
Return _tCP_In
End Get
End Property
''' <summary>
''' Gets the value for the output TCP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property TCP_Out() As Integer
Get
Return _tCP_Out
End Get
End Property
''' <summary>
''' Gets the value for the input UDP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property UDP_In() As Integer
Get
Return _uDP_In
End Get
End Property
''' <summary>
''' Gets the value for the output UDP.
''' </summary>
''' <value></value>
''' <returns></returns>
''' <remarks></remarks>
Public ReadOnly Property UDP_Out() As Integer
Get
Return _uDP_Out
End Get
End Property
Private Sub ComputeValues(ByVal value As Integer, _
ByVal io As InOut)
If value > 0 AndAlso value <= 5000 Then
SetValues(80, 50, 10, 10, io)
ElseIf value > 5000 AndAlso value <= 10000 Then
SetValues(75, 50, 9, 9, io)
ElseIf value > 10000 AndAlso value <= 100000 Then
SetValues(75, 50, 2, 2, io)
ElseIf value > 100000 AndAlso value <= 40000000 Then
SetValues(75, 50, 1, 1, io)
End If
End Sub
Private Sub SetValues(ByVal tcp As Integer, _
ByVal udp As Integer, _
ByVal icmp As Integer, _
ByVal igmp As Integer, _
ByVal io As InOut)
Select Case io
Case InOut.Input
_tCP_In = tcp
_uDP_In = udp
_iCMP_In = icmp
_iGMP_In = igmp
Case InOut.Output
_tCP_Out = tcp
_uDP_Out = udp
_iCMP_Out = icmp
_iGMP_Out = igmp
End Select
End Sub
End Structure
End Namespace
Still lost in code, just at a little higher level.