Unzip/Unstuff Folder Action

Question

I wanted to set up a folder in which a file would automatically unzip/unstuff once it is done downloading from an FTP site, and V.K. in the Automator board showed me this applescript:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px;
color: #000000;
background-color: #ADD8E6;
overflow: auto;" title="this text can be pasted into the Script Editor">
property DELAYTIMESECONDS : 5 -- How long to wait between checking file size.
on adding folder items to thisFolder after receiving theItems
repeat with f in theItems
set oldSize to 0
set newSize to -1
-- When newSize equals oldSize, it means the copy is complete because the size hasn't changed.
repeat while newSize ≠ oldSize
-- Get the file size.
set oldSize to size of (info for f)
delay DELAYTIMESECONDS
-- Sample the size again after delay for comparison.
set newSize to size of (info for f)
end repeat
-- Do your processing here on file f.
tell application "Finder" to open f
-- thats where my processing should start for each file
end repeat
-- Or start processing here to wait for all files to be complete.
end adding folder items to</pre>
I attached it to a folder, and it works, but only on the first file. If I let multiple files download concurrently, the script never kicks in for the second, third, etc. file. Can the applescript be modified so that it hits every file that is, eventually, saved to the folder?

Answer 1

The problem is that the folder action gets triggered the minute something gets added to the folder. This works when everything is added at once, but if there is much of a time delay between adding items there can be a problem, since repeatedly firing off the same folder action script on the same folder with different items doesn't seem to work very well.
Another thing to try would be to just look at the folder itself to stop changing size. After the folder has stopped changing size (presumably because the files have finished downloading), all of the files would then be processed. The items would need to be moved somewhere during the processing, so that the next time the folder action is triggered, it would just be processing the new items (if the processing just gets all of the files, a sub folder could be used).
The following folder action is similar to what you were using, it just looks at the folder size.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFEE80;
overflow: auto;"
title="this text can be pasted into the Script Editor">
on adding folder items to thisFolder after receiving theItems
if (WaitForFilesToCopy into thisFolder for 60) then
tell application "Finder"
set theItems to (files of thisFolder) as alias list -- get a new item list
end tell
repeat with anItem in theItems
-- do stuff with anItem
end repeat
else
-- the downloads didn't happen in time
end if
end adding folder items to
to WaitForFilesToCopy into TheFolder for TimeToWait
waits up to the TimeToWait for files to be copied/downloaded to TheFolder
the test is based on the size of the folder not changing after several seconds
the rough TimeToWait may need to be adjusted if copying several files/folders
parameters - TheFolder [mixed]: the folder to check
TimeToWait [integer]: a maximum timeout value in seconds
returns [boolean]: true if copy/download finished, false if timeout
set {Possible, Interval} to {false, 3} -- change the check interval as desired
set CurrentSize to size of (info for TheFolder) -- get initial size
repeat (TimeToWait div Interval) times -- check every Interval seconds
delay Interval
set NewSize to size of (info for TheFolder) -- recheck size
if (NewSize is equal to CurrentSize) then
if Possible then -- no change since last time
return true -- success
else -- one more time...
set Possible to true
end if
else -- update size & Possible switch
set {CurrentSize, Possible} to {NewSize, false}
end if
end repeat
return false -- fail (timeout)
end WaitForFilesToCopy
</pre>