Uploading CSV file to DB table using APEX

Question

HI,
Can anyone guide me how to upload a .csv file to a DB table.
THANKS IN ADVANCE

Answer 1

user12550902 wrote:
as i got some information from the otn..i got a pl/sql code which is used in the process.
i used it in browse item .selecting file in the client disk and submitting it.when i press the button submit ,it calls a process.It is complex to parse a CSV file manually - as your code is doing. Using an external table (and having Oracle parse it for you), is a lot simpler.
My guess is that your parsing code fails to deal with all the data formatting cases for that CSV file - and thus the run-time error and failure.
I suggest that the very first thing you consider is modularisation. How can one test the parsing code in your source? It is totally embedded in the code. A very unflexible approach in all aspects - from code design to maintenance, troubleshooting and debugging. It also does not allow the CSV parsing code to be re-used.
It comes down to a very fundamental software engineering principle - modularise your code. Always.
Here's an example of creating a CSV parser - using a custom SQL data type to store the "tokens" from the CSV file, and a function to return it.
SQL> create or replace type TStrings is table of varchar2(4000);
  2  /                                                         
Type created.
SQL>
SQL> create or replace function tokenise( line varchar2, separatorChars varchar2 default ',', enclosedBy varchar2 default null ) return TStrings is
  2          strList         TStrings;                                                                                                            
  3          str             varchar2(4000);                                                                                                      
  4          i               integer;                                                                                                             
  5          l               integer;                                                                                                             
  6          enclose1        integer;                                                                                                             
  7          enclose2        integer;                                                                                                             
  8          encloseStr      varchar2(4000);                                                                                                      
  9          replaceStr      varchar2(4000);                                                                                                      
10                                                                                                                                               
11          procedure AddString( cLine varchar2 ) is                                                                                             
12          begin                                                                                                                                
13                  strList.Extend(1);                                                                                                           
14                  strList( strList.Count ) := REPLACE( cLine, CHR(0), separatorChars );                                                        
15          end;                                                                                                                                 
16                                                                                                                                               
17  begin                                                                                                                                        
18          strList := new TStrings();                                                                                                           
19                                                                                                                                               
20          str := line;                                                                                                                         
21          loop                                                                                                                                 
22                  if enclosedBy is not null then                                                                                               
23                          -- find the enclosed text, if any                                                                                    
24                          enclose1 := INSTR( str, enclosedBy, 1 );                                                                             
25                          enclose2 := INSTR( str, enclosedBy, 2 );                                                                             
26                                                                                                                                               
27                          if (enclose1 > 0) and (enclose2 > 0) and (enclose2 > enclose1) then                                                  
28                                  -- extract the enclosed string                                                                               
29                                  encloseStr := SUBSTR( str, enclose1, enclose2-enclose1+1 );                                                  
30                                  -- replace the separator char's with zero char's                                                             
31                                  replaceStr := REPLACE( encloseStr, separatorChars, CHR(0) );                                                 
32                                  -- and remove the enclosed quotes                                                                            
33                                  replaceStr := REPLACE( replaceStr, enclosedBy );                                                             
34                                  -- change the enclosed string in the big string to the replacement string                                    
35                                  str := REPLACE( str, encloseStr, replaceStr );                                                               
36                          end if;                                                                                                              
37                  end if;                                                                                                                      
38                                                                                                                                               
39                  l := LENGTH( str );                                                                                                          
40                  i := INSTR( str, separatorChars );                                                                                           
41                                                                                                                                               
42                  if i = 0 then                                                                                                                
43                          AddString( str );                                                                                                    
44                  else                                                                                                                         
45                          AddString( SUBSTR( str, 1, i-1 ) );                                                                                  
46                          str := SUBSTR( str, i+1 );                                                                                           
47                  end if;                                                                                                                      
48                                                                                                                                               
49                  -- if the separator was on the last char of the line, there is                                                               
50                  -- a trailing null column which we need to add manually                                                                      
51                  if i = l then                                                                                                                
52                          AddString( null );                                                                                                   
53                  end if;                                                                                                                      
54                                                                                                                                               
55                  exit when str is NULL;                                                                                                       
56                  exit when i = 0;                                                                                                             
57          end loop;                                                                                                                            
58                                                                                                                                               
59          return( strList );                                                                                                                   
60  end;                                                                                                                                         
61  /
Function created.
SQL> show errors
No errors.
SQL>
SQL> col TOKEN format a30
SQL>
SQL> -- default commas as separator, with a trailing null column
SQL> select rownum as TOKEN_ID, column_value as TOKEN from TABLE( tokenise('id,surname,date,1234,') );
  TOKEN_ID TOKEN
         1 id
         2 surname
         3 date
         4 1234
         5
SQL>
SQL> -- default commas as separator, with enclosed text, nulls, etc
SQL> select rownum as TOKEN_ID, column_value as TOKEN  from TABLE( tokenise('id,surname,"What do you want, universe?",date,1234,,another column',',','"') );
  TOKEN_ID TOKEN
         1 id
         2 surname
         3 What do you want, universe?
         4 date
         5 1234
         6
         7 another column
7 rows selected.
SQL>
{code}
This approach enables you to write a single and comprehensive parser, test it using SQL and PL/SQL, use it in PL/SQL and SQL, and re-use the code where and when needed.