UPDATE multiple columns with conditional SET parameters

Question

I have a procedure that updates multiple columns of a table using the procedure's parameter. Is it possible to have one update statement with conditional SET parameter?
CREATE TABLE TEMP
(POL_NUM NUMBER,
OED DATE,
TERM NUMBER,
TRANS_CD CHAR(2));
INSERT INTO TEMP VALUES (1, '1 AUG 2009', 12, 'NB');
INSERT INTO TEMP VALUES (2, '4 AUG 2009', 12, 'XL');
INSERT INTO TEMP VALUES (3, '2 AUG 2009', 12, 'RN');
COMMIT;
CREATE OR REPLACE PROCEDURE TMP_PROC (
  pPOL_NUM NUMBER,
  pOED IN DATE,
  pTERM IN NUMBER,
  pTRANS_CD CHAR2)
AS
BEGIN
  IF pOED IS NOT NULL THEN
    UPDATE TEMP SET OED = pOED WHERE POL_NUM = pPOL_NUM;
  END IF;
  IF pTERM IS NOT NULL THEN
    UPDATE TEMP SET TERM = pTERM WHERE POL_NUM = pPOL_NUM;
  END IF;
  IF pTRAN_CD IS NOT NULL THEN
    UPDATE TEMP SET TRANS_CD = pTRANS_CD WHERE POL_NUM = pPOL_NUM;
  END IF;
  COMMIT;
EXCEPTION
  WHEN OTHERS THEN
     NULL;
END;Is it possible to replace multiple IFs from the code to have only one UPDATE statement with condition that update the column only if the passed parameter is not null? In real scenario I have more than 3 columns and I don't want to write many IF blocks.
Please help Gurus!!
Edited by: Kuul13 on Sep 18, 2009 1:26 PM

Answer 1

Hi,
You certainly don't want to issue separate UPDATE statements for every column; that will be really inefficent.
SQL has several ways to implement IF-THEN-ELSE logic. CASE is the most versatile, but NVL will do everything you need for this job. You can use one of those to set a column to itself (and therefore not really update that column) when appropriate.
For example:
CREATE OR REPLACE PROCEDURE TMP_PROC (
  pPOL_NUM   IN       NUMBER,
  pOED          IN   DATE,
  pTERM          IN   NUMBER,
  pTRANS_CD  IN       CHAR
AS
BEGIN
     UPDATE  temp
     SET     oed      = NVL (poed,       oed)
     ,     term      = NVL (pterm,       term)
     ,     trans_cd = NVL (ptrans_cd, trans_cd)
     WHERE     pol_num      = ppol_num;
  COMMIT;     -- Maybe
END    tmp_proc;"EXCEPTION WHEN OTHERS THEN NULL" is almost always a bad idea. If there's an error, don't you want to know about it? Shouldn't you at least log a message in a warnings table or something?
Think careflully about whether or not you want to COMMIT every time you call this procedure.
Just as it's inefficient to issue a separate UPDATE statement for every column, it's also inefficient to issue a separate UPDATE statement for every row. If efficiency is important, it should be possible to UPDATE several rows in a single UPDATE statement, using NVL (or CASE, or COALESCE, or NULLIF, or NVL2, or ...).
This was a very well-written question! Thanks for providing the CREATE TABLE and INSERT statements, and such a clear explanation.